Visualizing Text, Please Help

General Discussion Other

ollena

Visualizing Text, Please Help

in General Discussion • Other • 1 year ago

Hi guys,

I need some help with my programming again. I have a text document of subtitles of a film.
I need a code that will help me to visualise them.

In this text file subtitles appear like this:
1
00:00:15,549 --> 00:00:17,798
What is your first name, your last name?

2
00:00:18,680 --> 00:00:20,037
My name is Yuri Zhary.

3
00:00:28,760 --> 00:00:31,568
Where did you come from?

4
00:00:38,640 --> 00:00:41,799
l came from...Kharkov.

......

653
01:36:34,359 --> 01:36:35,939
Everything will be...

654
01:37:49,119 --> 01:37:52,279
Would you rather have a boy or a girl?

655
01:42:32,520 --> 01:42:36,140

I need to convert them into dots on a grid.

These subtitles are of a film which is 100 minutes long, I create a grid of every second of the film (so there is 100x60=6000 seconds). So the grid is 78x78 frames (that’s how many seconds there are approx), each frame is 9 pixels, so the grid is 697x697 pixels.

• The seconds of the film that has the subtitles should be represented by the dots in the center of the frame.

• The seconds of the film that has no subtitles should be represented by the empty black frames.

This is a picture illustrating this idea.

Can you please help me to program this process?

I will really appreciate any help.
I'm still a beginner but I try very hard to manage Processing, so I'm sorry in advance for any stupid questions I may ask.

Thanks a lot, you guys are always incredibly helpful and friendly.
Regards,
Ollena

Replies(4)

PhiLho

Re: Visualizing Text, Please Help

1 year ago

Use loadStrings() to load the text file.
Then you have to parse the lines.
Search the forum (from Processing.org) for SimpleDateFormat and how to use it.

ollena

Re: Visualizing Text, Please Help

1 year ago

Thank you.
I'll do what you recommend.

Chrisir

Re: Visualizing Text, Please Help

1 year ago

With lots of help from this great forum, I think I have a program for you...

it takes a few lines to parse the beast first.

please note when you point on a cell with the mouse, the time is displayed in red (only when the cell is on, the cell is white then).

// This sketch is a grid to display the times where a synchonization text is displayed in a movie
//
// http://forum.processing.org/topic/visualizing-text-please-help
//
// the grid
Cell[][] grid;
// Number of columns and rows in the grid
final int cols = 78;
final int rows = 78;
// the size of one cell
final int cellsize = 9;
// time:
// from https://forum.processing.org/topic/subtract-dates-in-arduino-with-processing#25080000001645645
// see below
long ref;
DateFormat df = new SimpleDateFormat("HH:mm:ss");
//
// font
PFont myFont;
void setup() {
// init window
size(rows * cellsize, cols * cellsize);
// necessary for calculating seconds
ref = getTime_Helper ("00:00:00") ;
//
// ---------------------------------------------------------
// prepare the grid ---------
myFont = createFont("Arial", 32);
grid = new Cell[cols][rows];
// The counter variables i and j are also the column and row numbers and
// are used as arguments to the constructor for each object in the grid.
for (int i = 0; i < cols; i++) {
for (int j = 0; j < rows; j++) {
// Initialize each object
grid[i][j] = new Cell(i*cellsize, j*cellsize,
cellsize, cellsize,
i+j);
}
}
//
// ---------------------------------------------------------
// prepare data ---------
// load data
String[] a1 = loadStrings("sync.txt");
// prepare empty array b1
String[] b1 = {
}
;
// fill b1
for (int i = 0; i < a1.length; i++) {
if (a1[i].contains("-->")) {
b1 = (String [])append(b1, a1[i]);
} // if
}
// analyze b1
for (int i = 0; i < b1.length; i++) {
//println(b1[i]);
// replace "-->"
b1[i] = b1[i].replaceAll("-->", "#");
// split
String[] c1=split(b1[i], '#');
// trim
c1[0]=trim (c1[0]);
c1[1]=trim (c1[1]);
println( "//"+ c1[0] + "//" + c1[1] + "//" );
//
// get rid of , and what comes after it (millis)
int commaPos= c1[0].indexOf(',');
c1[0]= c1[0].substring (0, commaPos );
commaPos= c1[1].indexOf(',');
c1[1]= c1[1].substring (0, commaPos );
//
// DateFormat df = new SimpleDateFormat("s");
int date1=0;
int date2=0;
//
// convert to seconds
date1 = getSeconds(c1[0]);
date2 = getSeconds(c1[1]);
//
println( "//"+ c1[0] + "//" + c1[1] + "//" );
print(date1 + " ");
println(date2);
//
// init grid coors
int x=0;
int y=0;
//
// now loop thru all seconds and set them in the grid
for (int k = date1 ; k <= date2; k++) {
println(k);
// convert seconds to x,y
// https://forum.processing.org/topic/get-x-y-in-a-grid-from-a-continous-number-for-all-cells
x = k % rows;
y = k / rows;
// if within range
if (x<cols&&y<rows)
{
grid[x][y].filled = true;
grid[x][y].theTextForTime = c1[0] + " - " + c1[1];
}
else
{
// message as log
print(" Left out ");
}
} // for k
println();
} // for i
} // func
void draw() {
background(255);
fill(0);
stroke(0);
// The counter variables i and j are also the column and row numbers and
// are used as indices
// grid
for (int i = 0; i < cols; i++) {
for (int j = 0; j < rows; j++) {
// display each object
grid[i][j].display();
}
}
// now the text for the time
for (int i = 0; i < cols; i++) {
for (int j = 0; j < rows; j++) {
// if mouse is over
if ( grid[i][j].isOver () ) {
textFont(myFont);
textAlign(CENTER, CENTER);
fill(244, 2, 2);
text ( grid[i][j].theTextForTime, mouseX+7, mouseY+7);
}
}
}
} // func
// =====================================================================
// class
// A Cell object
class Cell {
// A cell object knows about its location in the grid
// as well as its size with the variables x,y,w,h and letter
float x, y; // x,y location
float w, h; // width and height
String theTextForTime=""; // letter
boolean filled = false;
// Cell Constructor
Cell(float tempX, float tempY, float tempW, float tempH, float tempAngle) {
x = tempX;
y = tempY;
w = tempW;
h = tempH;
theTextForTime = "";
} // Constructor
//
boolean isOver() {
// is mouse within cell?
return (mouseX>=x && mouseX<=x+w &&
mouseY>=y && mouseY<=y+h);
} // method
void display() {
// Color and rect
stroke(255);
if (filled)
fill(255);
else
fill(0) ;
rect(x, y, w, h);
} // method
} // class
// ====================================================
/*
from https://forum.processing.org/topic/subtract-dates-in-arduino-with-processing#25080000001645645
getTime() returns the number of milliseconds since the epoch, some past reference. So it always be a big number...
*/
int getSeconds(String date)
{
return (int((getTime_Helper(date) - ref)/1000));
}
//
long getTime_Helper(String date)
{
try
{
return df.parse(date).getTime();
}
catch (ParseException e)
{
println ("Error");
e.printStackTrace();
return 0;
}
}

ollena

Re: Re: Visualizing Text, Please Help

1 year ago

WOW.
It is amazing, what can I say.
It's a great pattern and it even shows the time when the subtitles appear!!!!
Chrisir you are supercool!
I'm very grateful as always!