Just wondering if anyone else out there has encountered a similar problem to this and had any light to shed on it:

In trying to write a program that creates a simple random tree using LinkedLists of Branch objects. That is, each branch has a list of branchs which stem from it and each of those has its own list of branches and so on.

The only problem is that when I try to 'grow' the tree, the function which populates the list is recursive and goes off in one direction only creating branches on just one of the objects in the list.

I understand this isnt the best explaination so here is the code:

Branch root;

int num_of_branches, tree_size;

void setup()
{
 size(500,500);
 background(0);
 stroke(255);
 strokeWeight(1);
 
 translate(250,450);
 tree_size = 0;
 
 num_of_branches = 10;
 
 root = new Branch(0,0,0,-60);
 
}


class Branch
{
 int s_x, s_y, e_x, e_y; //start and end point coordinates
 
 LinkedList branches;
 
 Branch(int start_x, int start_y, int end_x, int end_y)
 {
   branches = new LinkedList();
   
   //create end points based on start point
   this.s_x = start_x;
   this.s_y = start_y;
   
   this.e_x = end_x;
   this.e_y = end_y;
   
   this._draw();
   this.grow();
 }
 
 Branch(int start_x, int start_y)
 {
   branches = new LinkedList();
   
   //create end points based on start point
   this.s_x = start_x;
   this.s_y = start_y;
   
   this.e_x = s_x - int(random(-50, 50));
   this.e_y = s_y - int(random(50));
   
   this._draw();
 
 }
 
 void grow()
 {
   tree_size++;
   
   int num = int(random(num_of_branches));
   println(num);
   
   //create branches
   for(int i=0;i<num;i++)
   {
     branches.add(new Branch(this.e_x, this.e_y));
   }
   
   //for each branch in list, grow until some tree size is reached
   int s = branches.size();
   for(int i=0;i<s;i++)
   {
     Branch temp = (Branch) branches.get(i);
     if(tree_size<20)
     {
       temp.grow();
     }
   }
 }
 
 void _draw()
 {
   
   line(this.s_x, this.s_y, this.e_x, this.e_y);
 }
}


If anyone else out there has had a go with anything similar to this, id be really interested to know what would be a good angle to go about populating all the branches in one recursive function to create a more realistic tree.

cheers for your time anyway,
paul.

I would try to keep track of the level of each branch instead of the total tree size (if not the tree will only grow one branch at a time until it reaches the max tree size).

Another solution would be to not do it recursive, but that's a bit more work.

Here's the modified code:
Code:

Branch root;  
 
int num_of_branches, num_of_levels;
 
void setup()
{
  size(500,500);
  background(0);
  stroke(255);
  strokeWeight(1);
   
  translate(250,450);
   
  num_of_branches = 6;
  num_of_levels = 6;
   
  root = new Branch(0,0,0,-60,0);
   
}
 
 
class Branch
{
  int s_x, s_y, e_x, e_y; //start and end point coordinates
   
  LinkedList branches;
  
  int level;
   
  Branch(int start_x, int start_y, int end_x, int end_y, int lvl)
  {
    branches = new LinkedList();
     
    //create end points based on start point
    this.s_x = start_x;
    this.s_y = start_y;
     
    this.e_x = end_x;
    this.e_y = end_y;
     
    this.level = lvl; 
     
    this._draw();
    this.grow();
  }
   
  Branch(int start_x, int start_y, int lvl)
  {
    branches = new LinkedList();
     
    //create end points based on start point
    this.s_x = start_x;
    this.s_y = start_y;
     
    this.e_x = s_x - int(random(-50, 50));
    this.e_y = s_y - int(random(50));
    
    this.level = lvl; 
	 
    this._draw();
   
  }
   
  void grow()
  {
     
    int num = int(random(num_of_branches));
    num=constrain(num, 1, num_of_branches);
    println(num);
     
    //create branches
    for(int i=0;i<num;i++)
    {
	this.branches.add(new Branch(this.e_x, this.e_y, this.level+1));
    }
     
    //for each branch in list, grow until some tree size is reached
    int s = this.branches.size();
    for(int i=0;i<s;i++)
    {
	Branch temp = (Branch) this.branches.get(i);
	if(temp.level<num_of_levels)
	{
	  temp.grow();  
	}
    }
  }
   
  void _draw()
  {
     
    line(this.s_x, this.s_y, this.e_x, this.e_y);
  }
} 
 

Quasimodo and Ricard.. thanks so much for your help. Thats exactly what I needed to do.

Paul.