Whack-a-mole Game - Slowing down draw

Programming Questions

RadiantCh..

Whack-a-mole Game - Slowing down draw

in Programming Questions • 1 year ago

So I'm in a Computer Science course and we are coding a whack a mole game. The goal is to have the "mole" (in this case a circle) appear in a random place on the screen, stay there briefly, and then leave. By implementing the mouseClicked method, we then want to use if methods to change the score display on the bottom of the screen when the user clicks the circle. Unfortunately, processing always executes the draw statement before anything else, so it is impossible to simply slow the frame rate to make the game playable. So my question is, how else can I get the circle to stay put, in the simplest way possible? I've tried a variety of things already, but I'm very new to processing and coding in general. Can anyone help?

CODE:

int score;
float x, y;
final int EASY = 300;
final int NRML = 200;
final int HARD = 100;
float diameter = 25;
int height = NRML; //Plug in one of the constants to set
int width = NRML; //a difficulty level.
void setup() {
size(width, height);
background(255);
smooth();
textFont( loadFont("Arial.vlw") );
}
void draw() {
background(255);
fill(255, 155, 0);
x = random(0 + diameter, width - diameter);
y = random(0 + diameter, height - diameter);
ellipse(x, y, diameter, diameter);
x = x;
y = y;
ellipse(x, y, diameter, diameter);
if(score == 1) {
text("Score = 1", 10, NRML - 10);
} else if(score == 2) {
text("Score = 2", 10, NRML - 10);
} else if(score == 3) {
text("Score = 3", 10, NRML - 10);
} else if(score == 4) {
text("Score = 4", 10, NRML - 10);
} else if(score == 5) {
text("Score = 5", 10, NRML - 10);
} else if(score == 6) {
text("Score = 6", 10, NRML - 10);
} else if(score == 7) {
text("Score = 7", 10, NRML - 10);
} else if(score == 8) {
text("Score = 8", 10, NRML - 10);
} else if(score == 9) {
text("Score = 9", 10, NRML - 10);
} else if(score >= 10) {
text("You Win!!", 10, NRML - 10);
} else {
text("Score = 0", 10, NRML - 10);
}
}
void mouseClicked() {
if (x - diameter * .5 <= mouseX && mouseX <= x + diameter * .5 &&
y - diameter * .5 <= mouseY && mouseY <= y + diameter * .5) {
score += 1;
}
}

Replies(8)

calsign

Re: Whack-a-mole Game - Slowing down draw

1 year ago

To start, you don't want to slow down draw() under most any circumstance.

I'm not sure if this is the point of the assignment, but the best way to go about doing this would be to create a Mole class that can stay on the screen for longer than just one frame.
See http://processing.org/learning/objects/.

If this is beyond what you are supposed to be doing right now, I would look at a datatype that you would store globally that would contain the position of the mole. This is akin to OOP, without taking the extra step into writing classes.

For example, I would look at Arrays.
I'll leave the implementation up to you.

CivicImag..

Re: Whack-a-mole Game - Slowing down draw

1 year ago

I'm new to this too, but I can try point you in the right direction. You can slow your frame rate down with frameRate(), but that's probably not the best way to do it. Have a look at Examples-->Topics-->Advanced Data-->ArrayListClass. If you take the move function out of that, you're pretty close to what you need for a circle that disappears.

Also look at GUI-->Buttons to get a better idea of what a mouse over if statement should look like for a circle.

Finally, your code for printing the score can look like this:

if (score < 10) {

text("Score = " + score, 10, NRML - 10);

} else {

text("You Win!!", 10, NRML - 10);

}

Hope that helps.

Edit: looks like I didn't see calsign's comments. Anyway, what he said.

RadiantCh..

Re: Whack-a-mole Game - Slowing down draw

1 year ago

Thanks for the help guys, especially on the shortening of the if statements. However, we haven't covered arrays yet either, and aren't doing so for a couple chapters. So far all we've done is methods, if statements, and simple animation. This isn't the first time that I've had a problem with the class being unclear, which is unfortunate. I know there's a specific answer the prof has in mind, I'm just not sure what it is.

Thanks anyway for your help, though, it's just too advanced at this point.

PhiLho

Re: Whack-a-mole Game - Slowing down draw

1 year ago

x = x; is quite useless...

Don't put x = random( ... ); directly in draw(). Compute it once in setup(), and again when hitting the circle (score += 1). Thus, the circle will have a stable position until it is hit.

RadiantCh..

Re: Whack-a-mole Game - Slowing down draw

1 year ago

Okay, that's all good, but I want the circle to move automatically after a short period of time... if there's no way to do that, though, then I'll just go with that.

Chrisir

Re: Whack-a-mole Game - Slowing down draw

1 year ago

yeah, what you need is a timer

 
see here

with global scope (= at the beginning of the program): 

int lastTime; // When the current circle was first displayed


in setup() : 

  lastTime = millis();


in draw() :


 if (millis() - lastTime >= DISPLAY_TIME) // Time to display next circle
  {

paintCircle();

      lastTime = millis();

in mouseClicked() :

after
score += 1;
use
lastTime = millis ( ) ;

Remark:
Maybe you need one timer for between the drawing of cirlces (not necessary) and one timer for how long one circle stays (necessary).

Greetings, Chrisir

Chrisir

Re: Whack-a-mole Game - Slowing down draw

1 year ago

here is the beast...

you could vary the time how long the circle stays by difficulty level or by random.

int score;
float x, y;
//
final int EASY = 300;
final int NRML = 200;
final int HARD = 100;
//
float diameter = 25;
//
int height = NRML; //Plug in one of the constants to set
int width = NRML; //a difficulty level.
//
int DISPLAY_TIME = 900; // how long it is displayed
int lastTime; // When the current circle was first displayed
//
void setup() {
size(width, height);
background(255);
smooth();
textFont( createFont("Arial.vlw", 16) );
setNewRandomPosition();
lastTime = millis();
}
//
void draw() {
background(255);
fill(255, 155, 0);
ellipse(x, y, diameter, diameter);
// if time to display the circle is over
if (millis() - lastTime >= DISPLAY_TIME)
{
// create new circle
setNewRandomPosition();
lastTime = millis();
}
// print score
if (score < 10) {
text("Score = " + score, 10, NRML - 10);
}
else {
text("You Win!!", 10, NRML - 10);
}
}
//
void mouseClicked() {
if (x - diameter * .5 <= mouseX && mouseX <= x + diameter * .5 &&
y - diameter * .5 <= mouseY && mouseY <= y + diameter * .5) {
score += 1;
// create new circle
setNewRandomPosition() ;
lastTime = millis();
}
}
//
void setNewRandomPosition() {
// creates new circle
x = random(0 + diameter, width - diameter);
y = random(0 + diameter, height - diameter);
}
//

Greetings...

RadiantCh..

Re: Whack-a-mole Game - Slowing down draw

1 year ago

Thanks, that bit of code regarding timing was just what I needed.

Top Reply