Code:

size(300,300);
textFont(loadFont("ArialMT-48.vlw"),20);//load a font and set textfont
String s="eskimoblood"; //the string
int l=s.length(); //the length of the string
int r=100; //the radius of the circle
//now for every char of the string calculate the position on a circle
for(int i=0;i<l;i++){
  float x=sin(-TWO_PI/l*i+PI)*r;
  float y=cos(-TWO_PI/l*i+PI)*r;   
  pushMatrix();
  translate(x+width/2,y+height/2);
  rotate(TWO_PI/l*i);
  char c=s.charAt(i);
  text(c,0,0);
  popMatrix();
}
 

I'm currently doing a library which should make this very simple.  But this is only the theory, in practice, I have to do a restructuration of the interface, so things will change  and become incompatible in later releases.

here's a bit of code:

Code:

import geomerative.*;

RShape path;
RGroup texto;
RFont font;
float t=0;

String string="Whatever text you want to adapt to the circle goes here.";

void setup(){
 size(800,600,P3D);
 framerate(50);
 font = new RFont(this,"YourTrueTypeFont.ttf",372,RFont.CENTER);
 texto = font.toGroup(string);
 
 path = new RShape();
 path = path.createCircle(200);
}

void draw(){
  background(255);
  fill(0);
  translate(width/2,height/2);
  noStroke();
  
  RGroup.setAdaptorLengthOffset(t);
  RGroup.setAdaptorScale(0.1);
  RGroup newTexto = texto.adaptTo(path);
  
  newTexto.draw(g);
  
  t+=0.001;
  t%=1;
}
 

for this to work you need to install the library  Geomerative

and you'll need to copy a True Type font in the data directory of your sketch.

hope it helps!