Ah, a little morning challenge! I hope this is not homework...
Just in case, I give only the start of a possible solution. This evening, I will show the final solution. I invite you to try a solution of your own in the meanwhile (if you are not in the middle of the night on your side...).

Draw a simple circle:

1. void setup()
2. {
3.   size(500, 500);
4.   smooth();
5.   background(255);
6.  
7.   float cx = width / 2;
8.   float cy = height / 2;
9.   float radius = 0.75 * width / 2;
10.   float px = 0, py = 0;
11.   for (int angle = -1; angle <= 360; angle++)
12.   {
13.     float a = radians(angle);
14.     float x = cx + radius * cos(a);
15.     float y = cy + radius * sin(a);
16.     if (angle >= 0)
17.     {
18.       line(px, py, x, y);
19.     }
20.     px = x;
21.     py = y;
22.   }
23. }

You can use smaller steps too.

Hint: use a disturbance of the radius, varying it with a trigonometric function.

Here is a giant piece of code found on openprocessing, don't remember where ... sry for the credits.
Its really good to make you understand the technique.

1. PGraphics spiro;
2. PFont AndalMono;
3. float dent_P, dent_M, dent_T, dent_L, r_M, evol, vitesse, rot_M, offset, hu, colo_speed;
4. PVector p_P, p_M, p_txt, ligne;
5. int nb_dents_M, r_P;
6. boolean r_cw;
7. //*******************************************************************************************************
8. void setup()
9. {
10.   size(900,660);
11.   colorMode(HSB,1);
12.   smooth();
13.   AndalMono = loadFont("Agenda-Black-15.vlw");
14.   textFont(AndalMono, 15);
15.   strokeWeight(2);
16.   spiro = createGraphics(600,600,JAVA2D);
17.   spiro.beginDraw();
18.   spiro.colorMode(HSB,1);
19.   spiro.smooth();
20.   spiro.noFill();
21.   spiro.strokeWeight(2);
22.   spiro.endDraw();
23.   p_P        = new PVector(570,330);       // position du trou principal (le centre)
24.   r_P        = 300;                        // rayon du trou principal
25.   dent_P     = 2*PI/120.0005;              // taille en angle des dents du trou principal
26.   dent_L     = (2*PI*r_P)/120;             // largeur des dents
27.   nb_dents_M = 54;                         // nombre de dents de la piece mobile
28.   r_M        = (nb_dents_M*dent_L)/(2*PI); // rayon de la piece mobile
29.   dent_M     = 2*PI/(nb_dents_M+.0005);    // taille en angle des dents de la piece mobile
30.   p_M        = new PVector
31.     (p_P.x+sin(0)*(r_P-r_M)
32.     ,p_P.y+cos(0)*(r_P-r_M));              // position de la piece mobile
33.   dent_T     = 5;                          // taille en pixel des dents
34.   offset     = .5;
35.   vitesse    = 0.03;          // vitesse de rotation en angle autour du centre principal
36.   evol       = 0;       // evolution de la rotation autour du centre principal, en angle
37.   rot_M      = 0;               // evolution de la rotation de la piece mobile, en angle
38.   hu         = 0;
39.   p_txt      = new PVector (20,18,40);
40.   ligne      = new PVector (
41.   300+(r_P-r_M)*cos(evol-PI/2) + offset*r_M*cos(((r_P-r_M)/r_M)*evol)
42.     ,
43.   300-(r_P-r_M)*sin(evol-PI/2) + offset*r_M*sin(((r_P-r_M)/r_M)*evol));
44.   r_cw = true;
45.   colo_speed = 0;
46. }
47. //*******************************************************************************************************
48. void draw()
49. {
50.   hu= (hu+colo_speed > 1) ? hu-1+colo_speed : hu+colo_speed;
51.   background(.6,.3,1);
52.   fill(1);
53.   roue_crantee(p_P.x, p_P.y, r_P, 0, dent_P);
54.   rect(20, 435, 119, 26);
55.   image(spiro, 270, 30);
56.   fill(.6,.6,.5);
57.   textAlign(LEFT);
58.   text("THE GUIGUITROCHOID"                        ,p_txt.x,p_txt.z+p_txt.y * 0);
59.   text("The fixed cogwheel has 120 cogs."          ,p_txt.x,p_txt.z+p_txt.y * 2);
60.   text("The rolling cogwheel has:"                 ,p_txt.x,p_txt.z+p_txt.y * 4);
61.   text("cogs and his rolling speed is:"            ,p_txt.x,p_txt.z+p_txt.y * 6);
62.   text("radian per frame."                         ,p_txt.x,p_txt.z+p_txt.y * 8);
63.   text("The drawing point inside"                  ,p_txt.x,p_txt.z+p_txt.y * 10);
64.   text("the rolling cogwheel"                      ,p_txt.x,p_txt.z+p_txt.y * 11);
65.   text("is farther from its center"                ,p_txt.x,p_txt.z+p_txt.y * 12);
66.   text("time its radius."                          ,p_txt.x,p_txt.z+p_txt.y * 14);
67.   text("The framerate is "+round(frameRate)+" fps.",p_txt.x,p_txt.z+p_txt.y * 17);
68.   text("The framecount is "+round(frameCount)      ,p_txt.x,p_txt.z+p_txt.y * 19);
69.   text("The color cycling speed is"                ,p_txt.x,p_txt.z+p_txt.y * 26);
70.   text("cycle per frame."                          ,p_txt.x,p_txt.z+p_txt.y * 28);
71.   text("Press h to hide or unhide"                 ,p_txt.x,p_txt.z+p_txt.y * 30);
72.   text("the rolling cogwheel."                     ,p_txt.x,p_txt.z+p_txt.y * 31);
73.   text("Press the space bar to erase the drawing." ,p_txt.x,p_txt.z+p_txt.y * 33);
74.   fill(hu,1,1);
75.   text(" o < hue > p"                              ,p_txt.x,p_txt.z+p_txt.y * 23);
76.   fill(.6,1,.3);
77.   text("a < "+nb_dents_M+" > z"                    ,p_txt.x,p_txt.z+p_txt.y * 5);
78.   text("q < "+vitesse+" > s"                       ,p_txt.x,p_txt.z+p_txt.y * 7);
79.   text("w < "+offset+" > x "                       ,p_txt.x,p_txt.z+p_txt.y * 13);
80.   text("l < "+colo_speed+" > m "                   ,p_txt.x,p_txt.z+p_txt.y * 27);
81.   stroke(.6,.6,.5);
82.   noFill();
83.   rect(1, 1, width-2 , height-2);
84.   ellipse(p_P.x, p_P.y, r_P*2+dent_T*4, r_P*2+dent_T*4);
85.   evol = evol+vitesse;
86.   p_M.x = p_P.x+sin(evol)*(r_P-r_M);
87.   p_M.y = p_P.y+cos(evol)*(r_P-r_M);
88.   rot_M = -evol*(r_P-r_M)/r_M;
89.   if (r_cw == true)
90.   {
91.     fill(.6,.6,1,.5);
92.     roue_crantee(p_M.x, p_M.y, r_M, rot_M, dent_M);
93.     noFill();
94.     ellipse(p_M.x, p_M.y, r_M*2-dent_T*4, r_M*2-dent_T*4);
95.     line(
96.     p_P.x+(r_P-r_M)*cos(evol-PI/2) + (r_M-dent_T*2)*cos(((r_P-r_M)/r_M)*evol),
97.     p_P.y-(r_P-r_M)*sin(evol-PI/2) + (r_M-dent_T*2)*sin(((r_P-r_M)/r_M)*evol),
98.     p_P.x+(r_P-r_M)*cos(evol-PI/2) - (r_M-dent_T*2)*cos(((r_P-r_M)/r_M)*evol),
99.     p_P.y-(r_P-r_M)*sin(evol-PI/2) - (r_M-dent_T*2)*sin(((r_P-r_M)/r_M)*evol)
100.       );
101.     fill(hu,1,1);
102.     ellipse(
103.     p_P.x+(r_P-r_M)*cos(evol-PI/2) + offset*r_M*cos(((r_P-r_M)/r_M)*evol)
104.       ,
105.     p_P.y-(r_P-r_M)*sin(evol-PI/2) + offset*r_M*sin(((r_P-r_M)/r_M)*evol)
106.       , 7, 7);
107.   }
108.   spiro.beginDraw();
109.   spiro.stroke(hu,1,1);
110.   spiro.line(
111.   ligne.x
112.     ,
113.   ligne.y
114.     ,
115.   300+(r_P-r_M)*cos(evol-PI/2) + offset*r_M*cos(((r_P-r_M)/r_M)*evol)
116.     ,
117.   300-(r_P-r_M)*sin(evol-PI/2) + offset*r_M*sin(((r_P-r_M)/r_M)*evol)
118.     );
119.   spiro.endDraw();
120.   ligne.x= 300+(r_P-r_M)*cos(evol-PI/2) + offset*r_M*cos(((r_P-r_M)/r_M)*evol);
121.   ligne.y= 300-(r_P-r_M)*sin(evol-PI/2) + offset*r_M*sin(((r_P-r_M)/r_M)*evol);
122. }
123. //*******************************************************************************************************
124. void roue_crantee(float p_x, float p_y, float rayon, float rot, float dent)
125. {
126.   beginShape();
127.   vertex(
128.   p_x   + sin(rot+0)            * (rayon+dent_T)  ,  p_y + cos(rot+0)            * (rayon+dent_T)
129.     );
130.   for (float i = (dent); i < (2*PI); i = i+(dent)) {
131.     bezierVertex(
132.     p_x + sin(rot+i-(dent/6*5)) * (rayon+dent_T)  ,  p_y + cos(rot+i-(dent/6*5)) * (rayon+dent_T)
133.       ,
134.     p_x + sin(rot+i-(dent/6*4)) * (rayon-dent_T)  ,  p_y + cos(rot+i-(dent/6*4)) * (rayon-dent_T)
135.       ,
136.     p_x + sin(rot+i-(dent/6*3)) * (rayon-dent_T)  ,  p_y + cos(rot+i-(dent/6*3)) * (rayon-dent_T)
137.       );
138.     bezierVertex(
139.     p_x + sin(rot+i-(dent/6*2)) * (rayon-dent_T)  ,  p_y + cos(rot+i-(dent/6*2)) * (rayon-dent_T)
140.       ,
141.     p_x + sin(rot+i-(dent/6))   * (rayon+dent_T)  ,  p_y + cos(rot+i-(dent/6))   * (rayon+dent_T)
142.       ,
143.     p_x + sin(rot+i)            * (rayon+dent_T)  ,  p_y+cos(rot+i)              * (rayon+dent_T)
144.       );
145.   }
146.   endShape();
147. }
148. //*******************************************************************************************************
149. void keyPressed() {
150.   switch(key) {
151.   case 'a':
152.     nb_dents_M = max(nb_dents_M-1,10);
153.     r_M        = (nb_dents_M*dent_L)/(2*PI);
154.     dent_M     = 2*PI/(nb_dents_M+.0005);
155.     break;
156.   case 'z':
157.     nb_dents_M = min(nb_dents_M+1,120);
158.     r_M        = (nb_dents_M*dent_L)/(2*PI);
159.     dent_M     = 2*PI/(nb_dents_M+.0005);
160.     break;
161.   case 'q':
162.     vitesse = max(vitesse-.001,-0.3);
163.     break;
164.   case 's':
165.     vitesse = min(vitesse+.001,0.3);
166.     break;
167.   case 'w':
168.     offset= max(offset-.01,0);
169.     break;
170.   case 'x':
171.     offset = min(offset+.01,.9);
172.     break;
173.   case 'o':
174.     hu= (hu+0.003 > 1) ? hu-.997 : hu+0.003;
175.     break;
176.   case 'p':
177.     hu= (hu-0.003 < 0) ? hu+.997 : hu-0.003;
178.     break;
179.   case 'l':
180.     colo_speed= max(colo_speed-.0001,0);
181.     break;
182.   case 'm':
183.     colo_speed= min(colo_speed+.0001,0.01);
184.     break;
185.   case ' ':
186.     spiro.beginDraw();
187.     spiro.noStroke();
188.     spiro.fill(1);
189.     spiro.ellipse(300,300,587,587);
190.     spiro.noFill();
191.     spiro.endDraw();
192.     break;
193.      case 'h':
194.     r_cw = (r_cw == true) ? false : true;
195.     break;
196.   default:
197.     break;
198.   }
199. }