Working with pixels: alpha values?

Programming Questions

newmiracle

Working with pixels: alpha values?

in Programming Questions • 1 year ago

Hi, I'm new to Processing. I'm going through the tutorials, and then trying to do different things with the base principles in order to test my knowledge. I've run into a problem I was hoping someone would help me with.

http://processing.org/learning/pixels/

and specifically this part:

http://www.learningprocessing.com/examples/chapter-15/example-15-9/

I wanted to make my own image filter. I understood the principles of doing that with brightness values, but then I wanted to make the same with with alpha values and I hit a brick wall.

I loaded an image from a file, took the pixel information and created a new image object. Displaying the new image works. The brightness filter from the tutorial works. Trying to change the alpha values on a per-pixel did not work. Just to make sure, I used tint() to adjust the alpha on my image object instead of the individual pixels. It did worked.

So it looks to me that:

 pixels[i] = color(255, 102, 204);

Would seem correct, but then adding a fourth value:

pixels[i] = color(255, 102, 204, 127);

Did nothing at all. I did some reading, and I'm getting the impression that pixels[] simply won't take alpha values. Is this a correct assumption? Or am I screwing up royally?

Replies(4)

PhiLho

Re: Working with pixels: alpha values?

1 year ago

Showing some code could help to understand your problem...
Adding transparency to the image shown by the sketch isn't very useful, since there is nothing behind to be revealed. Transparency is useful only in image composition, when you put one image over another.

newmiracle

Re: Working with pixels: alpha values?

1 year ago

I have an image behind the one I am trying to make transparent. What I am trying to achieve is making a filter for the image "on top" of it. It would be all 100% transparent, except for the area around the mouse x/y position. Putting your mouse over the image reveals a distorted version of it.

My program has different parts to it, but here is the relevant snippet. "destination" is the image object that is on top of another image object.

for (int x = 0; x < destination.width; x++) {
for (int y = 0; y < destination.height; y++ ) {
// Calculate the 1D pixel location
int loc = x + y*destination.width;
// Get the R,G,B values from image
float r = red (destination.pixels[loc]);
float g = green (destination.pixels[loc]);
float b = blue (destination.pixels[loc]);
float a = alpha (destination.pixels[loc]);
// Calculate an amount to change brightness
// based on proximity to the mouse
float distance = dist(x,y,mouseX,mouseY);
float adjustBrightness = (50-distance)/50;
r *= adjustBrightness;
g *= adjustBrightness;
b *= adjustBrightness;
a *= adjustBrightness;
// Constrain RGB to between 0-255
float a_value = 127;
r = constrain(r,0,255);
g = constrain(g,0,255);
b = constrain(b,0,255);
a = constrain(a,0,255);
// Make a new color and set pixel in the window
color c = color(r,g,b,127);
destination.pixels[loc] = c;
//destination.pixels[loc] = alpha(a_value);
}
}

As you can see, I've tried hardcoding the alpha value at the end of the for loop. This yields no change. " destination.pixels[loc] = alpha(a_value);" was a bust, as well.

Later on I draw "destination". I've used the tint() function to adjust the alpha values of the entire image object, and that works fine. I can see the image underneath it.

So, can pixels[] only handle color brightness values? Or is there a way to give it alpha values as well?

PhiLho

Re: Working with pixels: alpha values?

1 year ago

Your code works for me, so perhaps you have problems with the surrounding code.
I tested your code as follows, with a simple sketch:

void setup()
{
size(500, 500);
}
void draw()
{
PGraphics pg = createGraphics(width, height, JAVA2D);
pg.beginDraw();
pg.background(#557799);
pg.fill(#FF8822);
for (int i = 0; i < width; i += 20)
{
pg.ellipse(i, i, 20, 20);
}
pg.endDraw();
adjustImage(pg);
background(255);
fill(#FF0000);
ellipse(0, 0, width, height);
fill(#FFFF00);
ellipse(width, height, width * 1.5, height * 1.5);
image(pg, 0, 0);
}
void adjustImage(PImage destination)
{
// Your code here, unchanged
}

The image is tinted, and I can see semi-transparent circles over the image (on the diagonal) when I move the mouse over them.
Processing 1.5.1.

newmiracle

Re: Working with pixels: alpha values?

1 year ago

Thanks for your help.

I probably should have asked my question in a more complete way, and shown you my entire code. Everything was kind of frankenstein'd together and I thought I had isolated my problem above, but of course I didn't.

The images I was drawing, laying over each other and making transparent were loaded JPGs. When I created an image object with them, I used

destination = createImage(img.width, img.height, RGB);

instead of...

destination = createImage(img.width, img.height, ARGB);

and once I used ARGB I could play with the alpha values of the image. If I had shown you everything you probably would have caught it. Again, I appreciate the help.

Top Reply