I don't see an obvious error. Is the water_surface class after this code? How your sketch is named?

the main sketch is called Brandon_Images and the class file name is water_surface, the same as the declaration public class water_surface in the first line of the file.

this following code works to substitute the background images used by the class, its just klunky and doesn't work as well as using switch ... case.

1.  if (millis()-LastUpdate >= UpdateInterval) {
2.    bgno = bgno +1;
3.    if (bgno == 1) {mywater_surface = new water_surface(img1);}
4.    if (bgno == 2) {mywater_surface = new water_surface(img2);}
5.    if (bgno == 3) {mywater_surface = new water_surface(img3);}
6.    if (bgno >= 4) {bgno = 0;}
7.    println(str(bgno));
8.    LastUpdate = millis(); 
9.  }

I didn't write the water_surface class; i just converted an existing sketch into a class and modified it slightly so that the images used don't need to be exactly the same size as in size() ... it's a really terrific water surface sketch .. been looking around now to see where it came from .. either processing.org examples or openprocessing.org .. the author deserves more recognition .. it would also be fun to see what this does when it's rotated on the y axis (so it's not just a top down perspective):

1. public class water_surface {
2.   int heightMap[][][]; // water surface (2 pages).
3.   int turbulenceMap[][]; // turbulence map
4.   int line[]; // line optimizer;
5.   int space;
6.   int radius, heightMax, density;
7.   int page = 0;
8.   PImage water;
9.   PImage wsmall;
10.  
11.   public water_surface(PImage c_img) {
12.     wsmall = c_img;
13.     wsmall.resize(dwidth,dheight);
14.     water = wsmall;
15.     //water.resize(height,width);
16.     initMap();
17.   }
18.  
19.   public void drawwater(){
20.     waterFilter();
21.     updateWater();
22.     page ^=1;
23.   }
24.  
25.   public void initMap() {
26.   // the height map is made of two "pages".
27.   // one to calculate the current state, and another to keep the previous state.
28.   heightMap = new int[2][width][height];
29.   line = new int[height];
30.   for (int l = 0; l < height; l++) {
31.     line[l] = l * width;
32.   }
33.   density = 5;
34.   radius = 20;
35.   space = width * height - 1;
36.  
37.   // the turbulence map, is an array to make a smooth turbulence over the height map.
38.   turbulenceMap = new int[radius * 2][radius * 2]; // turbulence map.
39.   int r = radius * radius;
40.   int squarex, squarey;
41.   double dist;
42.  
43.   for (int x = -radius; x < radius; x++) {
44.     squarex = x * x;
45.     for (int y = -radius; y < radius; y++) {
46.       squarey = y * y;
47.       dist = Math.sqrt(squarex + squarey);
48.       if ((squarex) + (squarey) < r) {
49.         turbulenceMap[radius + x][radius + y] += (int) (900 * ((float) radius - dist));
50.       }
51.     }
52.   }
53. }
54. // to make a turbulence, just add the turbulence map, over the height map.
55. public void makeTurbulence(int cx, int cy) {
56.   int r = radius * radius;
57.   int left = cx < radius ? -cx + 1 : -radius;
58.   int right = cx > (width - 1) - radius ? (width - 1) - cx : radius;
59.   int top = cy < radius ? -cy + 1 : -radius;
60.   int bottom = cy > (height - 1) - radius ? (height - 1) - cy : radius;
61.  
62.   for (int x = left; x < right; x++) {
63.     int xsqr = x * x;
64.     for (int y = top; y < bottom; y++) {
65.       if ((xsqr) + (y * y) < r)
66.         heightMap[page ^ 1][cx + x][cy + y] += turbulenceMap[radius + x][radius + y];
67.     }
68.   }
69. }
70. public void waterFilter() {
71.   for (int x = 0; x < width; x++) {
72.     for (int y = 0; y < height; y++) {
73.       int n = y - 1 < 0 ? 0 : y - 1;
74.       int s = y + 1 > (height) - 1 ? (height) - 1 : y + 1;
75.       int e = x + 1 > (width) - 1 ? (width) - 1 : x + 1;
76.       int w = x - 1 < 0 ? 0 : x - 1;
77.  
78.       // water filter. I used to thought that this effect
79.       // had something to do with physics... :)
80.  
81.       // it a kind of image filter, but instead of applying to an image,
82.       // we apply it to the height map, that encodes the height of the waves.
83.       int value = ((heightMap[page][w][n] + heightMap[page][x][n]
84.         + heightMap[page][e][n] + heightMap[page][w][y]
85.         + heightMap[page][e][y] + heightMap[page][w][s]
86.         + heightMap[page][x][s] + heightMap[page][e][s]) >> 2)
87.         - heightMap[page ^ 1][x][y];
88.  
89.       heightMap[page ^ 1][x][y] = value - (value >> density);
90.     }
91.   }
92. }
93.  
94. public void updateWater() {
95.   loadPixels();
96.   arraycopy(water.pixels, pixels); // not really needed...
97.   for (int y = 0; y < height - 1; y++) {
98.     for (int x = 0; x < width - 1; x++) {
99.       // using the heightmap to distort underlying image
100.       int deltax = heightMap[page][x][y] - heightMap[page][(x) + 1][y];
101.       int deltay = heightMap[page][x][y] - heightMap[page][x][(y) + 1];
102.  
103.       int offsetx = (deltax >> 3) + x;
104.       int offsety = (deltay >> 3) + y;
105.  
106.       offsetx = offsetx > width ? width - 1 : offsetx < 0 ? 0 : offsetx;
107.       offsety = offsety > height ? height - 1 : offsety < 0 ? 0 : offsety;
108.  
109.       int offset = (offsety * width) + offsetx;
110.       offset = offset < 0 ? 0 : offset > space ? space : offset;
111.       // Getting the water pixel with distortion and...
112.       // apply some fake lightning, in true color.
113.       int pixel = water.pixels[offset];
114.       int red = (pixel >> 16) & 0xff;
115.       int green = (pixel >> 8) & 0xff;
116.       int blue = (pixel) & 0xff;
117.       int light = (deltax + deltay) >> 6;
118.       red += light;
119.       green += light;
120.       blue += light;
121.       red = red > 255 ? 255 : red < 0 ? 0 : red;
122.       green = green > 255 ? 255 : green < 0 ? 0 : green;
123.       blue = blue > 255 ? 255 : blue < 0 ? 0 : blue;
124.       // updating our image source.
125.       pixels[line[y] + x] = 0xff000000 | (red << 16) | (green << 8) | blue;
126.     }
127.   }
128.   updatePixels();
129. }

The class takes an PImage as it's only argument and is called as in the original post in this thread.  Ultimately, I want to make a slideshow player for an artist friend that puts some different processing.org created effects on top of the images and the water_effect is only one of several 'effects' I'm thinking of using.  Another effect I'm trying to write is doing an outline detect on an image and then creating a path for sprites or makelines to follow around on the image .. i.e. something that would automatically detect the shape of a tree trunk or building facade and then have moving elements in the sketch move in dynamic paths based upon detected outlines .. creating an array of points to move to from shapes in a png image... but that's another story.

Note 1: If you use bgno this way, it should be case 1, not case '1'.
Note 2: You can just put the PImage items in an array and get them from there.

thanks ... having the removing the elipse so it' 1 not '1' appeared to do the trick.  I also had to move the switcher into a function and call it from the timer so that it would only execute once.  I've now got a working switch...case scenario where I can set variables depending on what background (or stage) is running.  As far as adding images to an array and using bgno as the index to pull items from the array, I'll add that when I'm done with the main things I want to do with the sketch and probably in connection with an image loader that loads all the images in the data directory.

1. PImage img1;
2. PImage img2;
3. PImage img3;
4. PImage img4;
5. PImage img5;
6. PImage bgimg;
7. public int dwidth;
8. public int dheight;
9. int bgno;
10. int UpdateInterval;
11. int LastUpdate;
12. water_surface mywater_surface;
13. //tree mytree;
14. void setup() {
15.   size(640, 420);
16.   dwidth = 640;
17.   dheight = 420;
18.   img1=loadImage("gully.jpg");
19.   img2=loadImage("bunny-disquise.png");
20.   img3=loadImage("bg__big_a.png");
21.   bgno = 1;
22.   bgimg = img1;
23.   mywater_surface = new water_surface(bgimg);
24.   //mytree = new tree();
25.   UpdateInterval = 5*1000;
26.   LastUpdate = millis();
27. }
28. void draw(){
29.   background(0);
30. if (millis()-LastUpdate >= UpdateInterval) {
31.    bgno = bgno +1;
32.    swapbg();
33.    if (bgno >= 4) {bgno = 0;}
34.    println(str(bgno));
35.    LastUpdate = millis(); 
36.  }
37.   
38.    
39.   mywater_surface.drawwater();
40.  
41. }
42. void swapbg(){
43.     switch(bgno) {
44.     case 1:
45.     bgimg = img1;
46.     mywater_surface = new water_surface(bgimg);
47.     break;
48.     case 2:
49.     bgimg = img2;
50.     mywater_surface = new water_surface(bgimg);
51.     break;
52.     case 3:
53.     bgimg = img3;
54.     mywater_surface = new water_surface(bgimg);
55.     break;
56.    }
57. }
58. public void mouseDragged(){
59.   mywater_surface.makeTurbulence(mouseX,mouseY);
60. }
61.  
62. public void mousePressed() {
63.   mywater_surface.makeTurbulence(mouseX,mouseY);
64.   //mytree.drawtree();
65. }