Writing tron ( how to not crash when going backwards)

Programming Questions

qwerty6

Writing tron ( how to not crash when going backwards)

in Programming Questions • 3 years ago

I'm not sure how to write my code so that when i'm moving to the right and i press 'a' to go to the left, i don't crash into myself. Thanks.

int x=50;
int y=200;
int direction = RIGHT;
void setup()
{
size(400,400);
background(0);
noFill();
stroke(0,150,150);
rect(20,20,360,360);
}

void draw()
{
    human();
}

void human()
{
stroke(255,255,255);
if(get(x,y) != color(0,0,0))
{
    fill(255,0,0);
    ellipse(150,150,200,200);
    stroke(0,255,0);
}
else
{
    point(x,y);
    if(direction == RIGHT)
    {
      x++;
    }
    else if(direction == LEFT)
    {
      x--;
    }

    else if(direction == UP)
    {
      y--;
    }

    else if( direction == DOWN)
    {
      y++;
    }
}
}

void keyPressed()
{
if (key == 'a')
{
    direction= LEFT;
}
if (key == 'd')
{
    direction= RIGHT;
}
if (key == 'w')
{
    direction= UP;
}
if (key == 's')
{
    direction= DOWN;
}
}

Replies(5)

amnon.owed

Re: Writing tron ( how to not crash when going backwards)

3 years ago

Like this...

int x=50;
int y=200;
int direction = RIGHT;
void setup()
{
size(400,400);
background(0);
noFill();
stroke(0,150,150);
rect(20,20,360,360);
}
void draw()
{
human();
}
void human()
{
stroke(255,255,255);
if(get(x,y) != color(0,0,0))
{
fill(255,0,0);
ellipse(150,150,200,200);
stroke(0,255,0);
}
else
{
point(x,y);
if(direction == RIGHT)
{
x++;
}
else if(direction == LEFT)
{
x--;
}
else if(direction == UP)
{
y--;
}
else if( direction == DOWN)
{
y++;
}
}
}
void keyPressed()
{
if (key == 'a' && direction != RIGHT)
{
direction= LEFT;
}
if (key == 'd' && direction != LEFT)
{
direction= RIGHT;
}
if (key == 'w' && direction != DOWN)
{
direction= UP;
}
if (key == 's' && direction != UP)
{
direction= DOWN;
}
}

qwerty6

Re: Writing tron ( how to not crash when going backwards)

3 years ago

Thanks it works. But now i can't figure out what's wrong with my code. I added a computer that moves in four random directions. And i thought the reason why it seems to keep crashing is because it also goes backwards. But... after i added the code to prevent them from going backwards... it still crashes.

int x=50;

int y=200;

int compx=350;

int compy=200;

int c2ompx=220;

int c2ompy=60;

int c3ompx=180;

int c3ompy=320;

int c3ompdirection = int(random(0,4));

int c2ompdirection = int(random(0,4));

int compdirection = int(random(0,4));

int direction = RIGHT;

void setup()

{

size(400,400);

background(0);

noFill();

stroke(0,150,150);

rect(20,20,360,360);

}

void draw()

{

human();

computer();

}

void human()

{

stroke(255,255,255);

if(get(x,y) != color(0,0,0))

{

fill(255,0,0);

ellipse(150,150,20,20);

}

else

{

point(x,y);

if(direction == RIGHT)

{

x++;

}

else if(direction == LEFT)

{

x--;

}

else if(direction == UP)

{

y--;

}

else if( direction == DOWN)

{

y++;

}

void keyPressed()

{

if (key == 'a' && direction != RIGHT)

{

direction= LEFT;

}

if (key == 'd'&& direction != LEFT)

{

direction= RIGHT;

}

if (key == 'w'&& direction != DOWN)

{

direction= UP;

}

if (key == 's'&& direction != UP)

{

direction= DOWN;

}

void computer()

{

stroke(0,255,0);

if(get(compx,compy) != color(0,0,0))

{

fill(0,255,0);

ellipse(150,150,20,20);

}

else

{

if(int(random(100)) == 0)

{

compdirection = int(random(0,4));

}

point(compx,compy);

if(compdirection == 0 && compdirection != 1)

{

compx--;

}

if(get(compx-1,compy) != color(0,0,0))

{

compdirection = 3;

if(get(compx,compy+1) != color(0,0,0))

{

compdirection = 2;

}

else if(compdirection== 1 && compdirection != 0)

{

compx++;

if(get(compx+1,compy) != color(0,0,0))

{

compdirection = 3;

if(get(compx,compy+1) != color(0,0,0))

{

compdirection = 2;

}

else if(compdirection == 2 && compdirection != 3)

{

compy--;

if(get(compx,compy-1) != color(0,0,0))

{

compdirection = 1;

if(get(compx+1,compy) != color(0,0,0))

{

compdirection = 0;

}

else if(compdirection == 3 && compdirection != 2)

{

compy++;

if(get(compx,compy+1) != color(0,0,0))

{

compdirection = 0;

if(get(compx-1,compy) != color(0,0,0))

{

compdirection = 1;

}

amnon.owed

Re: Writing tron ( how to not crash when going backwards)

3 years ago

Pretty cool. I've been playing around with the code a bit. Let me share what I got...

It's working all right now. But to be realistic, the computer only sees 1 pixel around itself. So even though it will avoid collision one pixel ahead it's still pretty stupid. A challenge now would be to find better algorithms.

// use arrow keys to change direction
// press SPACE to reset
int x,y;
int direction;
int compx,compy;
int compdirection;
void setup() {
size(400,400);
smooth();
initGrid();
}
void initGrid() {
background(0);
noFill();
stroke(0,150,150);
rect(20,20,360,360);
x = int(random(width/3,2*width/3));
y = int(random(height/3,2*height/3));
direction = int(random(37,41));
compx = int(random(width/3,2*width/3));
compy = int(random(height/3,2*height/3));
compdirection = int(random(37,41));
}
void draw() {
human();
computer();
}
void human() {
if(get(x,y) != color(0,0,0)) {
noStroke();
fill(255,255,255);
ellipse(x,y,20,20);
} else {
stroke(255,255,255);
point(x,y);
if (direction == RIGHT) { x++; }
else if (direction == LEFT) { x--; }
else if (direction == UP) { y--; }
else if( direction == DOWN) { y++; }
}
}
void keyPressed() {
if (keyCode == LEFT && direction != RIGHT) { direction = LEFT; }
if (keyCode == RIGHT && direction != LEFT) { direction = RIGHT; }
if (keyCode == UP && direction != DOWN) { direction = UP; }
if (keyCode == DOWN && direction != UP) { direction = DOWN; }
if (key == ' ') { initGrid(); }
}
void computer() {
if(get(compx,compy) != color(0,0,0)) {
noStroke();
fill(0,255,0);
ellipse(compx,compy,20,20);
} else {
stroke(0,255,0);
point(compx,compy);
if (int(random(40)) == 0) {
int newcompdirection = int(random(37,41));
if (compdirection == RIGHT && newcompdirection != LEFT) { compdirection = newcompdirection; }
if (compdirection == LEFT && newcompdirection != RIGHT) { compdirection = newcompdirection; }
if (compdirection == UP && newcompdirection != DOWN) { compdirection = newcompdirection; }
if (compdirection == DOWN && newcompdirection != UP) { compdirection = newcompdirection; }
}
checkcollision();
if (compdirection == RIGHT) { compx++; }
else if (compdirection == LEFT) { compx--; }
else if (compdirection == UP) { compy--; }
else if( compdirection == DOWN) { compy++; }
}
}
void checkcollision() {
boolean compleftcolor;
boolean comprightcolor;
boolean compupcolor;
boolean compdowncolor;
if (get(compx+1,compy) != color(0,0,0)) { comprightcolor = true; } else { comprightcolor = false; }
if (get(compx-1,compy) != color(0,0,0)) { compleftcolor = true; } else { compleftcolor = false; }
if (get(compx,compy-1) != color(0,0,0)) { compupcolor = true; } else { compupcolor = false; }
if (get(compx,compy+1) != color(0,0,0)) { compdowncolor = true; } else { compdowncolor = false; }
switch(compdirection) {
case RIGHT:
if (comprightcolor == true && compupcolor == false) { compdirection = UP; }
else if (comprightcolor == true && compdowncolor == false) { compdirection = DOWN; }
break;
case LEFT:
if (compleftcolor == true && compdowncolor == false) { compdirection = DOWN; }
else if (compleftcolor == true && compupcolor == false) { compdirection = UP; }
break;
case UP:
if (compupcolor == true && compleftcolor == false) { compdirection = LEFT; }
else if (compupcolor == true && comprightcolor == false) { compdirection = RIGHT; }
break;
case DOWN:
if (compdowncolor == true && comprightcolor == false) { compdirection = RIGHT; }
else if (compdowncolor == true && compleftcolor == false) { compdirection = LEFT; }
break;
}
}

amnon.owed

Re: Writing tron ( how to not crash when going backwards)

3 years ago

If you want to have more than one computer player, I would suggest switching to object-oriented programming and using a class, so you can easily add multiple computer players. Like this...

int x,y;
int direction;
ArrayList computerplayers = new ArrayList();
void setup() {
size(400,400);
smooth();
initGrid();
}
void draw() {
human();
for (int i=0; i<computerplayers.size(); i++) {
Computer c = (Computer) computerplayers.get(i);
c.doStuff();
}
}
void human() {
if(get(x,y) != color(0,0,0)) {
noStroke();
fill(255,255,255);
ellipse(x,y,20,20);
} else {
stroke(255,255,255);
point(x,y);
if (direction == RIGHT) { x++; }
else if (direction == LEFT) { x--; }
else if (direction == UP) { y--; }
else if( direction == DOWN) { y++; }
}
}
void keyPressed() {
if (keyCode == LEFT && direction != RIGHT) { direction = LEFT; }
if (keyCode == RIGHT && direction != LEFT) { direction = RIGHT; }
if (keyCode == UP && direction != DOWN) { direction = UP; }
if (keyCode == DOWN && direction != UP) { direction = DOWN; }
if (key == ' ') { initGrid(); }
if (key == 'a') { addPlayer(); }
}
void initGrid() {
background(0);
noFill();
stroke(0,150,150);
rect(20,20,360,360);
x = int(random(width/3,2*width/3));
y = int(random(height/3,2*height/3));
direction = int(random(37,41));
computerplayers.clear();
addPlayer();
}
void addPlayer() {
int compx = int(random(width/3,2*width/3));
int compy = int(random(height/3,2*height/3));
int compdirection = int(random(37,41));
computerplayers.add(new Computer(compx,compy,compdirection));
}
class Computer {
int compx,compy;
int compdirection;
Computer(int compx, int compy, int compdirection) {
this.compx = compx;
this.compy = compy;
this.compdirection = compdirection;
}
void doStuff() {
if(get(compx,compy) != color(0,0,0)) {
noStroke();
fill(0,255,0);
ellipse(compx,compy,20,20);
} else {
stroke(0,255,0);
point(compx,compy);
if (int(random(40)) == 0) {
int newcompdirection = int(random(37,41));
if (compdirection == RIGHT && newcompdirection != LEFT) { compdirection = newcompdirection; }
if (compdirection == LEFT && newcompdirection != RIGHT) { compdirection = newcompdirection; }
if (compdirection == UP && newcompdirection != DOWN) { compdirection = newcompdirection; }
if (compdirection == DOWN && newcompdirection != UP) { compdirection = newcompdirection; }
}
checkcollision();
if (compdirection == RIGHT) { compx++; }
else if (compdirection == LEFT) { compx--; }
else if (compdirection == UP) { compy--; }
else if( compdirection == DOWN) { compy++; }
}
}
void checkcollision() {
boolean compleftcolor;
boolean comprightcolor;
boolean compupcolor;
boolean compdowncolor;
if (get(compx+1,compy) != color(0,0,0)) { comprightcolor = true; } else { comprightcolor = false; }
if (get(compx-1,compy) != color(0,0,0)) { compleftcolor = true; } else { compleftcolor = false; }
if (get(compx,compy-1) != color(0,0,0)) { compupcolor = true; } else { compupcolor = false; }
if (get(compx,compy+1) != color(0,0,0)) { compdowncolor = true; } else { compdowncolor = false; }
switch(compdirection) {
case RIGHT:
if (comprightcolor == true && compupcolor == false) { compdirection = UP; }
else if (comprightcolor == true && compdowncolor == false) { compdirection = DOWN; }
break;
case LEFT:
if (compleftcolor == true && compdowncolor == false) { compdirection = DOWN; }
else if (compleftcolor == true && compupcolor == false) { compdirection = UP; }
break;
case UP:
if (compupcolor == true && compleftcolor == false) { compdirection = LEFT; }
else if (compupcolor == true && comprightcolor == false) { compdirection = RIGHT; }
break;
case DOWN:
if (compdowncolor == true && comprightcolor == false) { compdirection = RIGHT; }
else if (compdowncolor == true && compleftcolor == false) { compdirection = LEFT; }
break;
}
}
}

qwerty6

Re: Writing tron ( how to not crash when going backwards)

3 years ago

Ok. Thanks. I'll try it out.

Top Reply