Wanna change direction with keypressed

GoToLoop

Re: Wanna change direction with keypressed

7 months ago

I can only guess exactly what you want, since you haven't posted your code.

Here's an example of balloons bouncing when touching the edge of canvas:

/*
 * Bouncing Balloons (v3.1)
 
 * forum.processing.org/topic/using-arrays-to-create-and-change-circles
 * http://forum.processing.org/topic/object
 * http://forum.processing.org/topic/balloon-string
 
 * studio.processingtogether.com/sp/pad/export/ro.9FqnMDLUZqQCV/latest
 
 */

final static color bg = 0, fg = 255;
final static byte  fps = 50;

final static byte ellipNum = 3;
final static myBalloon[] balloons = new myBalloon[ellipNum];

void setup() {
  size (500, 500);
  smooth();
  frameRate(fps);

  balloons[0] = new myBalloon(
  120, 70, // initX, initY
  50, 40, // sizeX, sizeY
  7, 1, // moveX, moveY
  #0000FF); // colour

  balloons[1] = new myBalloon(
  320, 400, // initX, initY
  40, 50, // sizeX, sizeY
  2, -9, // moveX, moveY
  #00FF00); // colour

  balloons[2] = new myBalloon(
  250, 250, // initX, initY
  30, 30, // sizeX, sizeY
  -7, 4, // moveX, moveY
  #FF0000); // colour
}

void draw() {
  background(bg);

  //for ( byte idx=ellipNum; idx!=0; balloons[--idx].all() );

  for ( myBalloon ball: balloons )     ball.all();
}

final class myBalloon {
  int x, y;
  final int szX, szY;
  int mvX, mvY;
  final color cor;

  myBalloon (
  int initX, int initY, 
  int sizeX, int sizeY, 
  int moveX, int moveY, 
  color colour ) {

    x   = initX;
    y   = initY;
    szX = sizeX;
    szY = sizeY;
    mvX = moveX;
    mvY = moveY;
    cor = colour;
  }

  void all() {
    update();
    display();
    strDisplay();
  }

  void update() {
    if ( x < (szX>>1) || x > width  - (szX>>1) )    mvX *= -1;
    if ( y < (szY>>1) || y > height - (szY>>1) )    mvY *= -1;

    x += mvX;
    y += mvY;
  }

  void display() {
    noStroke();
    fill(cor);
    ellipse(x, y, szX, szY);
  }

  void strDisplay() {
    stroke(fg);
    line( x, y+(szY>>1), x-mvX, y+szY );
  }
}

ani_abd

Re: Wanna change direction with keypressed

7 months ago

// Declare the image and the x- and y-coordinate variables

PImage back;

int x, y;

int myRed = 200;

int myGreen = 20;

int myBlue = 20;

void setup()

{

// Initialize the output window size and set stroke to smooth;

size(400, 400);

smooth();

// Load the background image

back = loadImage("green1.JPG");

x= width/2;

y= height/2;

//my colors

}

void draw()

{

// Clear the background to the angry birds image

background(back);

//draw the bird

//tail

noStroke();

fill(0);

quad(x-210, y-210, x-270, y-197, x-265, y-210, x-220, y-190);

quad(x-190, y-212, x-275, y-192, x-277, y-182, x-200, y-212);

quad(x-190, y-220, x-265, y-183, x-260, y-175, x-195, y-220);

//head

stroke(0);

strokeWeight(3);

fill(myRed, myGreen, myBlue);

beginShape();

curveVertex(x-300, y-200);

curveVertex(x-190, y-240);

curveVertex(x-250, y-250);

curveVertex(x-100, y-100);

endShape(CLOSE);

beginShape();

curveVertex(x-300, y-230);

curveVertex(x-200, y-240);

curveVertex(x-235, y-265);

curveVertex(x-300, y-110);

endShape(CLOSE);

ellipse(x-205, y-205, 100, 100);

//dark dots on the body

noStroke();

fill(myRed-33,myGreen-6,myGreen-6);

ellipse(x-210,y-205,20,30);

ellipse(x-168,y-200,20,30);

ellipse(x-225,y-195,10,20);

ellipse(x-235,y-185,10,10);

//tan part on the body

noStroke();

fill(myRed+34, myGreen+166, myBlue+117);

arc(x-195, y-153, 80, 80, radians(192), radians(328));

noFill();

stroke(0);

ellipse(x-205, y-205, 100, 100);

noStroke();

fill(myRed, myGreen, myBlue);

rect(x-230, y-256, 27, 20);

//left eye

stroke(0);

fill(255);

ellipse(x-195,y-204,23,23);

fill(0);

ellipse(x-191,y-204,5,5);

//left eyebrow

quad(x-185, y-215, x-215, y-220, x-215, y-213, x-185, y-210);

//right eye

fill(255);

ellipse(x-173,y-204,23,23);

fill(0);

ellipse(x-178,y-204,5,5);

//right eyebrow

quad(x-185, y-215, x-160, y-220, x-160, y-213, x-185, y-210);

//peak

fill(myRed+55, myGreen+176, myBlue-20);

strokeWeight(2);

stroke(0);

triangle(x-185, y-170, x-170, y-185, x-200, y-185);

fill(myRed+55, myGreen+200, myBlue-20);

beginShape();

curveVertex(x-140, y-20);

curveVertex(x-165, y-185);

curveVertex(x-205,y-185);

curveVertex(x-200, y-185);

curveVertex(x-220,y-185);

endShape(CLOSE);

noStroke();

fill(myRed+34, myGreen+166, myBlue+117);

rect(x-210,y-190,10,10);

//move the bird

x=x+1;

y=y+1;

}

void keyPressed()

{

}

void mousePressed()

{

myRed = myRed-10;

myGreen = myGreen-10;

myBlue = myBlue-10;

}

This is all my code, i just need to change its direction with key press but i dont know how,

I'm kinda amature in this so the baloon example has a lot of codes that i havent learndd yet

Thank

v.k.

Re: Wanna change direction with keypressed

7 months ago

For a very basic movement control, more an example:

// Declare the image and the x- and y-coordinate variables
PImage back;
int x, y;
int incX =1;
int incY =1;
int myRed = 200;
int myGreen = 20;
int myBlue = 20;
void setup()
{
// Initialize the output window size and set stroke to smooth;
size(400, 400);
smooth();
// Load the background image
back = loadImage("green1.JPG");
x= width/2;
y= height/2;
//my colors
}
void draw()
{
// Clear the background to the angry birds image
background(0);
//draw the bird
//tail
noStroke();
fill(0);
quad(x-210, y-210, x-270, y-197, x-265, y-210, x-220, y-190);
quad(x-190, y-212, x-275, y-192, x-277, y-182, x-200, y-212);
quad(x-190, y-220, x-265, y-183, x-260, y-175, x-195, y-220);
//head
stroke(0);
strokeWeight(3);
fill(myRed, myGreen, myBlue);
beginShape();
curveVertex(x-300, y-200);
curveVertex(x-190, y-240);
curveVertex(x-250, y-250);
curveVertex(x-100, y-100);
endShape(CLOSE);
beginShape();
curveVertex(x-300, y-230);
curveVertex(x-200, y-240);
curveVertex(x-235, y-265);
curveVertex(x-300, y-110);
endShape(CLOSE);
ellipse(x-205, y-205, 100, 100);
//dark dots on the body
noStroke();
fill(myRed-33,myGreen-6,myGreen-6);
ellipse(x-210,y-205,20,30);
ellipse(x-168,y-200,20,30);
ellipse(x-225,y-195,10,20);
ellipse(x-235,y-185,10,10);
//tan part on the body
noStroke();
fill(myRed+34, myGreen+166, myBlue+117);
arc(x-195, y-153, 80, 80, radians(192), radians(328));
noFill();
stroke(0);
ellipse(x-205, y-205, 100, 100);
noStroke();
fill(myRed, myGreen, myBlue);
rect(x-230, y-256, 27, 20);
//left eye
stroke(0);
fill(255);
ellipse(x-195,y-204,23,23);
fill(0);
ellipse(x-191,y-204,5,5);
//left eyebrow
quad(x-185, y-215, x-215, y-220, x-215, y-213, x-185, y-210);
//right eye
fill(255);
ellipse(x-173,y-204,23,23);
fill(0);
ellipse(x-178,y-204,5,5);
//right eyebrow
quad(x-185, y-215, x-160, y-220, x-160, y-213, x-185, y-210);
//peak
fill(myRed+55, myGreen+176, myBlue-20);
strokeWeight(2);
stroke(0);
triangle(x-185, y-170, x-170, y-185, x-200, y-185);
fill(myRed+55, myGreen+200, myBlue-20);
beginShape();
curveVertex(x-140, y-20);
curveVertex(x-165, y-185);
curveVertex(x-205,y-185);
curveVertex(x-200, y-185);
curveVertex(x-200, y-185);
curveVertex(x-220,y-185);
endShape(CLOSE);
noStroke();
fill(myRed+34, myGreen+166, myBlue+117);
rect(x-210,y-190,10,10);
//move the bird
x=x+incX;
y=y+incY;
}
void keyPressed(){
if (key == CODED) {
if (keyCode == LEFT)
incX = -1;
if (keyCode == RIGHT)
incX = 1;
if (keyCode == UP)
incY = -1;
if (keyCode == DOWN)
incY = 1;
}
}
void mousePressed()
{
myRed = myRed-10;
myGreen = myGreen-10;
myBlue = myBlue-10;
}

Just so you can get the idea ;)

HTH

ani_abd

Re: Wanna change direction with keypressed

7 months ago

Thanks but still when i press keyboard it doesnt change its direction,

Fir example right now its going from upper left to down right and when i press keyboard it should go visa versa

And again if i press a key it should go the same way

Basicly it should change its direction of movement whenever i press a key and stays that way until i press another key

v.k.

Re: Wanna change direction with keypressed

7 months ago

I edited the code above with the changes in, it respond to key here... Give a try.

GoToLoop

Re: Wanna change direction with keypressed

7 months ago

Gr8 skills on drawing Angry Bird!

I've had an idea to turn your static drawing into a PImage.
That way, we got speed and more control where to place it and check it against canvas' edges!

I've had to seek out how to do some techniques. But it's finally done!
Also, I've let some comments so you can learn from how it was done.

Check it out main tab:

http://studio.processingtogether.com/sp/pad/export/ro.9lSicL0a3WMfi/latest

/**
 * Bouncing Angry Bird (2.75)
 * by ani_abd (2013/Mar)
 * mod GoToLoop
 *
 * http://forum.processing.org/topic/wanna-change-direction-with-keypressed
 */

final static short w  = 0200, h = 0170;
//final static short ww = w >> 1, hh = h >> 1;
PImage imgBG, imgBird = createImage(w, h, ARGB);

final static color BG = 0;

final static byte  sp = 4;
byte  spd = sp;
int   incX = spd, incY = spd;

final static short opac = 0xFF, opacMax = 0xFF;
final static byte  opacStep = 5, opacMin = 0;
short x, y, opacity = opac;

void setup() {
  size(640, 480);
  smooth();
  frameRate(50);
  imageMode(CORNER);

  // Places imgBird's at a random position:
  x = (short) random(width  - w);
  y = (short) random(height - h);

  // Loads background image:
    imgBG = loadImage("G1.jpg");
    imgBG.resize(width, height);

  // Draws bird in the canvas:
  prepareCanvas();
  drawBird(280, 272, 200, 20, 20);

  // Copies PGraphics g to PImage imgBird:
  imgBird.copy(g, 0, 0, w, h, 0, 0, w, h);
}

void draw() {
  // Clears canvas:
  //background(BG);
  background(imgBG);

  // Moves & checks canvas' limits for bird:
  birdUpdate();

  // Displays imgBird:
  int sig = signum(incX); // returns either -1 or 1 for incX
  scale(sig, 1);          // horizontal flip if incX < 0
  image(imgBird, x*sig + w*(sig >> 1), y);

  frame.setTitle
    ("Angry Birds  ---  FPS: " + round(frameRate) + 
    "  ---  Spd: " + spd + "  ---  Opac: " + opacity);
}

void keyPressed() {
  switch (keyCode) {

  case LEFT:
  case 'A':
    incX = -spd;
    break;

  case RIGHT:
  case 'D':
    incX = spd;
    break;

  case UP:
  case 'W':
    incY = -spd;
    break;

  case DOWN:
  case 'S':
    incY = spd;
    break;

  case ALT:
  case 'J':
    --spd;
    refreshSpeed();
    break;

  case ' ':
  case 'K':
    ++spd;
    refreshSpeed();
    break;

  case BACKSPACE:
  case 'H':
    spd = sp;
    refreshSpeed();
    break;

  case ENTER:
  case RETURN:
    if (looping)    noLoop();
    else            loop();
  }
}

void mousePressed() {
  if (mouseButton == LEFT)
    if ( (opacity -= opacStep) < opacMin)
      opacity = opacMax;

  if (mouseButton == RIGHT)
    if ((opacity += opacStep) > opacMax)
      opacity = opacMin;

  if (mouseButton == CENTER)    opacity = opac;

  tint(0xFF, opacity);
}

GoToLoop

Re: Re: Wanna change direction with keypressed

7 months ago

void prepareCanvas() {
  // Loads canvas' PGraphics g into pixels[]:
  loadPixels();

  // Makes PGraphics g 100% transparent black:
  Arrays.fill(pixels, 0);
  updatePixels();
}

void birdUpdate() {
  if ( (x += incX) < 0 | x > width  - w )   incX *= -1;
  if ( (y += incY) < 0 | y > height - h )   incY *= -1;
}

void refreshSpeed() {
  incX = spd * signum(incX);
  incY = spd * signum(incY);
}

int signum(int n) {
  // returns either -1 or 1:
  return n >> 31 | 1;
}

void drawBird(int x, int y, 
color R, color G, color B) {

  //tail
  noStroke();
  fill(R, G, B);
  quad(x-210, y-210, x-270, y-197, x-265, y-210, x-220, y-190);
  quad(x-190, y-212, x-275, y-192, x-277, y-182, x-200, y-212);
  quad(x-190, y-220, x-265, y-183, x-260, y-175, x-195, y-220);

  //head
  stroke(0);
  strokeWeight(3);
  fill(R, G, B);
  beginShape();

  curveVertex(x-300, y-200);
  curveVertex(x-190, y-240);
  curveVertex(x-250, y-250);
  curveVertex(x-100, y-100);

  endShape(CLOSE);

  beginShape();

  curveVertex(x-300, y-230);
  curveVertex(x-200, y-240);
  curveVertex(x-235, y-265);
  curveVertex(x-300, y-110);

  endShape(CLOSE);

  ellipse(x-205, y-205, 100, 100);

  //dark dots on the body
  noStroke();
  fill(R-33, G-6, G-6);
  ellipse(x-210, y-205, 20, 30);
  ellipse(x-168, y-200, 20, 30);
  ellipse(x-225, y-195, 10, 20);
  ellipse(x-235, y-185, 10, 10);

  //tan part on the body
  fill(R+34, G+166, B+117);
  arc(x-195, y-153, 80, 80, radians(192), radians(328));
  noFill();
  stroke(0);
  ellipse(x-205, y-205, 100, 100);
  noStroke();
  fill(R, G, B);
  rect(x-230, y-256, 27, 20);

  //left eye
  stroke(0);
  fill(-1);
  ellipse(x-195, y-204, 23, 23);
  fill(0);
  ellipse(x-191, y-204, 5, 5);

  //left eyebrow
  quad(x-185, y-215, x-215, y-220, x-215, y-213, x-185, y-210);

  //right eye
  fill(-1);
  ellipse(x-173, y-204, 23, 23);

  fill(0);
  ellipse(x-178, y-204, 5, 5);

  //right eyebrow
  quad(x-185, y-215, x-160, y-220, x-160, y-213, x-185, y-210);

  //beak
  fill(R+55, G+176, B-20);
  strokeWeight(2);
  stroke(0);
  triangle(x-185, y-170, x-170, y-185, x-200, y-185);

  fill(R+55, G+200, B-20);

  beginShape();

  curveVertex(x-140, y-20);
  curveVertex(x-165, y-185);
  curveVertex(x-205, y-185);
  curveVertex(x-200, y-185);
  curveVertex(x-200, y-185);
  curveVertex(x-220, y-185);

  endShape(CLOSE);

  noStroke();
  fill(R+34, G+166, B+117);
  rect(x-210, y-190, 10, 10);
}