Peasycam is a contributed library so I have moved it to that forum. As to your question I believe it is the lookAt method -

lookAt(x,y,z);
or
lookAt(x,y,z,d);

x,y,z is the new centre of rotation and d is the distance from the new origin.

Thx quark.. I manage to change to center of rotation but i can't fix it in that point since it will change every time I pan the object (mid mouse click).. Is there a way to fixed the center of rotation even if I pan the object?

Not sure what you mean by pan the object. Is the object supposed to be the centre of rotstion? Can you post some code we can try out.

here's the code.. i'm trying to make the femur bone rotate with the center of rotation is at the center of the femur bone. But when I move the femur bone, the center of rotation changed to where I click & drag the mid mouse button.. 

You should be aware that when using PeasyCam the lookAt position is always moved to the centre of the screen and all rotation with the mouse is about the centre of the screen.

If the femur is centred on the lookAt position then it will rotate about the centre of the display. If you move the femur away from the lookAt position, then dragging with the mouse will rotate the femur about the lookAt position (so it will 'orbit' the centre of the screen), it will NOT rotate about the centre of the femur.

So there are two rotations to consider
1) rotation of the femur about its mid point
2) rotating the 3D view of the 'world' which is done with PeasyCam.

This means that if you use PeasyCam you cannot use the mouse to rotate the actual femur.

The code below ceates 2 bones. The average position of the xyz data of the white bone is being used as the lookAt point for PeasyCam. The yellow bone has been moved and rotated a little to demonstrate what I have been saying.

1. import peasy.*;
2. PeasyCam cam;
3. Bone b0, b1;
4. 
   
5. void setup() {
6.   size(400, 500, P3D);
7.   b0 = new Bone("Femur.xyz");
8.   b1 = new Bone("Femur.xyz");
9.   // Reposition the second bone and change its rotation
10.   b1.px = 100;
11.   b1.py = 60;
12.   b1.pz = 120;
13.   b1.rx = PI/2;
14.   b1.col = color(255,255,0);
15.  
16.   cam = new PeasyCam(this, 500);
17.   cam.setMinimumDistance(50);
18.   cam.setMaximumDistance(600);
19.   // Look at average point for the white bone
20.   cam.lookAt(b0.refPoint.x, b0.refPoint.y, b0.refPoint.z);
21. }
22. 
    
23. void draw() {
24.   background(0);
25.   pushMatrix();
26.   b0.display();
27.   b1.display();
28.   popMatrix();
29. }
30. 
    
31. class Bone {
32.   float px, py, pz;
33.   float rx, ry, rz;
34.   int col;
35.   ArrayList<PVector> pointList;
36.   PVector refPoint; // The average position of all points
37. 
    
38.   Bone(String fileXYZ) {
39.     col = color(255);
40.     pointList = new ArrayList<PVector>();
41.     refPoint = new PVector(); 
42.     String[] strLines = loadStrings(fileXYZ); 
    
43.     for (int i = 0; i < strLines.length; ++i) {
44.       String[] arrTokens = split(strLines[i], ' ');   
    
45.       float xx = float(arrTokens[0]);
    
46.       float yy = float(arrTokens[1]);
47.       float zz = float(arrTokens[2]);
    
48.       pointList.add( new PVector(xx/5, yy/5, zz/5) );
49.       refPoint.add(xx, yy, zz);
50.     }
51.     refPoint.div(5 * pointList.size());
52.     println(refPoint);
53.   }
54.   void display() {
55.     pushMatrix();
56.     translate(px, py, pz);
57.     rotateX(rx);
58.     rotateY(ry);
59.     rotateZ(rz);
60.     stroke(col);
61.     for (PVector v : pointList)     
62.       point(v.x, v.y, v.z);
63.     popMatrix();
64.   }
65. }

Thx quarks..  I understand it fully.. So is there any method or any libraries that have center of rotation fixed to the object instead of fixed to the center of 3D world?