Processing Forum

[0 Replies]

25-Jun-2013 12:03 PM
Forum: Programming Questions

Is it wrong of me to expect the following code to do the same thing with resetBoth set to true or false?

(processing 2.0.1)

PShape test;
PMatrix3D pm;
boolean resetBoth = false;
boolean shapeForVerts = true;

void setup() {
  size(400,400,P3D);
  frameRate(1);
  ortho();
  test = createShape(BOX, 100,100,100);
  noStroke();
  pm = doTx(test);
  if(shapeForVerts) shape(test);
}

void mouseClicked() {
  if(resetBoth) pm.reset();
  pm.apply(doTx(test));
  if(shapeForVerts) shape(test);
}

PMatrix3D doTx(PShape in) {
  if(resetBoth) in.resetMatrix();
  PVector tx = new PVector(
    random(-25,25),random(-25,25),random(-25,25));
  PVector rx = new PVector(
    random(-1,1),random(-1,1),random(-1,1));
  PMatrix3D ret = new PMatrix3D();
  tx.mult(-1);
  ret.translate(tx.x, tx.y, tx.z);
  ret.rotateX(rx.x);
  ret.rotateY(rx.y);
  ret.rotateZ(rx.z);
  tx.mult(-1);
  ret.translate(tx.x, tx.y, tx.z);
  in.applyMatrix(ret);
  return ret;
}

void draw() {
  background(204);
  translate(width*.5, height*.5);
//  shape(test);
  
  hint(DISABLE_DEPTH_TEST);
  fill(255,0,0); 
  pushMatrix();
  applyMatrix(pm);
  
  pushStyle();
  stroke(0);
  fill(255);
  box(100,100,100);
  popStyle();
  
  for(int a=0; a<8; a++) {
    pushMatrix();
    PVector cur = test.getVertex(a);
    translate(cur.x, cur.y, cur.z);
    sphere(10);
    popMatrix();
  }
  popMatrix();
  
  PVector pv = test.getVertex(0).get();
  pm.mult(pv, pv);
  fill(0,0,255);
  pushMatrix();
  translate(pv.x, pv.y, pv.z);
  sphere(5);
  popMatrix();
  hint(ENABLE_DEPTH_TEST);
}

LWJGL Renderer

[4 Replies]
- 11-Jun-2013 10:40 AM
- Forum: Core Library Questions
I noticed there is LWJGL stuff in the Processing source:
https://github.com/processing/processing/tree/master/java/libraries/lwjgl

Can anyone comment on whether this will be released? Will it be possible to embed OpenGL sketches with LWJGL's applet launcher thing?

OpenGL vertex color interpolation mode

[0 Replies]

06-May-2013 05:09 PM
Forum: Core Library Questions

I seem to recall reading about and trying an OpenGL method to get a more blended, softer look between vertex colors on irregular shapes. It seems like it was something simple like a single method to switch modes, but now I'm having trouble finding anything like that. Does anyone maybe know about something like this? Here is an example of the standard mode for testing:

import processing.opengl.*;

PVector[] test;

void setup() {
  size(400,400,OPENGL);
  colorMode(HSB);
  noStroke();
  
  test = new PVector[] {
    new PVector(1955,1754),
    new PVector(1925,1871),
    new PVector(2042,2054),
    new PVector(2000,2250),
    new PVector(1858,2495),
    new PVector(1517,2525),
    new PVector(1262,2432),
    new PVector(1268,2060),
    new PVector(1529,2126),
    new PVector(1676,1856),
    new PVector(1880,1622)};
  
  pushMatrix();
  translate(-300,-430);
  beginShape();
  for(PVector cur : test) {
    fill(random(255),255,255);
    cur.mult(.3);
    vertex(cur.x, cur.y);
  }
  endShape(CLOSE);
  popMatrix();
}

jbullet basic example

[0 Replies]
- 22-Apr-2013 04:08 PM
- Forum: Share your Work
I'm thinking about doing another project using the 3D physics library JBullet (the Java port of Bullet) and I did a very basic example today that I thought might be helpful for anyone interested in using JBullet with Processing. I had previously released the code for a game like experiment with JBullet ( https://forum.processing.org/topic/jbullet-experiment), but that code was fairly complicated. The new example is on OpenProcessing: http://www.openprocessing.org/sketch/97086
I hope its helpful. I would be interested to see more people working with this.

realtime sketch output video capture

[9 Replies]
- 17-Feb-2013 01:26 PM
- Forum: Share your Work
I just corrected a stupid error and got my third attempt at realtime sketch capture to work. I haven't tested it much at all and the code is still a little raw, but I am very pleased with the performance and convenience.

My previous attempts:
attempt one
attempt two

This third version is much more convenient because it captures directly to compressed video instead of an image sequence and, now that I have OpenGL PBOs working, using it seems to cause very little framerate penalty. I have only tested it with 720 so far though.

The process involves adding a file to the sketch you would like to capture. The code creates a temporary file and continuously overwrites it with the raw pixel data of the most recent frame. The actual video encoding is done by ffmpeg which is run via another Processing sketch that reads the same temporary file that is being written to and pipes the data to the ffmpeg process. Your PATH environment variable has to inlude ffmpeg's bin folder for this to work.

capSend.pde (put this with the sketch you want to capture)
capEncode.pde (run your sketch using capSend.pde, then this to start capturing, click to stop)

The encoding sketch is basically an ffmpeg command line that I have tailored for Vimeo. The output video filenames are hard coded and it will overwrite them without asking unless you rename them. I have only tested this on Windows and Processing 1.5.1 because those are what I use most of the time (it wont work on the 2.0 betas). I'm kind of waiting for a stable 2.0 release before trying it with that. It shouldn't be hard to convert.

The command lines could probably be less hackish if this was run on Mac or Linux. I have the option to record the currently playing audio along with the video which should be possible with just one command line but I had to do them separately and combine them after the capture because the audio would not allow the process to end and close the file properly. On Linux I'm assuming you could send the process SIGINT with the kill command and it would close correctly. Also on Windows I'm using this audio capture thing. I don't know if you can capture line in via ffmpeg on Windows, but I think you can on Linux. Anyway I have the audio disabled by default in the code.

If you try it don't forget to make sure the width(ww) and height(hh) and save and temp locations match in both files. Width and height are set to 1280 and 720 by default. The temp location defaults to C:\p5temp and the save location to a folder called test in the sketch path. I'd be happy to hear if it does or doesn't work and how it performs on your system; Also, any suggestions for the code.

OpenGL glReadPixels and PBOs

[2 Replies]
- 07-Feb-2013 08:48 AM
- Forum: Core Library Questions
In the past I have used the version of glReadPixels(...) that takes a Buffer to fill as input in an attempt to capture image sequences from Processing sketches in real-time without slowing down the interaction. I had also read about the other version of glReadPixels(...) that takes an offset instead of a buffer and is supposed to transfer pixels to a PBO (pixel buffer object) in video memory. It is apparently supposed to return immediately after starting the memory transfer.

Now I'm trying to implement a system to read back pixels using two PBOs which should have very little impact on the running sketch. (The buffer version takes about 10ms for 1280x720 which slows down a sketch that pushes 60fps to 45.) There is a nice article outlining what I am trying to do here under asynchronous read-back: http://www.songho.ca/opengl/gl_pbo.html

I'm using gl.glBufferData(pboIds[0], width*height*4, null, GL.GL_STREAM_READ); to allocate memory for the PBO. This line produces an invalid enumerant error (on GL.GL_STREAM_READ I guess). I've also tried this line with an empty buffer instead of null with the same results. When I try to map the read-back buffer I get this GLExcpetion: "Error: buffer size returned by glGetBufferParameterivARB was zero;"

Here is all the GL stuff that I'm having trouble with now:

void setup() {
...
pboIds = new int[2];
gl.glGenBuffers(2, pboIds, 0);
gl.glBindBuffer(GL.GL_PIXEL_PACK_BUFFER, pboIds[0]);
gl.glBufferData(
    pboIds[0], width*height*4, null, GL.GL_STREAM_READ);
// gl.glGetError();
gl.glBindBuffer(GL.GL_PIXEL_PACK_BUFFER, pboIds[1]);
gl.glBufferData(
    pboIds[1], width*height*4, null, GL.GL_STREAM_READ);
// gl.glGetError();
gl.glBindBuffer(GL.GL_PIXEL_PACK_BUFFER, 0);
}

void draw() {
...
int vpboInd = frameCount%2;
int cpboInd = (frameCount+1)%2;
gl.glReadBuffer(GL.GL_FRONT);
gl.glBindBuffer(GL.GL_PIXEL_PACK_BUFFER, pboIds[vpboInd]);
gl.glReadPixels(
    0,0,width,height,GL.GL_BGRA,GL.GL_UNSIGNED_BYTE,0L);
gl.glBindBuffer(GL.GL_PIXEL_PACK_BUFFER, pboIds[cpboInd]);
try {
    gl.glMapBuffer(GL.GL_PIXEL_PACK_BUFFER, GL.GL_READ_ONLY);
} catch(Throwable ex) {ex.printStackTrace();}
gl.glUnmapBuffer(GL.GL_PIXEL_PACK_BUFFER);
gl.glBindBuffer(GL.GL_PIXEL_PACK_BUFFER, 0);
}

Has anyone worked with PBOs, tried this before, or see any problems with this code?

my first 3d printed system

[3 Replies]
- 19-Jan-2013 10:59 AM
- Forum: Share your Work
I used a lot of follow through on a project and actually had it 3d printed via Shapeways. The core code is quite simple, but it took a lot of refinement to get nice clean models. I used Java's built in Area type with its CAG boolean operations to get various polygons. Poly2Tri for general triangulation and my own code for tri or quad strips was used to get valid Hemesh meshes via HEC_FromFaceList. I tried various Hemesh modifiers, HEM_Wireframe for example.

The Shapeways prints turned out so well I even decided to put one variation up for sale. If anyone orders it I can easily produce a unique model from my system and upload as part of a series using the Shapeways co-creator system. http://www.shapeways.com/model/844750/gw01a.html

I'd be interested to see more code-generated products on Shapeways that aren't purely mathematical. Anyway, thanks for checking mine out.

super accurate upcoming 3D sensing device demoed with MSAFluid

[2 Replies]
- 24-Jun-2012 11:40 AM
- Forum: General Discussion
http://youtu.be/XZNh3qvVE4s

I never got around to buying a Kinect, but I put in my pre-order for this thing. Looks quite impressive.

drop-in image sequence sketch capture for 2.0 OGL

[2 Replies]

23-Jun-2012 07:11 PM
Forum: Share your Work

I am tinkering with a method to capture video output from Processing sketches using a TGA image sequence and its starting to show promise. Creating a new tab in any P3D (OpenGL) sketch and adding the following code automatically sends the raw visual output of the sketch to a single file overwriting it with each new frame. Running the second piece of code from a separate PDE (separate process) begins reading the raw data in the file once each time the draw loop runs and saving each frame to a separate TGA file.

I have tried to make it as efficient as possible to enable the capture of interactive sketches without excessive slowdown. I have not tested this code heavily and it is still somewhat unfinished and uncommented.

Using Processing's smooth(...) method causes an error (from JOGL I believe "cannot lock native surface" or something like that). On Windows you can work around this by adding a profile in NVidia control panel for the java.exe that Processing is using and setting anti-aliasing options there. I believe AMD has something similar.
It looks like there are some dropped frames between the first and the second captured frames. I have not looked into it yet. Past that the capture rate seems to be quite consistent.
I have occasionally seen glitches in the output TGAs of one of my testing setups. It seems to either affect most of the frames of a run or none. Have not tried to fix it yet.
Be sure to close fileCapSave.pde with the window button. It waits a second to make sure the final frame is properly written.

fileCapSend.pde
add this to a new tab in the sketch you want to capture from

PApplet fileCapSendPAppletRef;
{
  import javax.media.opengl.GLContext;
  import javax.media.opengl.GL;
  import java.nio.ByteBuffer;
  import java.nio.channels.FileChannel;
  
  fileCapSendPAppletRef = this;
  new Thread(new Runnable() {
    public void run() {
      while(frameCount < 1) {}
      new FileCapSend();
    }
  }).start();
}

public class FileCapSend {
  
  class SendThread extends Thread {
    public void run() {
      for(;;) {
        if(!run) break;
        if(cap) {
          glc.makeCurrent();
          gl.glReadPixels(
            0, 0, width, height, 
            GL.GL_RGBA, GL.GL_UNSIGNED_BYTE, bb);
          glc.release();
          try {
            fc.write(bb);
            fc.position(0);
          } catch(Throwable fex) {fex.printStackTrace();}
          bb.clear();
          cap = false;
        } else {
          try {
            sleep(1);
          } catch(Throwable ex) {ex.printStackTrace();}
        }
      }
    }
  }
    
  PApplet p5;
  PGraphicsOpenGL pg;
  GLContext glc;
  GL gl;
  ByteBuffer bb;
  String tmpLoc = "C:\\p5tmp";
  FileChannel fc;
  boolean run = true;
  boolean registered, cap;
  SendThread sendThread;
  
  FileCapSend() {
    p5 = fileCapSendPAppletRef;
    pg = (PGraphicsOpenGL)p5.g;
    glc = pg.pgl.context;
    gl = pg.pgl.gl;
    bb = ByteBuffer.allocateDirect(width*height*4);
    
    if(run) beginCap();
  }
  
  void beginCap() {
    try {
      File prev = new File(tmpLoc);
      if(prev.exists()) prev.delete();
      fc = new RandomAccessFile(tmpLoc, "rw").getChannel();
    } catch(Throwable ex) {
      ex.printStackTrace();
      run = false;
      return;
    }
    sendThread = new SendThread();
    sendThread.start();
    register();
  }
  
  void register() {
    p5.registerPost(this);
    registered = true;
  }
  
  void endCap() {
    p5.unregisterPost(this);
    try {
      fc.close();
    } catch(Throwable ex) {ex.printStackTrace();}
  }

  public void post() {
    if(!run && registered) {
      endCap();
      return;
    }
    cap = true;
  }
}

fileCapSave.pde
add this to a new PDE, make sure the tmpLoc variable (points to the temp file) is the same here and in fileCapSend.pde, also set ww and hh to the width and height of the sketch you are capturing and change the saveLoc (location where frames will be saved, default is [fileCapSave.pde sketchPath]\test\) if you want

import processing.opengl.PGL;
import java.nio.ByteOrder;
import java.nio.ByteBuffer;
import java.nio.channels.FileChannel;

int ww = 1280;
int hh = 720;
String tmpLoc = "C:\\p5tmp";
String saveLoc = sketchPath("test\\");
ByteBuffer bb;
FileChannel fc;
int ind = -1;
PImage pi;

void setup() {

  try {
    fc = new RandomAccessFile(tmpLoc, "rw").getChannel();
    fc.map(FileChannel.MapMode.READ_ONLY, 0, ww*hh*4);
    bb = ByteBuffer.allocateDirect(ww*hh*4);
    bb.order(ByteOrder.nativeOrder());
  } catch(Throwable ex) {ex.printStackTrace();}
  
  pi = createImage(1280,720,RGB);
  pi.loadPixels();
}

void draw() {  
  ind++;
  try {
    fc.position(0);
    fc.read(bb);
  } catch(Throwable ex) {ex.printStackTrace();}  
  regularSave();
  bb.clear();
}

void regularSave() {
  bb.rewind();
  bb.asIntBuffer().get(pi.pixels);
  PGL.nativeToJavaRGB(pi.pixels, ww, hh);
  pi.save(saveLoc+nf(ind, 6)+".tga");
}

void exit() {
  try {
    Thread.currentThread().sleep(500);
  } catch(Throwable ex) {}
  super.exit();
}

glReadPixels(...) appears to output only red, white, and black

[5 Replies]
- 21-Jun-2012 05:32 PM
- Forum: Contributed Library Questions
I'm trying to get raw pixel data in a ByteBuffer with glReadPixels(...).

gl.glReadPixels(
0, 0, width, height,
GL.GL_RGBA, GL.GL_UNSIGNED_BYTE, bb);

When I later try to construct an image from the bytes,

bb.asIntBuffer().get(pi.pixels);
PGL.nativeToJavaARGB(pi.pixels, 1280, 720);

I get only red, white, and black. Greens and blues appear black. Anyone know what I'm doing wrong here?

sketch with frameRate(59) uses much less processor than same sketch without

[3 Replies]
- 24-Mar-2012 01:28 PM
- Forum: General Discussion
I just noticed this with 2.0a1 and P3D (GL2). I have a simple sketch that draws a shape with about twenty verts using cureVertex and regular vertex calls and calculates a curve tangent. When I add frameRate(59) to this sketch it goes from showing 25%+ processor usage in task manager, to around 1-5%. If I insert frameRate(60), which is the default behavior as far as I know, usage is back to 25% and above. Anyone else notice this or have any idea why it is happening?

By the way, I just tested it with a blank sketch that only clears the background with the same results.

JBullet Experiment

[4 Replies]
- 29-Dec-2011 12:02 PM
- Forum: Share your Work
I have uploaded a small project I did a while back while experimenting with the JBullet physics engine and Processing. I remember JBullet being a little finicky to set up and thought it would be nice to release this working example and maybe get a little feedback. The example also includes setting up a static triangle mesh collision object in JBullet and a "raw mouse" setup using java.awt.Robot.

It is something of a game or could be an actual game if developed further. It consists of two balls on top of each other. Hold the left mouse button and drag to apply force to the top ball in the direction of the mouse movement. Try to keep the top ball from touching the ground for as long as possible. The game restarts automatically when you fail. Also it is pause-able by pressing 'p' or the pause key. This releases the mouse. Start dragging again to continue. Press 'r' to reset the high score. Escape exits immediately.

http://www.r6753.com/balanceBalls.windows32.zip
http://www.r6753.com/balanceBalls.macosx.zip
http://www.r6753.com/balanceBalls.linux32.zip

I guess I am pretty good at it from all the practice while developing it. It is easiest with an actual mouse and a large area to move it through. On my system, it sometimes fails to render one of the balls and it has runtime exceptions that I am ignoring. I haven't tested it on Mac or Linux.

The code is messy and has no comments, but I can break it down and try to help if anyone else wants to attempt to work with JBullet. I'd like to get back into it and try a dynamic triangle mesh example next. Any feedback is appreciated, especially weather or not it works on Mac and Linux.

transforms per frame outside of Processing (manual), any better way?

[0 Replies]
- 21-Jan-2011 12:58 PM
- Forum: Programming Questions
I always wondered how Processing handles transformations so that a translate, for example, doesn't get repeated each time the function is called (each frame). Every time I try to set up my own translation I have to use translate(mouseX-pmouseX, mouseY-pmouseY) to get the same effect of Processing's translate(mouseX, mouseY). The only other way I've been able to do it is the following:
1. void move(float x, float y) {
2. if(x != tx || y != ty) {
3. AffineTransform ng = AffineTransform.
4. getTranslateInstance((double)-tx,(double)-ty);
5. transform(ng);
6. AffineTransform mv = AffineTransform.
7. getTranslateInstance((double)x, (double)y);
8. transform(mv);
9. tx = x;
10. ty = y;
11. }
12. }
I'm pretty sure that is not how Processing does it. Does anyone know how that stuff works?

v3ga blobDetection jar

[9 Replies]
- 10-Dec-2010 12:55 PM
- Forum: Contributed Library Questions
Would anyone be able to provide the jar for v3ga's blobDetection library? When I try to download from his site I get six java source code files in a zip. I tried unsuccessfully to compile them myself. Thanks a lot.

add file, capture sketch output, threaded for less slowdown

[25 Replies]
- 14-Sep-2010 05:46 PM
- Forum: Share your Work
This isn't exactly a tool or library yet, but I thought this was the place to post it.

Saving the following code as a pde and adding it to a sketch should allow the sketch output to be captured to an image sequence without any further modification to the sketch itself. After adding the file, running the sketch should produce an extra, minimized window. When the window is "de-minimized" sketch output should be recorded, minimizing should stop recording.

This is in very early development, but should work with some quirks. I've experimented with various image formats and methods of saving them and found that Targa(tga) files work best for what I'm doing. Some formats produce more slowdown in the sketch and general strangeness in the output especially for larger image sizes. I think the problems may have something to do with the image writing functions not being entirely compatible with threading. This is the first time I've tried threading so I really don't know.
1. PApplet p = this ;
2. {
4. import javax.imageio.ImageIO;
5. import java.awt. image .RenderedImage;
6. import java.awt.event.WindowEvent;
7. import java.awt.event.WindowStateListener;
8. import java.awt.Color;
9. import processing.app.Base;
11. new ThreadWriter();
12. // new Thread(
13. // new Runnable() {
14. // boolean running = true;
15. // public void run() {
16. // while(running) {
17. // if(frameCount==1) {
18. // p.registerDraw(new ThreadWriter());
19. // running = false;
20. // }
21. // }
22. // }
23. // }
24. // ).start();
26. }
27. public class ThreadWriter implements WindowStateListener {
28. int vidRate;
29. int ind;
30. long fTime;
31. File render;
32. Frame f;
33. String stopped = "p5cap : stopped" ;
34. String recording = "p5cap : " ;
35. int sz;
37. ThreadWriter() {
38. vidRate = 0;
39. // Base.initPlatform();
40. f = setupFrame();
41. f.addWindowStateListener( this );
42. }
44. Frame setupFrame() {
45. Frame frame = new Frame();
46. frame.setSize(200,200);
47. frame.setTitle(stopped);
48. frame.setExtendedState(frame.ICONIFIED);
49. frame.setLocation( screen . width -200,0);
50. frame.setBackground( new Color(255,0,0));
51. frame. setVisible ( true );
52. return frame;
53. }
55. public void windowStateChanged(WindowEvent e) {
56. if (e.getNewState()==1) {
57. p.unregisterDraw( this );
58. f.setTitle(stopped);
59. }
60. if (e.getNewState()==0) {
61. if (render== null ) render = new File(p.sketchPath( "render" ));
62. if (!render.exists()) render.mkdir();
63. fTime = System.nanoTime();
64. p.registerDraw( this );
65. }
66. }
68. public void draw () {
69. // println(Thread.activeCount());
70. double cTime = System.nanoTime()-fTime;
71. if (cTime >= vidRate*.001) {
72. new Thread (
73. new Runnable() {
74. public void run() {
75. // p.save(render.getAbsolutePath()+"/"+nf(ind++,6)+".tiff");
76. p.g. save (render.getAbsolutePath()+ "/" + nf (ind++,6)+ ".tga" );
77. // try {
78. // ImageIO.write((RenderedImage)p.g.getImage(), "png",
79. // createOutput("render/"+nf(ind++,6)+".png"));
80. // ImageIO.write((RenderedImage)p.g.getImage(), "jpg",
81. // new File(render.getAbsolutePath()+"/"+nf(ind++,6)+".jpg"));
82. // }
83. // catch(IOException e){println(e);}
84. fTime = System.nanoTime();
85. }
86. }
87. ).start();
88. }
89. // new Thread(
90. // new Runnable() {
91. // public void run() {
92. // sz = Base.calcFolderSize(new File(p.sketchPath("render")));
93. // sz /= 1048576; // sz/1024/1024 MB
94. // f.setTitle(recording+sz+"MB");
95. // }
96. // }
97. // ).start();
98. }
100. }
I had a little trouble making videos out of the image sequence to, but eventually found a decent process for H264:
Encode to lossless video with ffmpeg using QuickTime "Animation" codec:

ffmpeg -i %06d.tga -vcodec qtrle output.mov

Apparently libx264, the library ffmpeg uses to encode H264, only handles the YUV colorspace so it messes up the color on images in RGB format. I had this problem and others trying to use ffmpeg to go directly from image sequence or my mov to H264 encoding. I streamed the mov through VLC to an H264 encoded mp4 instead. Replace the bitrate part of the output string with crf=18 or so.
I appreciate people trying it out and giving feedback.

notify tool when sketch is about to run

[0 Replies]
- 10-Sep-2010 11:55 AM
- Forum: Library and Tool Development
Does anyone know of a way to run code from a Tool when a sketch is about to be run or be presented? A lot of the stuff in the source pertaining to this is protected / private and I think it would be quite a hack to notify a Tool that handleRun() is being called.

sketch video catpure with ffmpeg and xuggle

[2 Replies]
- 27-Aug-2010 05:21 PM
- Forum: Library and Tool Development
I found an open source video library for Windows, Mac, and Linux today called Xuggle . Xuggle is basically a Java wrapper for ffmpeg . I was able to successfully get it capturing video from a simple test sketch in mpeg4 fairly smoothly even up to 1024 by 768.Whatever automatic settings Xuggle applies look decent in this case although it seemed to drop green from the grays making the image appear a little red / violet. The only thing I set was frame rate.

To get it working (on Windows), I downloaded and installed Xuggle and copied the files in Xuggle/share/java/jars to a folder called xuggle in my Processing libraries folder and renamed xuggle-zuggler.jar to just xuggle.jar to match. Following is my test code:

import processing.opengl.*;

import com.xuggle.xuggler.*;
import com.xuggle.mediatool.*;

import java.awt. image.BufferedImage;
import java.awt. image.ImageObserver;
import java.util.concurrent.TimeUnit;

IMediaWriter imw;
IStreamCoder isc;
BufferedImage bgr;
int vidRate;
long sTime;
long fTime;

void setup() {
   size(1024,768);
  vidRate = 30;

   ellipseMode( CENTER);

  imw = ToolFactory.makeWriter(sketchPath( "output.mp4"));
  imw.addVideoStream(0,0, ICodec.ID.CODEC_ID_MPEG4,
    IRational.make(( double)vidRate), width, height);
  isc = imw.getContainer().getStream(0).getStreamCoder();

  bgr = new BufferedImage( width, height,
    BufferedImage.TYPE_3BYTE_BGR);
  sTime = fTime = System.nanoTime();
}

void draw() {
   background( sin( frameCount/25f)*255);
   ellipse( mouseX, mouseY, 100,100);
   loadPixels();

   long cTime = System.nanoTime()-fTime;
   if(cTime >= ( double)1000/vidRate) {
//    bgr.setRGB(0, 0, width, height, pixels, 0, width);
    bgr.getGraphics().drawImage(g.getImage(), 0, 0,
       new ImageObserver() {
         public boolean imageUpdate(Image i, int a, int b, int c, int d, int e){ return true;} });
    imw.encodeVideo(0, bgr, System.nanoTime()-sTime,
      TimeUnit.NANOSECONDS);
    fTime = System.nanoTime();
  }
}

void mouseClicked() {
  imw. close();
   exit();
}
If you try this make sure to click to end the video so the file gets finished properly. I would like to use this to develop a tool that would allow video to be captured from any sketch without adding extra code. I hear there may be a new core video library coming , though. I also had trouble with GSVideo for this purpose.

Activity Trend