Why is this sketch generating janky lines?

Programming Questions

RyanJP

Why is this sketch generating janky lines?

in Programming Questions • 3 months ago

Can't figure out why this simple recursion loop is generating uneven lines on the rectangles. I need accuracy!! Thanks for your help :)

void setup(){
size(800, 800);
background(235);
smooth();
drawRect(width/2, height/2, 200);
}
void drawRect(float x, float y, float len){
pushMatrix();
translate(x, y);
rotate(radians(45.0));
stroke(0);
strokeWeight(1);
noFill();
rectMode(RADIUS);
rect(0, 0, len, len);
popMatrix();
if(len >= 20){
drawRect(x + len, y, len / 2);
drawRect(x - len, y, len / 2);
drawRect(x, y + len, len / 2);
drawRect(x, y - len, len / 2);
}
}

Replies(9)

tfguy44

Re: Why is this sketch generating janky lines?

3 months ago

All the lines I see are straight. What do you mean by "uneven"?

Can you post an image of what you are expecting?

RyanJP

Re: Why is this sketch generating janky lines?

3 months ago

The small little double-lines I've highlighted which are repeated in various areas throughout the sketch, they're even more noticeable with a lighter line weight. To me they make they whole thing look a bit weird. But at least my code is right :)

tfguy44

Re: Why is this sketch generating janky lines?

3 months ago

I don't know why you're expecting those lines to match up. here, run this:

void setup(){
size(800, 800);
background(235);
smooth();
drawRect(width/2, height/2, 200);
}
void drawRect(float x, float y, float len){
pushMatrix();
translate(x, y);
strokeWeight(1);
noFill();
rectMode(RADIUS);
stroke(128,0,0);
rect(0, 0, len, len);
stroke(0);
rotate(radians(45));
rect(0,0,len,len);
popMatrix();
if(len > 100 ){
drawRect(x + len, y, len / 2);
drawRect(x - len, y, len / 2);
drawRect(x, y + len, len / 2);
drawRect(x, y - len, len / 2);
}
}

It does the largest square and the next smallest four squares. But it also adds some guide lines (in red) so that you can see where the four smaller squares are centered - they aren't centered on the largest squares corners!

tfguy44

Re: Why is this sketch generating janky lines?

3 months ago

Did you want this?

void setup(){
size(800, 800);
background(235);
smooth();
translate(width/2,height/2);
rotate(radians(45));
scale(.7);
drawRect(0,0, 200);
}
void drawRect(float x, float y, float len){
pushMatrix();
translate(x,y);
strokeWeight(1);
noFill();
rectMode(RADIUS);
// stroke(128,0,0);
// rect(0, 0, len, len);
stroke(0);
rect(0,0,len,len);
popMatrix();
if(len >= 20 ){
drawRect(x + len, y+len, len / 2);
drawRect(x - len, y+len, len / 2);
drawRect(x+len, y - len, len / 2);
drawRect(x-len, y - len, len / 2);
}
}

RyanJP

Re: Why is this sketch generating janky lines?

3 months ago

Sure looks great, I mean I didn't really "want" anything I'm just messing around and was wondering why the lines weren't lining up. Can you explain that if you have a sec? I'd be grateful. If not, thanks for the alternative solution

tfguy44

Re: Why is this sketch generating janky lines?

3 months ago

It's not easy to explain... They didn't line up because they shouldn't have lined up. You were moving them some distance each time, but then drawing the squares rotated. If you would move them the length of half the DIAGONAL of the square instead of half the length of the square's SIDE, they would have lined up.

RyanJP

Re: Why is this sketch generating janky lines?

3 months ago

ok cool, I get that (conceptually anyway) so how does yours work? I see you're just rotating the grid outright at the beginning which makes sense, translating to the center and then working your way out from there. Very nice, so doing this basically allows me to use the length of the side properly, as I was above.. correct? I'm still getting used to transformations and that is a big help so thanks.

As for the scale function- I'm guessing that's not essential.. Just acts as a global scale in this case?

tfguy44

Re: Why is this sketch generating janky lines?

3 months ago

Basically, yes. I make the origin the center right away, and tilt everything by 45 degrees. The rectangles get drawn from the center, and then smaller rectangles are drawn at the corners of the larger rectangle. And so on. Since the whole everything is rotated, the corners of the larger rectangle are (x+len,y+len), (x-len,y+len), (x+len,y-len), and (x-len,y-len), which is the points I call the recursive function on.

The scale function is certainly not essential, but commenting it out shows why I added it and picked .7 as the value... It does a global scale on everything, yes.

RyanJP

Re: Why is this sketch generating janky lines?

3 months ago

Cool! Thanks so much for your time I really appreciate it, was a big help

Top Reply

Statistics

9 Replies
501 Views
0 Followers

Actions

Permalink