calculate rotation in xyz

Programming Questions

clankill3r

in Programming Questions • 2 years ago

I want to get 3 values to use with rotateX, rotateY and rotateZ

if you have coordinates like (x, y, z) :
-33.49237 -19.30569 10.275825

and i know my center point:
0 0 0

Then how can the rotation in x, y and z be calculated.
I know there is atan2 but that's for 2d space.

Afcorse i want to make a function out of it.

Replies(6)

quarks

Re: calculate rotation in xyz

2 years ago

If you imagine a box where one corner is position 0,0,0 and the diagonally opposite corner is x,y,z. Now if you look down the z axis so the y axis is pointing up and the x axis is to the right and project the diagonal onto the x/y plane the angle of rotation about z is given by atan2(y,x).

Repeat this so you are looking down the x axis and imagine rotating the axis so that z is to the right this would make y point down (not up) - project the diagonal onto the z/y plane and the angle of rotation about the x axis is given by atan2(-y,z).

Repeat this looking down the y axis then the angle of rotation about that axis is atan2(-z,x)

I should point out that I have never tried this method so I can't guarentee results.

I have done the same sort of thing in the Shapes3D library but there I created a rotation object from a vector (used the Rot class) and then used the getAngles() method in the Rot class to return an array of 3 angles.

nardove

Re: calculate rotation in xyz

2 years ago

@quark, thats a very good picture I never visualized it that way

@clankill3r, not sure if this is exactly what you need but I will give it a go, you need to get the axis and angle of rotation, there are many way to do this, one could be (the one I use):

PVector xyzVec = new PVector( -33.49237, -19.30569, 10.275825 ); // this is your vector
PVector upVec = new PVector( 0, 1, 0 );
PVector axisOfRotation = xyzVec.cross( upVec );
float angleOfRotation = PVector.angleBetween( axisOfRotation, upVec );
axisOfRotation.normalize();
rotate( -angleOfRotation, axisOfRotation.x, axisOfRotations.y, axisOfRotation.z );

This code is from the top of my head, I remember the steps but I havent test this one so I hope it works on your end

Cheers

quarks

Re: calculate rotation in xyz

2 years ago

@nardove

Looks like a very neat solution and much better than mine but should the last line not be

rotate( -angleOfRotation, axisOfRotation.x, axisOfRotations.y, axisOfRotation.z );

nardove

Re: calculate rotation in xyz

2 years ago

Yes my bad, updated ;-)

clankill3r

Re: calculate rotation in xyz

2 years ago

That method doesn't look to complicated.
I did a attempt, i expect the line to hit the point, but it doesn't.
I must be close but i have no idea what is wrong.

import processing.opengl.*;

void setup() {
size(800, 800, OPENGL);
}

void draw() {
background(255);

pushMatrix();

translate(width/2, height/2);

rotateX(map(mouseY, 0, width, 0, TWO_PI));
rotateY(map(mouseX, 0, width, 0, TWO_PI));

stroke(0);
strokeWeight(10);
point(50, 60, 100);

PVector xyzVec = new PVector( 50, 60, 100); // this is your vector
PVector upVec = new PVector( 0, 1, 0 );
PVector axisOfRotation = xyzVec.cross( upVec );

float angleOfRotation = PVector.angleBetween( axisOfRotation, upVec );
axisOfRotation.normalize();
rotate(-angleOfRotation, axisOfRotation.x, axisOfRotation.y, axisOfRotation.z );

stroke(0, 255, 0);
line(0, 0, 300, 0);

popMatrix();
}

/*

PVector xyzVec = new PVector( -33.49237 -19.30569 10.275825 ); // this is your vector
PVector upVector = new PVector( 0, 1, 0 );
PVector axisOfRotation = xyzVec.cross( upVec );

float angleOfRotation = PVector.angleBetween( axisOfRotation, upVec );
axisOfRotation.normalize();
rotate( -angleOfRotation, axisOfRotation.x, axisOfRotations.y, axisOfRotation.z );

*/

nardove

Re: calculate rotation in xyz

2 years ago

Few things I spot that need a couple of tweaks:

1- Your matrix stack implementation is not correct, you are trying to rotateX + rotateY + axis-angle rotationg in the same transformation block dont get me wrong it is possible to do it in the same block, but other steps needs to be implemented.

2- The rotation code I post have a fix target vector in this case the xyzVec should be your target so you need to update the xyzVec to your desired point in space for the rotation to work

3- I made a mistake, the angleOfRotation should be calculated by the xyzVec and the upVec, example of this in the code below

The following code have the green line always looking at the black dot

import processing.opengl.*;
PVector xyzVec = new PVector( 50, 60, 100 ); // our target vector
void setup() {
size(800, 800, OPENGL);
}
void draw() {
background(255);
// This is the posiiton of the black point,
// we'll use a copy of this as our target vector to rotate
// I made it so the point goes to the mouse "xy" position and goes back and forward using sin() in "z"
xyzVec.x = mouseX - width / 2;
xyzVec.y = mouseY - height / 2;
xyzVec.z = sin( millis() * 0.001 ) * 300;
// Apply transformations to the point only
pushMatrix();
translate(width/2, height/2);
// Draw black point
stroke(0);
strokeWeight(10);
point(xyzVec.x, xyzVec.y, xyzVec.z);
popMatrix();
// Target vec, this is the vector we'll us to rotate
// our target is the xyzVec to targetVec is a copy of xyzVec
PVector targetVec = xyzVec.get();
targetVec.normalize();
PVector upVec = new PVector( 0, 1, 0 );
// Get axis of rotation from targetVec and the upVec
PVector axisOfRotation = targetVec.cross( upVec );
axisOfRotation.normalize();
// Get angle of rotation from targetVec and upVec
float angleOfRotation = PVector.angleBetween( targetVec, upVec );
// Apply transformation to the line and box only
pushMatrix();
translate(width/2, height/2);
// Apply rotation
rotate(-angleOfRotation, axisOfRotation.x, axisOfRotation.y, axisOfRotation.z );
// Draw green line
stroke(0, 255, 0);
line(0, 0, 0, 200);
// Draw red wireframe box
noFill();
strokeWeight(1);
stroke( 255, 0, 0 );
box( 100 );
popMatrix();
}

Hope that helps

Top Reply