Vertex adding inside for-loop?

Core Library Questions

alberto20..

Vertex adding inside for-loop?

in Core Library Questions • 1 year ago

I need to add vertexes based on array values, so i loop through the array always adding the vertex with the value from the array, but somehow it doesnt seem to work (shape doesnt get drawn)... what's wrong with this simple piece of code? Any help GREATLY appreciated...

import processing.opengl.*;
ArrayList values;
void setup() {
size(500, 500, OPENGL);
smooth();
values = new ArrayList();
values.add(2);
values.add(4);
values.add(4);
values.add(5);
values.add(4);
values.add(4);
drawGraph();
}
void drawGraph() {
background(255);
fill(20, 60, 180, 75);
stroke(20, 60, 180, 75);
translate(width/2, height/2);
beginShape();
for (int i = 0; i <= values.size() - 1; i++) {
int tmpValue = (Integer) values.get(i);
line(0, 0, 0, -40 * tmpValue);
vertex(0, -40 * tmpValue);
rotate(radians(360/values.size()));
}
endShape(CLOSE);
}

Replies(6)

Chrisir

Re: Vertex adding inside for-loop?

1 year ago

hm...
maybe you need a

void draw() {
drawGraph();
}

before the line

void drawGraph() {

alberto20..

Re: Re: Vertex adding inside for-loop?

1 year ago

its in the setup()

Chrisir

Re: Vertex adding inside for-loop?

1 year ago

it could be that

line(0, 0, 0, -40 * tmpValue);

draws outside the screen, since 0,0 is upper left corner and 0, -40 * tmpValue is far left from that. Bad.

alberto20..

Re: Re: Vertex adding inside for-loop?

1 year ago

ive translated() to width/2 and height/2 so its drawing from the center.

i think it has to do with the rotate() ... but dont know why line() works, but vertex() dont...

byhring

Re: Vertex adding inside for-loop?

1 year ago

You can't draw a line within beginshape and endshape.

Also, rotate doesn't work inside it.

try:

void drawGraph() {

background(255);

fill(20, 60, 180, 75);
stroke(20, 60, 180, 75);

translate(width/2, height/2);
beginShape();

for (int i = 0; i < values.size(); i++) {
    //(float)i/values.size() ranges from 0 to 1, TWO_PI is a
    //360 degree rotation in radians
    float rotationValue = ((float)i/values.size()) * TWO_PI;

    //Trigonometry helps us find the correct coordinates
    int tmpValue = (Integer) values.get(i);
    float vertexX = (-40*tmpValue) * sin(rotationValue);
    float vertexY = (-40*tmpValue) * cos(rotationValue);

    vertex(vertexX, vertexY);
}

endShape(CLOSE);

//Draw lines afterwards
for (int i = 0; i <= values.size() - 1; i++) {
    int tmpValue = (Integer) values.get(i);
    line(0, 0, 0, -40 * tmpValue);
    rotate(radians(360/values.size()));
}
}

alberto20..

Re: Re: Vertex adding inside for-loop?

1 year ago

THANKS!

Top Reply