vertex shading in PShape

Programming Questions

Prokop Ha..

in Programming Questions • 9 months ago

Hi, I'm potting map defined by values on 2D rectangular grid (in vertexes of the grid), for each rectangular tile (Quad) it should be linearly interpolated from the neighboring vertex values. If I do it by direct (immediate) method it works fine. However, if I try to use PShape (Retained rendering) to improve performance* it does not work. It seems that fill() command change color of the whole shape, instead of just one vertex.

Questins:

Is there any way how to do vertex shading** in PShape ?????
Is in Processing 2.0 still possible use Opengl RenderList ? How? Would it provide linearly interpolated vertex shading?
Or VertexBuffer ?
side question - even with vertex shading of quads, each quad is splitted to 2 triangles, so it is not interpolated correctly. I mean each triangle is interpolated independently, so there is a sharp diagonal seam in between. Is there any fast (GPU based) way how to render really bilinear interpolation between the 4 vertexes of the quad? I was thinking, maybe I can write some GLSL shader to do that?

* - I guess PShape works is something like OpenGL render list or VertexBuffer. I was insporated by examples in Demos>Performance>CubicGridRetained vs. CubicGridImmediate.

** - by vertex shading I mean something like in example Topics>Geometry>RGBcube

Simple example for just one quad:

void setup(){
size(800, 800, P3D);
noStroke();
colorMode(RGB, 1);
translate(400,400);
scale(50);
// using direct( Immediate rendering) - Correct linear interpolation :))
beginShape();
fill( 0x80000000 ); vertex( -1 , -1 );
fill( 0x8000FF00 ); vertex( -1 , +1 );
fill( 0x80FFFF00 ); vertex( +1 , +1 );
fill( 0x80FF0000 ); vertex( +1 , -1 );
endShape(CLOSE);
// using PShape (Retained rendering) - just fill it :((
translate(2.0,0);
PShape s = createShape();
s.fill( 0x80000000 ); s.vertex( -1 , -1 );
s.fill( 0x8000FF00 ); s.vertex( +1 , -1 );
s.fill( 0x80FFFF00 ); s.vertex( +1 , +1 );
s.fill( 0x80FF0000 ); s.vertex( -1 , +1 );
s.end(CLOSE);
shape(s);
}
void draw(){ noLoop(); }

Replies(3)

andres

Re: vertex shading in PShape

9 months ago

PShape.fill() should work per-vertex. However, I can see that your sketch results in a red quad, when using 2.0b7. I run it on the latest build from the source, and the PShape is shaded per-vertex as it should, so it appears that the bug has been solved at some point during after 2.0b7 was released.

The code I used with the build from source is:

PShape s;
void setup() {
size(800, 800, P3D);
noStroke();
colorMode(RGB, 1);
s = createShape();
s.beginShape();
s.fill( 0x80000000 );
s.vertex( -1, -1 );
s.fill( 0x8000FF00 );
s.vertex( +1, -1 );
s.fill( 0x80FFFF00 );
s.vertex( +1, +1 );
s.fill( 0x80FF0000 );
s.vertex( -1, +1 );
s.endShape(CLOSE);
}
void draw() {
background(0);
translate(400, 400);
scale(50);
beginShape();
fill( 0x80000000 );
vertex( -1, -1 );
fill( 0x8000FF00 );
vertex( +1, -1 );
fill( 0x80FFFF00 );
vertex( +1, +1 );
fill( 0x80FF0000 );
vertex( -1, +1 );
endShape(CLOSE);
translate(2.0, 0);
shape(s);
}

Note the changes in the PShape API: PShape.beginShape()/endShape(), which will be documented once the new version is out.

Prokop Ha..

Re: vertex shading in PShape

9 months ago

Hi, thank you,

I also found PVector.

setFill(int index, int fill) in the JavaDoc documentation (http://processing.googlecode.com/svn/trunk/processing/build/javadoc/core/index.html) of processing, and it is also working fine for this purpose ( my version of processing is 2.0b6 )

finally, I found that best way is just write the values the grid array to small piece of texture ( PImage of the same dimension as the grid ) and than render it simply by image(); function in big zoom ( using scale() function). The bilinear interpolation of textures works much better than vertex shading, and it is probably also faster.

Question: Is it possible to render textures with bicubic interpolation?

I mean something like this ( http://http.developer.nvidia.com/GPUGems2/gpugems2_chapter20.html )

is there any easy way, or should I try write shader by myself ?

andres

Re: vertex shading in PShape

9 months ago

By default, the OpenGL renderers in Processing (P2D/P3D) render textures using trilinear sampling, which means magnification filtering set to linear, and minification to linear - mipmap -linear (which offers the best mipmap quality since applies linear interpolation to compute the value in each of the two mipmaps surrounding the current level and then interpolates linearly between these two values). This is as long as mipmaps are enabled. If you disable them with hint(DISABLE_TEXTURE_MIPMAPS), then bilinear sampling will be used instead: linear magnification, linear minification. Bicubic interpolation is not included in any of these settings, so you have to implement it yourself in your own texture-rendering shader.

Top Reply