Random number grid, loops needed!

Programming Questions

virtualboy

Random number grid, loops needed!

in Programming Questions • 2 years ago

Hi everyone, I created a simple program to generate a grid showing a random number and the eight consecutive numbers.

I think im using too much code to construct the grid and number sequence, can anyone help me condense it a bit? I want to try and construct the grid in the setup using loops but i'm stuck!
Heres my code so far;

int RandomNum = 1;

void setup(){

size(270, 270);
PFont font;
font = loadFont("Arial-Black-32.vlw");
textFont(font);
noLoop();

}

void draw() {

fill(0, 255, 6);
rect(0, 0, 90, 90);
fill(0);
text(RandomNum++, 32, 60);

fill(255, 255, 0);
rect(90, 0, 90, 90);
fill(0);
text(RandomNum++, 122, 60);

fill(0, 255, 6);
rect(180, 0, 90, 90);
fill(0);
text(RandomNum++, 212, 60);

fill(255, 255, 0);
rect(0, 90, 90, 90);
fill(0);
text(RandomNum++, 32, 150);

fill(0, 255, 6);
rect(90, 90, 90, 90);
fill(0);
text(RandomNum++, 122, 150);

fill(255, 255, 0);
rect(180, 90, 90, 90);
fill(0);
text(RandomNum++, 212, 150);

fill(0, 255, 6);
rect(0, 180, 90, 90);
fill(0);
text(RandomNum++, 32, 240);

fill(255, 255, 0);
rect(90, 180, 90, 90);
fill(0);
text(RandomNum++, 122, 240);

fill(0, 255, 6);
rect(180, 180, 90, 90);
fill(0);
text(RandomNum++, 212, 240);
}
void mousePressed() {
RandomNum = int(random(1,91));
redraw();
}

Replies(8)

amnon.owed

Re: Random number grid, loops needed!

2 years ago

Click somewhere. The mouseX determines the grid size (minimum 1x1 and maximum 10x10 in this example).

void setup() {
size(1000,1000);
textFont(createFont("SansSerif",30));
textAlign(CENTER,CENTER);
noLoop();
}
void draw() {
int numGrid = mouseX/100+1;
int randomNum = int(random(1,91));
float gridSize = height/numGrid;
for (int y=0; y<numGrid; y ++) {
for (int x=0; x<numGrid; x ++) {
if ((x+y) % 2 == 0) { fill(0, 255, 6); }
else { fill(255, 255, 0); }
rect(x*gridSize,y*gridSize,gridSize,gridSize);
pushMatrix();
translate(gridSize/2,gridSize/2);
fill(0);
text(randomNum++, x*gridSize,y*gridSize);
popMatrix();
}
}
}
void mousePressed() {
redraw();
}

virtualboy

Re: Random number grid, loops needed!

2 years ago

I want to keep the grid the same size and clicking the mouse creates a new random number and sequence. Im just sure i am putting too much code down. Is the above an example of nested loops? Having trouble implementing the loops into the grid construction in setup.

PhiLho

Re: Random number grid, loops needed!

2 years ago

Don't post twice the same thread.
I answered in the old thread, but I wouldn't have lost my time if I knew you had an answer here.
I will delete the old thread as I am the only one having answered it.

virtualboy

Re: Re: Random number grid, loops needed!

2 years ago

I didnt see what you wrote on the old thread, is there any chance you could post it up again on here for me please? Sorry again for the repost!

virtualboy

Re: Random number grid, loops needed!

2 years ago

Apologies, i think I posted the last thread in the 'General' section and not the Programming questions. Couldn't see a way to delete my old thread, if you could get rid of it for me that would be great!

PhiLho

Re: Re: Random number grid, loops needed!

2 years ago

Done. And amnon.owed's answers are much better than the one I made, so no regrets... (well, I wouldn't have done the job for you, just giving guidelines...)

amnon.owed

Re: Random number grid, loops needed!

2 years ago

virtualboy, here it stays the same size and when you click the mouse it generates a new number sequence. Yes, these are nested loops. What do you mean "implementing the loops into the grid construction in setup"? There is really no need to place something in setup, because you need to draw the rects in draw() anyway. If you don't draw the rects in draw(), your text will become unreadable. You could draw the grid to a PGraphic (make an image of it) in setup and then use it as a background, however in this case that seems quite unnecessary.

void setup() {
size(270,270);
textFont(createFont("SansSerif",30));
textAlign(CENTER,CENTER);
noLoop();
}
void draw() {
int randomNum = int(random(1,91));
for (int y=0; y<3; y++) {
for (int x=0; x<3; x++) {
if ((x+y) % 2 == 0) { fill(0, 255, 6); } else { fill(255, 255, 0); }
rect(x*90,y*90,90,90);
fill(0);
text(randomNum++, x*90+45,y*90+45);
}
}
}
void mousePressed() {
redraw();
}

All right, to be complete, here is the PGraphic way of doing it. The grid is drawn once to an image which is used in the draw() loop. But like I said before, it seems a bit overkill in this situation. So the above solution is better in my opinion.

PGraphics grid;
void setup() {
size(270,270);
grid = createGraphics(width,height,P2D);
grid.beginDraw();
for (int y=0; y<3; y++) {
for (int x=0; x<3; x++) {
if ((x+y) % 2 == 0) { grid.fill(0, 255, 6); } else { grid.fill(255, 255, 0); }
grid.rect(x*90,y*90,90,90);
}
}
grid.endDraw();
textFont(createFont("SansSerif",30));
textAlign(CENTER,CENTER);
noLoop();
}
void draw() {
background(grid);
int randomNum = int(random(1,91));
fill(0);
for (int y=0; y<3; y++) {
for (int x=0; x<3; x++) {
text(randomNum++, x*90+45,y*90+45);
}
}
}
void mousePressed() {
redraw();
}

virtualboy

Re: Random number grid, loops needed!

2 years ago

Ah ok I was getting confused with trying to construct the grid in setup not draw(). So the construction of the grid is done by setting out the grid dimensions in setup, then placing the verticle and horizontal lines in draw at 1/3 intervals?
Also what would you describe the method as that you used to construct the grid in draw() ?

Top Reply