Why is cursor blinking (changes from ARROW to HAND)?

GoToLoop

Re: Why is cursor blinking (changes from ARROW to HAND)?

2 months ago

You know that by default, draw() is invoked @ 60 FPS!
It's like you're changing the cursor's type at that speed all the time!

Create some boolean variable to flag that cursor's type is already HAND!
And use it along w/ the rest of the conditional expression above!

fari

Re: Re: Why is cursor blinking (changes from ARROW to HAND)?

2 months ago

You mean something like this:

boolean hand = false;
void draw() {
if(hand==true) {
cursor(HAND);
}else {
cursor(ARROW);
}
}
void MyMethod() {
if(CloudRect.contains(mouseX,mouseY)) {
hand = true;
}else {
hand = false;
}
}

I tried it, but it gives the same result.

mentecode

Re: Why is cursor blinking (changes from ARROW to HAND)?

2 months ago

Try using a while() loop instead of the if() loop in your method/function.

- MenteCode.

fari

Re: Re: Why is cursor blinking (changes from ARROW to HAND)?

2 months ago

While loop just hangs the program :(

quarks

Re: Why is cursor blinking (changes from ARROW to HAND)?

2 months ago

Not sure what the problem is but it might be caused by calling the cursor() method from inside draw. Try something like this

void draw() {
}
void mouseMoved() {
if(CloudRect.contains(mouseX,mouseY)) {
cursor(HAND);
}else {
cursor(ARROW);
}
}

fari

Re: Re: Why is cursor blinking (changes from ARROW to HAND)?

2 months ago

It is the same. Blinks every now and then.

GoToLoop

Re: Why is cursor blinking (changes from ARROW to HAND)?

2 months ago

I've meant something a little more complex.

For a complete flicker-free cursor() toggle, you're gonna need not 1, but 2 boolean variables.

Besides the one which keeps the state of which cursor() type currently is,
you also need another 1 to store the previous result of whether mouse was hovering over a rectangle.
This way, toggle only happens once for each hovering change!

The example below is based on a previous 1 I got online here:
http://studio.processingtogether.com/sp/pad/export/ro.9owuz0wKx1ph7/latest

/** 
 * Flicker-Free Cursor Toggle (v1.1)
 * by GoToLoop (2013/Jul)
 * 
 * http://forum.processing.org/topic
 * /why-is-cursor-blinking-changes-from-arrow-to-hand
 */

final CloudRect cr = new CloudRect();
boolean isHand, wasHovering;

void setup() {
  size(200, 150);
  noLoop();
  fill(#0000FF);
}

void draw() {
  background(0);
  cr.display();
}

void mouseMoved() {
  toggleCursor();
  redraw();
}

void toggleCursor() {
  final boolean isHovering = cr.isInside(mouseX, mouseY);

  frame.setTitle("Hovering: " + isHovering);

  if ( wasHovering != (wasHovering = isHovering) )
    if ( isHand = !isHand )  cursor(HAND);
    else                     cursor(ARROW);
}

class CloudRect {
  short x = 80, y = 50, w = 80, h = 50;
  short xw, yh;

  CloudRect() {
    xw = (short) (x + w);
    yh = (short) (y + h);
  }

  CloudRect(int xx, int yy, int ww, int hh) {
    x = (short) xx;
    y = (short) yy;
    w = (short) ww;
    h = (short) hh;

    xw = (short) (x + w);
    yh = (short) (y + h);
  }

  void display() {
    rect(x, y, w, h);
  }

  boolean isInside(int xx, int yy) {
    return xx > x & xx < xw & yy > y & yy < yh;
  }
}

quarks

Re: Why is cursor blinking (changes from ARROW to HAND)?

2 months ago

Since the cursor can only change when the mouse moves then test it inside the mouseMoved method. Merging my code with GoToLoop's you get flicker free cursor changes with

CloudRect cr = new CloudRect();
void setup() {
size(200, 150);
noLoop();
fill(0, 0, 255);
}
void draw() {
background(160);
cr.display();
}
void mouseMoved() {
if (cr.isInside(mouseX, mouseY)) {
cursor(HAND);
}
else {
cursor(ARROW);
}
}
class CloudRect {
int x = 80, y = 50, w = 80, h = 50;
int xw, yh;
CloudRect() {
xw = x + w;
yh = y + h;
}
CloudRect(int xx, int yy, int ww, int hh) {
x = xx;
y = yy;
w = ww;
h = hh;
xw = x + w;
yh = y + h;
}
void display() {
rect(x, y, w, h);
}
boolean isInside(int xx, int yy) {
return xx > x & xx < xw & yy > y & yy < yh;
}
}

fari

Re: Why is cursor blinking (changes from ARROW to HAND)?

2 months ago

Thank you so much to everyone! I appreciate your taking time for helping me out.

I tried every possible way, but didn't succeed. So after playing with new sketches around, I found out that if I am using the G4P library to draw some controls on the sketch (e.g. button), the cursor will be having the blinking problem on any other x,y location rather than the control itself.

I don't know if someone else also faces the same problem?

Below is an example (I just added a simple control from G4P to the code given by GoToLoop) [you have to download the G4P library]

And I removed noLoop() from setup(), otherwise the controls will not be drawn by G4P.

import g4p_controls.*;
CloudRect cr = new CloudRect();
void setup() {
size(500, 500);
fill(0, 0, 255);
createGUI();
}
void draw() {
background(255);
cr.display();
}
void mouseMoved() {
if (cr.isInside(mouseX, mouseY)) {
cursor(HAND);
}
else {
cursor(ARROW);
}
}
class CloudRect {
int x = 80, y = 50, w = 80, h = 50;
int xw, yh;
CloudRect() {
xw = x + w;
yh = y + h;
}
CloudRect(int xx, int yy, int ww, int hh) {
x = xx;
y = yy;
w = ww;
h = hh;
xw = x + w;
yh = y + h;
}
void display() {
rect(x, y, w, h);
}
boolean isInside(int xx, int yy) {
return xx > x & xx < xw & yy > y & yy < yh;
}
}
/* =========================================================
* ==== WARNING ===
* =========================================================
* The code in this tab has been generated from the GUI form
* designer and care should be taken when editing this file.
* Only add/edit code inside the event handlers i.e. only
* use lines between the matching comment tags. e.g.
void myBtnEvents(GButton button) { //_CODE_:button1:12356:
// It is safe to enter your event code here
} //_CODE_:button1:12356:
* Do not rename this tab!
* =========================================================
*/
public void button1_click1(GButton source, GEvent event) { //_CODE_:button1:879951:
println("button1 - GButton event occured " + System.currentTimeMillis()%10000000 );
} //_CODE_:button1:879951:
// Create all the GUI controls.
// autogenerated do not edit
public void createGUI(){
G4P.messagesEnabled(false);
G4P.setGlobalColorScheme(GCScheme.BLUE_SCHEME);
G4P.setCursor(ARROW);
if(frame != null)
frame.setTitle("Sketch Window");
button1 = new GButton(this, 196, 238, 56, 30);
button1.setText("Face text");
button1.addEventHandler(this, "button1_click1");
}
// Variable declarations
// autogenerated do not edit
GButton button1;

GoToLoop

Re: Why is cursor blinking (changes from ARROW to HAND)?

2 months ago

I've inserted the G4P code into my original example and made some tweaks to it.
Then I've realized it is the G4P library which changes the cursor()'s symbol back
to its own config every time mouse moves!

So, if we modify #79 from GP4.setCursor(ARROW); to GP4.setCursor(WAIT);
we'd notice that the latter becomes the new default cursor for the whole sketch!
Except when mouse is hovering over GP4's own buttons. Sprite becomes cursor(HAND) then.
That also interferes for setting cursor() to another symbol for other parts of the sketch.

Here's the example I'm currently testing:

Main.pde:

/** 
 * Flicker-Free Cursor Toggle (v1.1)
 * by GoToLoop (2013/Jul)
 * 
 * http://forum.processing.org/topic
 * /why-is-cursor-blinking-changes-from-arrow-to-hand
 */

import g4p_controls.*;

final CloudRect cr = new CloudRect();
boolean isHand, wasHovering;

void setup() {
  size(300, 300);
  //noLoop();
  fill(#0000FF);

  createGUI();
}

void draw() {
  background(0);
  cr.display();
  //cursor(MOVE);
}

void mouseMoved() {
  toggleCursor();
  redraw();
}

void toggleCursor() {
  final boolean isHovering = cr.isInside(mouseX, mouseY);

  frame.setTitle("Hovering: " + isHovering);

  if ( wasHovering != (wasHovering = isHovering) )
    if ( isHand = !isHand )  cursor(HAND);
    else                     cursor(ARROW);
}

class CloudRect {
  short x = 80, y = 50, w = 80, h = 50;
  short xw, yh;

  CloudRect() {
    xw = (short) (x + w);
    yh = (short) (y + h);
  }

  CloudRect(int xx, int yy, int ww, int hh) {
    x = (short) xx;
    y = (short) yy;
    w = (short) ww;
    h = (short) hh;

    xw = (short) (x + w);
    yh = (short) (y + h);
  }

  void display() {
    rect(x, y, w, h);
  }

  boolean isInside(int xx, int yy) {
    return xx > x & xx < xw & yy > y & yy < yh;
  }
}

GP4.pde:

void button1_click1(GButton source, GEvent event) { //_CODE_:button1:879951:
  println("button1 - GButton event occured " + millis() % 10000000);
} //_CODE_:button1:879951:

void createGUI() {
  G4P.messagesEnabled(false);
  G4P.setGlobalColorScheme(GCScheme.BLUE_SCHEME);
  G4P.setCursor(WAIT);

  if (frame != null)  frame.setTitle("Sketch Window");

  button1 = new GButton(this, 196, 238, 56, 30);
  button1.setText("Face Text");
  button1.addEventHandler(this, "button1_click1");
}

GButton button1;

fari

Re: Re: Why is cursor blinking (changes from ARROW to HAND)?

2 months ago

I solved it: basically I have to set the cursor type of G4P anywhere I want to change it and to avoid blinking. For instance:

G4P.setCursorOff (1); //1 represents cross, and pass the relevant integer that represents the cursor

quarks

Re: Why is cursor blinking (changes from ARROW to HAND)?

2 months ago

As you have discovered G4P takes control of the cursor shape. To set the shape to use when not over a control use

G4P.setCursor(ARROW); // change ARROW to suit

When the mouse moves over a control hot-spot then the cursor shape is set according to the type of control (HAND for most controls). You can change the cursor-over image for a control with

controlName.setCursorOver(HAND); // change HAND to suit

If you use G4P but also include your own cursor shape handling code then they will conflict and flickering is likely to occur.

fari

Re: Re: Why is cursor blinking (changes from ARROW to HAND)?

2 months ago

Thank you quarks. I will not use my own code to change cursor type. Rather, I will use G4P's native method .setCursor()

quarks

Re: Why is cursor blinking (changes from ARROW to HAND)?

2 months ago

Do not these

G4P.setCursorOff(CROSS);
G4P.getCursorOff();

both of thee methods have been deprecated with G4P V3 and will eventually be removed from a future version of the library instead use the method

G4P.setCursor(CROSS);

instead.

BTW I recommend you use setCursor(CROSS) rather than setCursor(1) otherwise when you come back to your code in 6 months you have to remember what shape is represented by the number 1. This goes for any constants defined by Processing or Java.

fari

Re: Re: Why is cursor blinking (changes from ARROW to HAND)?

2 months ago

Thank you for the explanations. I am passing cursor types rather than integers in setCursor() now

GoToLoop

Re: Why is cursor blinking (changes from ARROW to HAND)?

2 months ago

Quarks! It'd be nice if you could modify your library to change cursor() once when starts hovering,
and change it back once when it's stops hovering a GP4's GUI element.

This way, an independent cursor() can be used at some other place at screen, along w/ GP4 library!