So i was bored and remembered that i've never programmed a cellular automata (As they're apparently called) so i made one. I am happy with how short and fast (on my computer, running it fullscreen - 1920*1080) i managed to make the program so i thought i'd post it:

1. int[] rules = {0,1,0,0,1,0,1,0};
2. void setup(){
3.   size(screenWidth,screenHeight);
4.   background(255);
5.   loadPixels();
6.   pixels[width/2] = color(0);
7.   reset();
8. }
9. void draw(){
10.   for(int y = 1;y<height;y++){
11.     for(int i = 1;i< width-1;i++){
12.       pixels[y*width+i] = color(255*rules[((((0xff&pixels[(y-1)*width+i-1])/255<<1)+(0xff&pixels[(y-1)*width+i])/255)<<1)+(0xff&pixels[(y-1)*width+i+1])/255]);
13.     }
14.   }
15.   updatePixels();
16.   noLoop();
17. }
18. void reset(){
19.   for(int i = 0;i<rules.length;i++){
20.     rules[i] = round(random(1));
21.   }
22. }
23. void mouseReleased(){
24.   loop();
25.   reset();
26. }

so what do you guys think? can it be done any shorter? :)

Good day,
This is a 3d image wall sketch that i created. it uses the flickr api to get the last 100 added images and displays them.
I can't really think of that much to say about this project... basically i wanted to see how it was like to work with xml files in processing so i made this. I know these aren't anything new but i haven't seen one i processing so i thought i'd post it, also i haven seen many exhibition posts lately...

Copy-paste the code to try it :)
Controlls: use the mouse to move and the scroll to zoom

1. //Processing Image Wall
   
2. //By Gustav Bjordal
   
3. import processing.opengl.*;
4. class Photo{
5.   PImage img;
6.   float x;
7.   float y;
8.   float z;
9.   float smallWidth;
10.   float smallHeight;
11.   float currentWidth;
12.   float currentHeight;
13.   int id;
14.   boolean loading;
15.   public Photo(String url,float nx,float ny,int _id){
16.     img = requestImage(url);
17.     id = _id;
18.     loading = true;
19.     x = nx;
20.     y = ny;
21.     z = 0;
22.   }
23.   public void doneLoading(){
24.     loading = false;
25.     if(img.width > img.height){
26.       currentWidth = smallWidth = 120;
27.       currentHeight = smallHeight = img.height*(120/(float)img.width);
28.     }
29.     else{
30.       currentWidth = smallWidth = img.width*(120/(float)img.height);
31.       currentHeight = smallHeight = 120;
32.     }
33.   }
34.   public void drawImage(PGraphics g){
35.     g.translate(0,0,z);
36.     g.beginShape();
37.     g.texture(img);
38.     g.vertex(x*120 + (120-currentWidth)/2, y*120+(120-currentHeight)/2, 0, 0);
39.     g.vertex(x*120+currentWidth+(120-currentWidth)/2, y*120+(120-currentHeight)/2, 1, 0);
40.     g.vertex(x*120+currentWidth+(120-currentWidth)/2, y*120+currentHeight+(120-currentHeight)/2, 1, 1);
41.     g.vertex(x*120+(120-currentWidth)/2, y*120+currentHeight+(120-currentHeight)/2, 0, 1);
42.     g.endShape();
43.     g.translate(0,0,-z);
44.   }
45.   public void drawBuffer(PGraphics b){
46.     b.translate(0,0,z);
47.     b.beginShape();
48.     b.noStroke();
49.     b.fill(-(id + 2));
50.     b.vertex(x*120 + (120-currentWidth)/2, y*120+(120-currentHeight)/2);
51.     b.vertex(x*120+currentWidth+(120-currentWidth)/2, y*120+(120-currentHeight)/2);
52.     b.vertex(x*120+currentWidth+(120-currentWidth)/2, y*120+currentHeight+(120-currentHeight)/2);
53.     b.vertex(x*120+(120-currentWidth)/2, y*120+currentHeight+(120-currentHeight)/2);
54.     b.endShape(CLOSE);
55.     b.translate(0,0,-z);
56.   }
57. }
58. int NUMOFIMAGES = 100;
59. PGraphics buffert;
60. XMLElement xml;
61. ArrayList photos;
62. int worldWidth;
63. int worldHeight;
64. float worldX;
65. float worldY = 100;
66. float worldZ;
67. float focusX;
68. float focusY;
69. float destZ = 100;
70. float destY;
71. float destX;
72. float worldRotateX;
73. float worldRotateY;
74. float worldRotateDestX;
75. float worldRotateDestY;
76. void setup(){
77.   size(1920,800,OPENGL); //sorry about the size, feel free to change it to something that fits your screen
78.   buffert = createGraphics(width,height,P3D);
79.   photos = new ArrayList();
80.   xml = new XMLElement(this, "http://api.flickr.com/services/rest/?method=flickr.photos.getRecent&api_key=99835d77b01b776f3115b56180c6c4f4&per_page="+NUMOFIMAGES);
81.   XMLElement photoList = xml.getChild(0);
82.   int childCount = photoList.getChildCount();
83.   int perRow = childCount/5;
84.   worldWidth = (perRow+1)*120;
85.   worldHeight = 6*120;
86.   int yPos = 0;
87.   for(int i = 0; i < childCount;i++){
88.     String farm = photoList.getChild(i).getAttribute("farm");
89.     String server = photoList.getChild(i).getAttribute("server");
90.     String id = photoList.getChild(i).getAttribute("id");
91.     String secret = photoList.getChild(i).getAttribute("secret");
92.     if(i%perRow == 0){
93.       yPos++;
94.     }
95.     photos.add(new Photo("http://farm"+farm+".static.flickr.com/"+server+"/"+id+"_"+secret+".jpg",i%perRow,yPos,i+1));
96.   }
97.   imageMode(CENTER);
98.   textureMode(NORMALIZED);
99.   noStroke();
100.   smooth();
101.   worldZ = 100;
102.   addMouseWheelListener(new java.awt.event.MouseWheelListener() {
103.     public void mouseWheelMoved(java.awt.event.MouseWheelEvent evt) {
104.       mouseWheel(evt.getWheelRotation());
105.     }
106.   }
107.   );
108. }
109. void draw(){
110.   background(0);
111.   if(worldZ < 300){
112.     worldRotateDestX = ((PI/2)*mouseY/height-PI/4);
113.     worldRotateDestY = ((PI/2)*mouseX/width-PI/4);
114.     destY = (height-worldHeight)/2-60;
115.     destY += -(mouseY-height/2)/2;
116.   }
117.   else{
118.     worldRotateDestX = 0;
119.     worldRotateDestY = 0;
120.     destY = -(mouseY-height/2);
121.   }
122.   worldY += (destY-worldY)/max((worldZ-100),25);
123.   worldZ += (destZ-worldZ)/50;
124.   worldX -= (mouseX-width/2)/max((worldZ-50),25);
125.   worldX = min(max(worldX,-worldWidth+width/2),width/2);
126.   worldY = min(max(worldY,-worldHeight+height/2),height/2);
127.   worldRotateX += (worldRotateDestX-worldRotateX)/15;
128.   worldRotateY += (worldRotateDestY-worldRotateY)/15;
129.   translate(width/2,height/2,0);
130.   rotateX(worldRotateX);
131.   rotateY(-worldRotateY);
132.   scale(worldZ/100);
133.   translate(-width/2,-height/2,-0);
134.   boolean toggled = false;
135.   translate(worldX,worldY,0);
136.   buffert.beginDraw();
137.   buffert.background(color(255));
138.   buffert.translate(width/2,height/2,0);
139.   buffert.rotateX(worldRotateX);
140.   buffert.rotateY(-worldRotateY);
141.   buffert.scale(worldZ/100);
142.   buffert.translate(-width/2,-height/2,-0);
143.   buffert.translate(worldX,worldY,0);
144.   for(int i = 0; i< photos.size();i++){
145.     Photo p = (Photo)photos.get(i);
146.     p.drawBuffer(buffert);
147.   }
148.   buffert.endDraw();
149.  
150.   for(int i = 0; i< photos.size();i++){
151.     Photo p = (Photo)photos.get(i);
152.     if(p.loading && p.img.width >0){
153.       p.doneLoading();
154.     }
155.     if(buffert.get(mouseX,mouseY) == -(p.id+2)){
156.       p.currentWidth = p.smallWidth*1.5;
157.       p.currentHeight = p.smallHeight*1.5;
158.       p.z =10;
159.       toggled = true;
160.     }
161.     else{
162.       p.currentWidth = p.smallWidth;
163.       p.currentHeight = p.smallHeight;
164.       p.z = 0;
165.     }
166.     p.drawImage(g);
167.   }
168. }
169. void mouseWheel(int delta) {
170.   destZ -= delta*30;
171.   if(destZ < 25){
172.     destZ = 25;
173.   }
174. }

Seeing how reas thinks the exhibition section is a good place to post and discuss code snippets, i'll just go ahead and post this. But first i just want to clarify why i am posting this. So i created this mouse trail/Paint effect some days ago and i think it looks really cool but i really have no use for it. So i am posting it here because someone else might be able to use it for something or get some new ideas from it. I am also hoping that someone would be able to improve on it a post the results here and by doing that maybe creating what could be an interesting discussion on mouse trail effects. :)
Here's some images just to show how it looks and what you can do with it:



And here's the code:

1. float widthOfTheStorke;
   void setup(){
     size(screenWidth,screenHeight,P2D);
     background(255);
     smooth();
     stroke(255,10);
     strokeWeight(4);
     widthOfTheStorke = 100;
   }
   void draw(){
     if(mousePressed){
       line(pmouseX,pmouseY,mouseX,mouseY);
       PVector current = new PVector(pmouseX,pmouseY);
       PVector destination = new PVector(mouseX,mouseY);
       while(current.dist(destination) >0.5){
         stroke(current.x*255/width,current.y*255/height,noise(current.x/100,current.y/100)*255,20);
         float angle = atan2(destination.y-current.y,destination.x-current.x);
         float rad = noise(current.x/100,current.y/100)*widthOfTheStorke;
         line(current.x,current.y,current.x+cos(angle-PI/2)*rad,current.y+sin(angle-PI/2)*rad);
         current.x += cos(angle);
         current.y += sin(angle);
       }
     }
     if(keyPressed){
       if (key == ' ') {
         //space clears the screen
         background(255);
       }
     }
   }

Hope someone likes it and decides to do something with it :)

I actually made this program so that i could be the first person to post in the exhibition part of the forum but i guess i were too slow. :(
But i still like the final images and i did in fact put some time into tweaking this and i have had this idea in my head all day so i was probably gonna post it anyways (maybe).
So here it is (right click on the images and select "View Image")