Shy oscP5 kissed Android at last, not really perfect

Shy oscP5 kissed Android at last, not really perfect

in Android Processing • 2 years ago

Hi, I had some troubles with receiving incoming values from Android Emulator, but when i replaced loopback address (127.0.0.1) with my private IP address (192.168.0.10), It works very well. Does anybody knows the reason? Or any ideas about how works with Multicast (239.0.0.1) ?

Anyway, here are working codes, I hope it will help newcomers like me.

Cheers and thanks in advance!

oscP5 on Processing:

/**
* oscP5sendreceive by andreas schlegel
* example shows how to send and receive osc messages.
* oscP5 website at http://www.sojamo.de/oscP5
*/
import oscP5.*;
import netP5.*;
OscP5 oscP5;
NetAddress myRemoteLocation;
void setup() {
size(400,400);
frameRate(25);
/* start oscP5, listening for incoming messages at port 12000 */
oscP5 = new OscP5(this,12000);
/* myRemoteLocation is a NetAddress. a NetAddress takes 2 parameters,
* an ip address and a port number. myRemoteLocation is used as parameter in
* oscP5.send() when sending osc packets to another computer, device,
* application. usage see below. for testing purposes the listening port
* and the port of the remote location address are the same, hence you will
* send messages back to this sketch.
*/
/*change 192.168.0.10 to your own IP address*/
myRemoteLocation = new NetAddress("192.168.0.10",12000);
}
void draw() {
}
/* incoming osc message are forwarded to the oscEvent method. */
void oscEvent(OscMessage theOscMessage) {
if(theOscMessage.checkAddrPattern("/mousedown"))
{
/* print the address pattern and the typetag of the received OscMessage */
// print("### received an osc message.");
// print(" addrpattern: "+theOscMessage.addrPattern());
// println(" typetag: "+theOscMessage.typetag());
println("aha!");
background(255);
}
else if(theOscMessage.checkAddrPattern("/mousedrag")) {
println("wooooooooooooow!");
}
else if(theOscMessage.checkAddrPattern("/mouseup")) {
println("yeah!");
background(0);
}
}

oscP5 on Android emulatior:

/*
Send mouse positions from Android emulatior to Processing sketch running on same WiFi network.
Modification based on hva.francesco's work. http://forum.processing.org/#Topic/25080000000336005
Version 0.1 By Lei Gao http://imlab.cc/whale (10.Nov.2010)
*/
import oscP5.*;
import netP5.*;
OscP5 oscP5;
NetAddress myRemoteLocation;
int x;
int y;
void setup() {
size(screenWidth,screenHeight);
background(255);
frameRate(25);
/* set up a remote location */
/*change 192.168.0.10 to your own IP address*/
myRemoteLocation = new NetAddress("192.168.0.10",12000);
}
void draw() {
}
void mousePressed() {
// create a new OscMessage with an address pattern, in this case /mouse_down.
OscMessage myOscMessage = new OscMessage("/mousedown");
// add a value (an integer) to the OscMessage
myOscMessage.add(mouseX);
myOscMessage.add(mouseY);
//send the OscMessage to the remote location.
OscP5.flush(myOscMessage,myRemoteLocation);
x = mouseX;
y = mouseY;
}
void mouseDragged() {
// create a new OscMessage with an address pattern, in this case /mouse_down.
OscMessage myOscMessage = new OscMessage("/mousedrag");
// add a value (an integer) to the OscMessage
myOscMessage.add(mouseX);
myOscMessage.add(mouseY);
//send the OscMessage to the remote location.
OscP5.flush(myOscMessage,myRemoteLocation);
// OscP5.flush(myOscMessage,myRemoteLocation);
// draws on screen
stroke(0);
line(x,y,mouseX,mouseY);
x = mouseX;
y = mouseY;
noStroke();
}
void mouseReleased() {
// create a new OscMessage with an address pattern, in this case /mouse_down.
OscMessage myOscMessage = new OscMessage("/mouseup");
// add a value (an integer) to the OscMessage
myOscMessage.add(mouseX);
myOscMessage.add(mouseY);
//send the OscMessage to the remote location.
OscP5.flush(myOscMessage,myRemoteLocation);
}
void keyPressed() {
if(key == CODED) {
if (keyCode == UP) {
OscMessage myOscMessage = new OscMessage("/margins");
// IMPORTANTE: per android cambiare con le seguenti righe
myOscMessage.add(screenWidth);
myOscMessage.add(screenHeight);
OscP5.flush(myOscMessage,myRemoteLocation);
background(255);
}
}
}

Replies(13)

andreas.s..

Re: Shy oscP5 kissed Android at last, not really perfect

2 years ago

thanks for sharing, a small but crucial detail. i dont have any inside information, but believe that the locahost address 127.0.0.1 does not apply to the android simulator. in case you need to now your local ip address, you can use netP5's NetInfo class to print the information into the console :

import netP5.*;
NetInfo.print();

without testing i believe the multicast address should work without any problems.

andreas schlegel, http://www.sojamo.de

lei.gao

Re: Shy oscP5 kissed Android at last, not really perfect

2 years ago

Hi thanks for the help, I put NetInfo in sketch as below

import oscP5.*;
import netP5.*;
NetInfo.print();
OscP5 oscP5;

then get error "unexpected token:(", something wrong?

also Multicast does not work on emulator (but works on computer), any feedback will be really helpful.

(for sure i set up Sketch Permissions INTERNET)

Cheers!

multicastSend

// Requirements
// * oscP5 (http://www.sojamo.de/libraries/oscP5/)
import oscP5.*;
import netP5.*;
OscP5 oscP5;
void setup() {
size(400,400);
oscP5 = new OscP5(this, "239.0.0.1", 12000);
}
void draw() {
background(0);
}
void mousePressed() {
OscMessage myOscMessage = new OscMessage("/mousedown");
// myOscMessage.add(1);
oscP5.send(myOscMessage);
}
void mouseReleased() {
OscMessage myOscMessage = new OscMessage("/mouseup");
// myOscMessage.add(0);
oscP5.send(myOscMessage);
}

multicastReceive

// Requirements
// * oscP5 (http://www.sojamo.de/libraries/oscP5/)
import oscP5.*;
import netP5.*;
OscP5 oscP5;
void setup() {
size(400,400);
oscP5 = new OscP5(this, "239.0.0.1", 12000);
}
void draw() {
}
void oscEvent(OscMessage theOscMessage) {
if(theOscMessage.checkAddrPattern("/mousedown"))
{
println("aha!");
background(255);
}
else if(theOscMessage.checkAddrPattern("/mouseup")) {
println("yeah!");
background(0);
}
}

tabbed

Re: Shy oscP5 kissed Android at last, not really perfect

2 years ago

Hi,

I have been trying to get OscP5 and android to play nice with no luck. I've tried sending messages from the device and emulator to 2 different ip address (computers i'm testing on).

Any tips, on where I could be going wrong? Has anyone else successfully got the above to work?

My steps are as follows:
1) Open new processing 0194 (on 10.6 osx) sketch in android mode
2) Copy paste all the 'send' code from above
3) Drag and drop the OscP5.jar library file onto my sketch
4) Run
5) I listen to messages using the Osculator app (http://www.osculator.net/) instead, but I also tried with the 'receive' code above. Neither work.

Cheers,
Trent.

tabbed

Re: Shy oscP5 kissed Android at last, not really perfect

2 years ago

Ah - found the missing link. You need to add the sketch permission "INTERNET".

Jesse Sco..

Re: Shy oscP5 kissed Android at last, not really perfect

2 years ago

Also, I had filed a bug, as I wasn't able to get an OSC-Android sketch to run (at first I thought it was all libraries), and it turns out the solution is to remove netP5 - they have similar classes, which Android doesn't like.

andreas.s..

Re: Shy oscP5 kissed Android at last, not really perfect

2 years ago

the netP5 issue has been continued and solved here, issues with libraries and android

algo_macc..

Re: Shy oscP5 kissed Android at last, not really perfect

2 years ago

Great ! thanks for your investigation :)

peterkirn

Re: Shy oscP5 kissed Android at last, not really perfect

2 years ago

Multicasting in the emulator also differs from how things are implemented on the device - run into some issues with multicasting on Android devices when playing with zeroconf implementation. Curious if anyone is trying this on devices, and if so, which OS version? I need to investigate this myself again(!)

andreas.s..

Re: Shy oscP5 kissed Android at last, not really perfect

2 years ago

hi peter, i just did some quick readings about android and multicast/zeroconf. also stumbled upon your yes, android can do zeroconf/bonjour:jmDNS, and this AndroidDnssd implementation. a thread over at stackoverflow suggest that multicast can be (un)locked by underlying processes on the device itself (Multicast on android 2.2). so i am very curious about solving/implementing a solution with oscP5, i will investigate more, maybe let me know if your investigations lead to some promising results.

alkopop79

Re: Shy oscP5 kissed Android at last, not really perfect

1 year ago

Hi,

I'm having troubles getting messages in the emulator. I wrote a couple of broadcast/client sketches and they work perfectly in Processing mode but once the client runs in android mode, it doesn't seem to get any messages. Sketches here:

http://forum.processing.org/topic/oscp5-for-processing-android

Any ideas? INTERNET is enabled in the sketch permission, I've tried different IP addresses... no luck:(

alkopop79

Re: Shy oscP5 kissed Android at last, not really perfect

1 year ago

Have any of you managed to get messages in the emulator or mobile? WHat am I doing wrong? I can send messages but cannot get any. Please help!!!

alkopop79

Re: Shy oscP5 kissed Android at last, not really perfect

1 year ago

What does that mean:

no such host null

### [2011/8/6 13:53:10] PROCESS @ OscP5 stopped.

ERROR @ Multicast

### [2011/8/6 13:53:10] INFO @ OscP5 is joining a multicast group @ 10.0.2.2.:11001

What's 'no such null host' and why the error?

andreas.s..

Re: Shy oscP5 kissed Android at last, not really perfect

1 year ago

to send messages back and forth between android emulator and standard mode, please see my post here topic/oscp5-for-processing-android#25080000001066218

Top Reply

Response title

Attachments

New to this Portal?