when condition is true, choose between n possibilities

General Discussion Other

karlhungus

when condition is true, choose between n possibilities

in General Discussion • Other • 1 month ago

how do i program something simple like this?

if some condition is true (say mousePressed)
choose to execute A, B or C

in other words when condition is met one of 3 possibilities is chosen

Replies(7)

asimes

Re: when condition is true, choose between n possibilities

1 month ago

Maybe something like this?

float[] p = {
0.25, 0.5, 0.25
};
void setup() {
size(200, 200);
float rand = random(1.0);
int selected = 0;
float accumulation = 0.0;
for (int i = 0; i < p.length; i++) {
if (accumulation+p[i] > rand) {
selected = i;
break;
}
accumulation += p[i];
}
println("index = "+selected+", rand = "+rand);
exit();
}

Edit: I made the assumption that the elements in p add up to 1.0.

PhiLho

Re: when condition is true, choose between n possibilities

1 month ago

Nested ifs:

if (flagIsOn)
{
if (condition1)
{
doStuff();
}
else if (x < 0)
{
outOfLeft();
}
else if (x > width)
{
outOnRight();
}
}

amnon.owed

Re: when condition is true, choose between n possibilities

1 month ago

Or switch.

Code Example

void setup() {
size(1200, 400);
rectMode(CENTER);
colorMode(HSB);
noStroke();
}
void draw() {
if (frameCount%3==0) {
fill((frameCount+125)%255, 255, 255, 15);
rect(width/2, height/2, width, height);
}
if (mousePressed) {
fill(frameCount%255, 255, 255);
float x = random(width);
float y = random(height);
float d = random(25);
int r = int(random(3));
switch(r) {
case 0: d*=2.5; ellipse(x, y, d, d); break;
case 1: rect(x, y, d, d); break;
case 2: d*=0.5; triangle(x, y-d, x-d, y+d, x+d, y+d); break;
}
}
}

karlhungus

Re: when condition is true, choose between n possibilities

1 month ago

using switch here choices are executed randomly on every frame
how to make choose just one while mouse is pressed and choose next
only when mouse is pressed again?

void setup() {
size(1200, 400);
rectMode(CENTER);
}
void draw() {
background(127);
if (mousePressed) {
int r = int(random(3));
switch(r) {
case 0:
ellipse(width/2, height/2, 100, 100);
break;
case 1:
rect(width/2, height/2, 100, 100);
break;
case 2:
line(0, 0, width, height);
break;
}
}
}

asimes

Re: when condition is true, choose between n possibilities

1 month ago

I thought you were dealing with probability when I wrote my first code (first element has a 25% chance of being selected, second element has a 50% chance, etc).

The code you put can be modified to select r once when the mouse is pressed by using mousePressed():

int r;
void setup() {
size(1200, 400);
rectMode(CENTER);
r = (int)random(3);
println("r = "+r);
}
void draw() {
background(127);
switch(r) {
case 0:
ellipse(width/2, height/2, 100, 100);
break;
case 1:
rect(width/2, height/2, 100, 100);
break;
case 2:
line(0, 0, width, height);
break;
}
}
// Called once when the mouse is pressed instead of every frame
void mousePressed() {
r = (int)random(3);
println("r = "+r);
}

amnon.owed

Re: when condition is true, choose between n possibilities

1 month ago

Easy. Instead of randomizing each frame, randomize each mouse press.

Adapted Code

int r;
void setup() {
size(1200, 400);
rectMode(CENTER);
}
void draw() {
background(127);
if (mousePressed) {
switch(r) {
case 0: ellipse(width/2, height/2, 100, 100); break;
case 1: rect(width/2, height/2, 100, 100); break;
case 2: line(0, 0, width, height); break;
}
}
}
void mousePressed() {
r = int(random(3));
}

PhiLho

Re: when condition is true, choose between n possibilities

1 month ago

final int MAX_CHOICES = 3; // final = constant
int r; // 0
void setup() {
size(1200, 400);
rectMode(CENTER);
}
void draw() {
background(127);
switch(r) {
case 0:
ellipse(width/2, height/2, 100, 100);
break;
case 1:
rect(width/2, height/2, 100, 100);
break;
case 2:
line(0, 0, width, height);
break;
}
}
// Better use mousePressed() because mousePressed is detected over several frames!
void mousePressed() {
r = ++ r % MAX_CHOICES;
}

Top Reply