Why is my sketch so much less responsive in Android?

Android Processing

teacherben

Why is my sketch so much less responsive in Android?

in Android Processing • 1 year ago

I wrote a simple little game for my toddler where he has to connect two dots by dragging his finger on the screen. On the computer, it is smooth and responsive. In Android, when you drag the line into the second circle and then release, it won't respond unless you hold your finger there for a few seconds. I tried on a Desire, a Sensation and a Transformer. Same each time. Is this typical or is there something wrong with my code?

float lastX, lastY;

float newX, newY;

float circle1X = random(50, 430);

float circle1Y = random(50, 350);

float circle2X = random(50, 430);

float circle2Y = random(450, 750);

float color1 = random(100);

float color2 = random(100);

float dist1;

float dist2;

int score = 0;

void setup() {

size(480, 800);

background(0);

strokeWeight(10);

stroke(255);

smooth();

textAlign(CENTER);

textSize(40);

}

void mousePressed() {

lastX = mouseX;

lastY = mouseY;

dist1 = dist(circle1X, circle1Y, lastX, lastY);

}

void mouseReleased() {

newX = mouseX;

newY = mouseY;

dist2 = dist(circle2X, circle2Y, newX, newY);

if (dist1 < 50 && dist2 < 50) {

// println("got it!");

color1 = random(100);

color2 = random(100);

circle1X = random(50, 430);

circle1Y = random(50, 350);

circle2X = random(50, 430);

circle2Y = random(450, 750);

score = score + 1;

}

void draw() {

background(0);

text(score, 20, 40);

colorMode(HSB, 100);

fill(color1, 80, 80);

ellipse(circle1X, circle1Y, 80, 80);

fill(100);

text("1", circle1X, circle1Y + 15);

fill(color2, 80, 80);

ellipse(circle2X, circle2Y, 80, 80);

fill(100);

text("2", circle2X, circle2Y + 15);

if (mousePressed == true) {

if (dist1 < 50) {

line(circle1X, circle1Y, mouseX, mouseY);

}

if (score == 10) {

fill(0);

rect(0, 0, width, height);

fill(100);

text("You Win!", width/2, height/2);

}

Of course, any suggestions on how to improve this are also welcome. i am very new to programming and always appreciate tips on how I can improve.

Replies(3)

rbrauer

Re: Why is my sketch so much less responsive in Android?

1 year ago

I didn't figure out why your code wasn't working but the following worked for me. You might want to add something to make sure the circles aren't to close to each other.

float circle1X;
float circle1Y;
float circle2X;
float circle2Y;
float color1 = random(100);
float color2 = random(100);
float dist1;
float dist2;
int score = 0;

void setup() {
  size(screenWidth, screenHeight);
//  size(640, 360);
  background(0);
  strokeWeight(10);
  stroke(255);
  smooth();
  textAlign(CENTER);
  textSize(40);
  
  newCircles();
  
  dist1 = dist2 = -1;
}

void draw() {
  background(0);
  text(score, 20, 40);
  colorMode(HSB, 100);
  fill(color1, 80, 80);
  ellipse(circle1X, circle1Y, 80, 80);
  fill(100);
  text("1", circle1X, circle1Y + 15);
  fill(color2, 80, 80);
  ellipse(circle2X, circle2Y, 80, 80);
  fill(100);
  text("2", circle2X, circle2Y + 15);
  if (score == 10) {
    fill(0);
    rect(0, 0, width, height);
    fill(100);
    text("You Win!", width/2f, height/2f);
  }
  
  if(mousePressed) {
    if(dist1 == -1) 
      dist1 = dist(circle1X, circle1Y, mouseX, mouseY);
    if (dist1 < 50)
      line(circle1X, circle1Y, mouseX, mouseY);
  } else {
    if(dist2 == -1) 
      dist2 = dist(circle2X, circle2Y, mouseX, mouseY);
    if (dist1 != -1 && dist1 < 50 && dist2 < 50) {
      //  println("got it!");
      color1 = random(100);
      color2 = random(100);

      newCircles();

      score = score + 1;
    }
    dist1 = dist2 = -1;
  }
}

void newCircles() {
  circle1X = random(width*.1, width*.9);
  circle1Y = random(height*.1, height*.9);
  
  circle2X = random(width*.1, width*.9);
  circle2Y = random(height*.1, height*.9);
  
  while(dist(circle1X, circle1Y, circle2X, circle2Y) < 100) {
    circle2X = random(width*.1, width*.9);
    circle2Y = random(height*.1, height*.9);
  }
}

teacherben

Re: Why is my sketch so much less responsive in Android?

1 year ago

Thanks for helping me out with this. I haven't had a long look through your sketch yet to try to make sense of it but I did export it as an apk and ran it on my phone. It is indeed much smoother. With mine, you have to hold your finger on the '2' circle for a moment or it doesn't work. With yours however, I noticed that you don't have to draw a line at all to score a point. You just have to tap on the circle with the '2' in it. Also, sometimes, the two circles appear on top of each other. The way I did it, one always appears in the top half of the screen and the other always on the bottom, which I imagine is not the best way to do it, but I hadn't yet thought of how to make it so they could appear anywhere, but never on top of each other.

The idea was that the program would teach my son to identify which circle had a 1 in it and which one had a 2, then, he would draw a line from the 1 to the 2 to score a point. He would get a win screen when he got to ten. As i learn more about Processing, I will try to make it a little more interesting bit by bit. I am hoping to eventually work out how to go higher and get maybe up to 10 circles in there eventually so that it is a little connect the dots sort of thing.

Could you explain the line dist1 = dist2 = -1. I don't quite get that one.

rbrauer

Re: Why is my sketch so much less responsive in Android?

1 year ago

I updated the code in my original post. The bug where you can just tap "2" to advance should be fixed and I added a function to pick circle positions that will try another position for "2" if it is to close until it finds a good one.

I set the distance variables to -1 to indicate they are in an "unset" state. They both get unset when the user makes an attempt (mouseReleased) so they can be set again for the next attempt. My code runs continuously since it is in the draw method, so to make sure the distance variables only get set once they need this unset state. Since -1 is less than 50 we need to make sure dist1 is actually set (!= -1) to fix the bug.