Hi, (sorry for the stream of questions),

I would like to rotate a 3D shape around its Y axis with only ONE variable:

I have been trying to modify this code that uses mouseX and mouseY to rotate a 3D object:
rotateZ(PI/2+atan2(mouseY-height/2, mouseX-width/2));

I shortened it down to this: rotateY(PI/(mouseY-height/2));
but then you only need to move the mouse a tiny bit when the whole 3D shape flips immediately.

How do I rotate a 3D shape with only mouseY?

thanks for your help,
am

also, if you want to avoid the *0.01, you could set a rotation range and do a simple ratio calculation between range and display window width. Here's the earlier example modified, taking into account toxi's suggestion and the controllable rotation range.

Code:

float rotateRange = 360.0; // in degrees 

void setup(){
  size(600, 400, P3D);  
  framerate(30);
}
void draw(){
  background(0);  
  ambientLight(140, 140, 140);
  translate(width/2, height/2, 0);
  rotateY(radians(mouseX*rotateRange/width));
  scale(50, 50, 50);
 
  beginShape(TRIANGLES);
  //face 1
  fill(45, 200, 20);
  vertex(-1, 1, -1);  
  vertex(0, -1, 0);  
  vertex(1, 1 , -1);  
 
  //face 2
  fill(255, 30, 30);
  vertex(-1, 1, 1);  
  vertex(0, -1, 0);  
  vertex(1, 1 , 1);
 
  //face 3
  fill(140, 45, 255);
  vertex(-1, 1, -1);  
  vertex(-1, 1, 1);  
  vertex(0, -1, 0);  
 
  //face 4
  fill(255, 255, 30);
  vertex(1, 1, -1);  
  vertex(1, 1, 1);  
  vertex(0, -1, 0);  
  endShape();  
}