Why is my 3d circle not rotating on a centered axis?

Core Library Questions

prismspecs

Why is my 3d circle not rotating on a centered axis?

in Core Library Questions • 1 year ago

So this is a very simple sketch, but when you use the mouse to rotate the circle it doesn't seem to rotate exactly on the Y axis. Run the sketch and you'll see what I mean.

import processing.opengl.*;

float a;

void setup() {
size(800, 600, OPENGL);
fill(0, 153);
noStroke();
hint(ENABLE_OPENGL_4X_SMOOTH);
}

void draw() {
background(255);
translate(width/2, height/2);
rotateY(radians(a));
ellipse(0, 0, 400, 400);
}

void mouseDragged() {
a = mouseX;
}

Replies(8)

PhiLho

Re: Why is my 3d circle not rotating on a centered axis?

1 year ago

Well, no, I don't see what you mean. It seems perfectly vertical for me. Processing 1.5.1, Windows 7, Java 1.6.0_30.

mbraendle

Re: Why is my 3d circle not rotating on a centered axis?

1 year ago

Yes, it is vertical, but the vertical axis of the ellipse doesn't coincide with the y-axis of the coordinate system upon rotation.

Add a

stroke(0);

line(0,-200,0,0,200,0);

noStroke();

to the code, and you will see why. The line should go from the highest point to the lowest point of the ellipse, but it doesn't. The center of the ellipse shows a precession in the xz plane. The problem is that ellipse() can only be specified in 2D, but not in 3D (such as ellipse(0,0,0,400,400,0)).

You also see that the ellipse collapses to its standard height when the rotation angle is exactly 90 degrees.

prismspecs

Re: Why is my 3d circle not rotating on a centered axis?

1 year ago

Not sure I follow, but I'll check it out. Is there a way around this problem?

mbraendle

Re: Why is my 3d circle not rotating on a centered axis?

1 year ago

Since ellipse() is a 2D primitive, you need to work with shapes (vertices) in 3D. Have a look at the beginShape, vertex and curveVertex commands in the Processing reference.

Chrisir

Re: Why is my 3d circle not rotating on a centered axis?

1 year ago

I am not sure but I'd expect

pushMatrix();
.......
popMatrix();

around the whole thing

also, can't we use 3D operations such as

translate(x,y,z); ......... or rotateX, rotateY and rotateZ..........

on a 2D thing? It works with text(.......) and ellipse(.....) I think.

Chrisir

Re: Why is my 3d circle not rotating on a centered axis?

1 year ago

did you see my remark here:

https://forum.processing.org/topic/3d-rotation-logic-problem#25080000001320475
?

hellochar

Re: Why is my 3d circle not rotating on a centered axis?

1 year ago

It's an optical illusion. If you drag the mouse around very quickly, you'll see two points at the top and bottom of the circle that don't move at all. Or take a look at this code:

import processing.opengl.*;
float a;
void setup() {
size(800, 600, OPENGL);
hint(ENABLE_OPENGL_4X_SMOOTH);
camera(0, 0, 500, 0, 0, 0, 0, 1, 0);
}
void draw() {
background(255);
lights();
if(keyPressed) {
rotateX(millis() / 1000f);
}
noFill(); stroke(255, 0, 0);
ellipse(0, 0, 400, 400);
rotateY(radians(a));
fill(140);
noStroke();
ellipse(0, 0, 400, 400);
}
void mouseDragged() {
a = mouseX;
}

Hold a key to see the scene from a different angle, and you'll see it.

mbraendle

Re: Why is my 3d circle not rotating on a centered axis?

1 year ago

You are right, it is indeed an optical illusion, created by the proximity of the camera to the center.

This code should make it even more clear.

import processing.opengl.*;
float a;
float b;
void setup() {
size(800, 600, OPENGL);
hint(ENABLE_OPENGL_4X_SMOOTH);
camera(0, 0, 500, 0, 0, 0, 0, 1, 0);
}
void draw() {
background(255);
lights();
pushMatrix();
if(keyPressed) {
rotateX(millis() / 1000f);
}
noFill();
stroke(255, 0, 0);
ellipse(0, 0, 400, 400);
popMatrix();
rotateY(radians(a));
fill(140);
noStroke();
ellipse(0, 0, 400, 400);
stroke(0,0,255);
noFill();
drawEllipse(200,24);
}
void mouseDragged() {
a = mouseX;
b = mouseY;
}
void drawEllipse(float radius, int resolution) {
beginShape();
for (int i = 0; i <= resolution; i++) {
float angle = TWO_PI*i/resolution;
float x = radius*cos(angle);
float y = radius*sin(angle);
float z = 0.0;
vertex(x,y,z);
}
endShape();
}

Top Reply