Do the following snippets of code do the same thing?

Code:

beginCamera(); 
resetMatrix(); 
lookat(ex,ey,ez,cx,cy,cz,ux,uy,uz); 
endCamera();
 

Code:

camera(ex,ey,ez,cx,cy,cz,ux,uy,uz);
 

I ask because I am trying to figure out if the new camera object can handle movement around a 3D space but still focus on a specified x, y, and z point.  I was previously doing it with translate combined with some rotateX, rotateY, and rotateZ trickery.  

The camera setup is unfortunately, quite screwy.

The following code should, in my intepretation fo the reference, make a camera pan around the centre object (a ball with 3 axes), in a smooth circle.
However it does something weird, and I'm not quite sure how it's interpreting the values passed to it.

Code:

float a;

void setup()
{
  size(600,600,P3D);
  a=0;
}

void draw()
{
  a+=0.01;
  background(128);
  //set camera "eye" x and y positions so they follow a circle radius 400 around point 0,0,0
  //set camera "scene centre" to be 0,0,0
  //set camrea "up" to be 0,1,0 , i.e. positive Y value = up;
  camera(400.0*cos(a),0,400.0*sin(a),0.0,0.0,0.0,0.0,1.0,0.0);
//draw a sphere at 0,0,0 (no translate, so I assume 0,0,0...
  noStroke();
  fill(255);
  sphere(10);
  //draw 3 axes, form 0,0,0 along x, y and z axes.
  beginShape(LINES);
    stroke(255,0,0);
    vertex(0,0,0);
    vertex(100,0,0);
    stroke(0,255,0);
    vertex(0,0,0);
    vertex(0,100,0);
    stroke(0,0,255);
    vertex(0,0,0);
    vertex(0,0,100);
  endShape();
  //end result should, I think, be that the camera pans aroudn the ball and axes, keeping them centred.
} 

Camera has been fixed in v86! lookAt and camera were too close in functionality to survive together, so only camera is left. It works just like gluLookat except that Y is reversed as in all things Processing. The code above now does what it was supposed to.

I mean that the actual call is like gluLookat.

Here's the real skinny on what does what:

Code:

camera(); or
camera(ex, ey, ez, cx, cy, cz, ux, uy, uz);
 

do not need to be called from with beginCamera();/endCamera(); That's because they always apply to the camera transformation, and they always totally replace it. That means that any coordinate transforms done before camera(); in draw() will be wiped out. It also means that camera() always operates in untransformed world coordinates. Therefore it is always redundant to call resetMatrix(); before camera(); This isn't technically true of gluLookat, but it's pretty much how it's used.

Now, beginCamera(); and endCamera(); are useful if you want to move the camera around using transforms like translate(), etc. They will wipe out any coordinate system transforms that occur before them in draw(), but they will not automatically wipe out the camera transform. This means that they should be at the top of draw(). It also means that the following:

Code:

beginCamera();
rotateY(PI/80);
endCamera();
 

will result in a camera that spins without stopping. If you want to just rotate a small constant amount, try this:

Code:

beginCamera();
camera(); // sets up the default view
rotateY(PI/80);
endCamera();
 

That will rotate a little off of the default view. Note that this is entirely equivalent to

Code:

camera(); // sets up the default view
beginCamera();
rotateY(PI/80);
endCamera();
 

because camera() doesn't care whether or not it's inside a begin/end clause.

Basically it's safe to use camera() or camera(ex,ey,ez,cx,cy,cz,ux,uy,uz) as naked calls because they do all the matrix resetting automatically.