Check if something is inside a rectangle?

Programming Questions

clankill3r

Check if something is inside a rectangle?

in Programming Questions • 2 years ago

First a image to put a visual in your brain:

I i didn't had rotation it would have been easy, point is i have.
So how can i check if something is inside the rectangle?
I want it to be done in the update() function inside the WindField class (but if it's easier to it in another way then taht's also fine).

WindField windField;

ArrayList<Rotor> rotors = new ArrayList<Rotor>();

void setup(){
size(800, 600);

windField = new WindField();

rotors.add(new Rotor(200, 300, radians(45)));
rotors.add(new Rotor(200, 300, radians(-45)));
rotors.add(new Rotor(200, 300, radians(0)));

smooth();
}

void draw(){
background(255);

for (Rotor rotor : rotors){
rotor.display();
}

windField.update();
windField.display();
}

// . . . . . . . . . . . . . .

class Rotor{

int x;
int y;
float rotation;

float Width = 100;
float Height = 400;

Rotor(int x, int y, float rotation){
    this.x = x;
    this.y = y;
    this.rotation = rotation;
}

void display(){
    pushMatrix();
    translate(x, y);
    rotate(rotation);
    rectMode(CENTER);
    fill(0, 60);
    rect(0, 0, Width, Height);
    fill(0);
    rect(0, 0, Width, 1);
    popMatrix();
}

}

class WindArrow{

int x, y;
int windedX;
int windedY;

WindArrow(int x, int y){
    this.x = x;
    this.y = y;
}

void reset(){
    windedX = x;
    windedY = y;
}

void display(){
    ellipse(windedX, windedY, 2, 2);
}

}

class WindField{

ArrayList<WindArrow> windArrows = new ArrayList<WindArrow>();

WindField(){
    for(int y = 0; y < height; y += 15){
      for(int x = 0; x < width; x += 15){
        windArrows.add(new WindArrow(x, y));
      }
    }
}

void update(){
    // reset all windArraws to it's original position
    for(WindArrow windArrow : windArrows){
      windArrow.reset();
    }

    for(Rotor rotor : rotors){
      for(WindArrow windArrow : windArrows){
        // check if the windArrow is inside the rotor rectangle
        // if so, change windArrow.windedX and windArrow.windedY
        // in the direction of the Rotor
      }
    }


}

void display(){
    noStroke();
    fill(0);
    for(WindArrow windArrow : windArrows){
      windArrow.display();
    }
};

}

Replies(8)

local_guru

Re: Check if something is inside a rectangle?

2 years ago

if you know the rotation angle and the coordinates of the rect you can rotate the the point you want to test

around the same pivot point in the opposite direction ( xr = mx + cos( radians( -alpha )) * d;

yr = my + sin( radians( -alpha )) * d; - where d is the distance of your point to the pivot point).

Then you can simply test the intersection like you would in an unrotated rectangle

thomas.di..

Re: Check if something is inside a rectangle?

2 years ago

http://wiki.processing.org/w/Using_AWT%27s_Polygon_class

clankill3r

Re: Check if something is inside a rectangle?

2 years ago

what is xr, what is mx and what is alpha?

this won't work since i use processing's rotate, but it's nice to know of
http://wiki.processing.org/w/Using_AWT%27s_Polygon_class

local_guru

Re: Re: Check if something is inside a rectangle?

2 years ago

alpha is the angle, mx and my are the pivot point you are rotating around and rx ry are the result of the rotation operation

clankill3r

Re: Check if something is inside a rectangle?

2 years ago

For every point, i have to check ( xr = mx + cos( radians( -alpha )) * d; yr = my + sin( radians( -alpha )) * d;
for every corner of the rectangle right (so 4 times)?
The pivot point your talking about, is 1 of the 4 corners right? (i ask cause i'm more fimilair with the pivot being the center of an object)

(do you know a good book to learn stuff like this?)

clankill3r

Re: Check if something is inside a rectangle?

2 years ago

I'm on my way, as you can see some red dots :)
There is only a bug in my code (or your formula).

It would be nice if you can take a look cause i have no clue of how to find it.
(the formula is used in the WindField function, void update()

WindField windField;
ArrayList<Rotor> rotors = new ArrayList<Rotor>();
void setup(){
size(800, 600);

windField = new WindField();

rotors.add(new Rotor(200, 300, radians(45)));
//rotors.add(new Rotor(200, 300, radians(-45)));
//rotors.add(new Rotor(200, 300, radians(0)));

smooth();
}
void draw(){
background(255);

for (Rotor rotor : rotors){
rotor.display();
}

windField.update();
windField.display();
}
// . . . . . . . . . . . . . .
class Rotor{

float x;
float y;
float rotation;

float rectWidth = 100;
float rectHeight = 400;

Rotor(float x, float y, float rotation){
    this.x = x;
    this.y = y;
    this.rotation = rotation;
}

void display(){
    pushMatrix();
    translate(x, y);
    rotate(rotation);
    rectMode(CENTER);
    fill(0, 60);
    rect(0, 0, rectWidth, rectHeight);
    fill(0);
    rect(0, 0, rectWidth, 1);
    popMatrix();
}

}
class WindField{

ArrayList<WindArrow> windArrows = new ArrayList<WindArrow>();

WindField(){
    for(int y = 0; y < height; y += 15){
      for(int x = 0; x < width; x += 15){
        windArrows.add(new WindArrow(x, y));
      }
    }
}

void update(){
    // reset all windArraws to it's original position
    for(WindArrow windArrow : windArrows){
      windArrow.reset();
    }

    for(Rotor rotor : rotors){

      float[][] rectCorners = getCorners(rotor);
      ellipse(rectCorners[0][0], rectCorners[0][1], 5, 5);

      for(WindArrow windArrow : windArrows){
        // check if the windArrow is inside the rotor rectangle
        // if so, change windArrow.windedX and windArrow.windedY
        // in the direction of the Rotor


        float d = dist(rotor.x, rotor.y, windArrow.x, windArrow.y);
        float mx = rotor.x;
        float my = rotor.y;

        float rx = mx + cos(radians(-rotor.rotation)) * d;
        float ry = my + sin(radians(-rotor.rotation)) * d;


        // test intersection
        if(rx < rotor.x + (rotor.rectWidth/2)){
          if(rx > rotor.x - (rotor.rectWidth/2)){
            if(ry < rotor.y + (rotor.rectHeight/2)){
              if(ry > rotor.y - (rotor.rectHeight/2)){
                windArrow.testColor = color(255, 0, 0);
              }
            }
          }
        }

      }
    }
}

float[][] getCorners(Rotor r){

    float[][] toReturn = new float[1][2];
    // right bottom
    float rectDiag = sqrt((r.rectWidth/2)*(r.rectWidth/2) + (r.rectHeight/2)*(r.rectHeight/2));
    float rectAngle = atan2(r.rectHeight/2, r.rectWidth/2);
    float cx = r.x + (rectDiag * cos(rectAngle + r.rotation));
    float cy = r.y + (rectDiag * sin(rectAngle + r.rotation));
    toReturn[0][0] = cx;
    toReturn[0][1] = cy;


    return toReturn;
}

void display(){
    noStroke();
    fill(0);
    for(WindArrow windArrow : windArrows){
      windArrow.display();
    }
};

}
class WindArrow{

int x, y;
int windedX;
int windedY;

color testColor = color(0);

WindArrow(int x, int y){
    this.x = x;
    this.y = y;
}

void reset(){
    windedX = x;
    windedY = y;
}

void display(){
    fill(testColor);
    ellipse(windedX, windedY, 2, 2);
}

}

local_guru

Re: Re: Check if something is inside a rectangle?

2 years ago

Sorry I got the rotation wrong
I corrected forular in your WindArrow.update method , now all the dots inside the rect are red.
Wikipedia article that explains rotation in 2D.

void update(){
    // reset all windArraws to it's original position
    for(WindArrow windArrow : windArrows){
      windArrow.reset();
    }

    for(Rotor rotor : rotors){

      float[][] rectCorners = getCorners(rotor);
      ellipse(rectCorners[0][0], rectCorners[0][1], 5, 5);

      for(WindArrow windArrow : windArrows){
        // check if the windArrow is inside the rotor rectangle
        // if so, change windArrow.windedX and windArrow.windedY
        // in the direction of the Rotor

        float mx = rotor.x;
        float my = rotor.y;

        float x = windArrow.x - mx;
        float y = windArrow.y - my;

        float rx = x * cos( -rotor.rotation ) - y * sin( -rotor.rotation );
        float ry = x * sin( -rotor.rotation ) + y * cos( -rotor.rotation );

        if(rx < rotor.rectWidth/2 && rx > -rotor.rectWidth/2 &&
           ry < rotor.rectHeight/2 && ry > -rotor.rectHeight/2){
           windArrow.testColor = color(255, 0, 0);
        }
      }
    }
}

clankill3r

Re: Check if something is inside a rectangle?

2 years ago

whoot this did it!!!

so many thanks, i've got it tattood.

Top Reply