Vector Math Branching Problem

Programming Questions

berechar

Vector Math Branching Problem

in Programming Questions • 2 years ago

Hello everyone,

Tiny bit by tiny bit i am getting the hang of working with vectors, but i don't know how to fix this one... illustration!

I have a center, from which i create an angle with a random magnitude. From the new point, I want to create a random amount of children, who should "branch" from the original angle, and being distibuted over an ellipse...

really, i don't get this one ..

hopefully someone can help me!
kind regards!

Replies(7)

classiclll

Re: Vector Math Branching Problem

2 years ago

some years ago, i made a class lib. named DEKU.

the DEKU is a model representing the local coordinate system with one/none parent DEKU instance, deku.

you can

0. draw point/line/rect/image mapped vertexes/sphere/box/pole/cone

1. place a new deku on the parent deku's space

2. scale and/or set scale change velocity of a deku, and it's posterity (each coordinate)

3. rotate and/or set rotate change velocity of a deku,, and it's posterity

but it's a beta level, no check of closed loop for example,

and the methods are named in ancient japanese "Yamato Kotoba".

the sample sketch and it's code is here (click to get next scene), and others are here

if it matches your need, i'll make the bilingual version and little usage documentation.

berechar

Re: Re: Vector Math Branching Problem

2 years ago

sounds interesting, but i dont know if you system is for me easy to understand.
ancient japanese sounds quite cool, but i am allready having enough trouble with trying to learn normal japanese :p

if it is not very bothersome for you to create a translation, i would definitly take a look :)

mannytan

Re: Vector Math Branching Problem

2 years ago

What determines the position of the children? Looks like the share the same radius from the branch point so that's a good start.

I'm also guessing that the children of all branches would be scattered along a larger sphere where 0,0,0 is the center. you can come up with a formula which gives you a set of points that are both along the sphere and a certain distance from the branch point (the solution itself would be a circle).

Also look up SLERPS or axis-aligned rotation formulas that returns a vector. You could write your own (which will lead you to the wonderful and confusing world of quaternions) or use toxi's libraries to make your life easier.

berechar

Re: Re: Vector Math Branching Problem

2 years ago

the wonderful and confusing world of quaternions, sounds also really cool, and complicated!!

where should i look for in the toxi libraries ( most of the times when I try to dive into his libs, I dont know where to look) ...

amnon.owed

Re: Vector Math Branching Problem

2 years ago

Your picture reminds me of this: http://www.openprocessing.org/visuals/?visualID=22525

This is a good page to see the vector capabilities of toxiclibs.

berechar

Re: Re: Vector Math Branching Problem

2 years ago

the openprocessing example is indeed a good example of what i would like to achieve!

you only have to switch the 2d into 3d :)

i looked at your link, and clicked to the VEC3D section, and saw a lot of vector functions :)
the problem is now that i really would have no clue how to use them for what i would like to achieve...

toxmeister

Re: Vector Math Branching Problem

2 years ago

That OpenProcessing example is maybe a bit over the top for this use case (no need for physics here :). Below is simple recursive tree growing example from a workshop, which I think is pretty close to your problem and also shows how to use the different vectors to achieve your goal. Hth!

/**
* This demo creates a recursively growing tree using the Vec2D class.
*
* (c) 2010 Karsten Schmidt // LGPLv2 licensed
*/
import toxi.geom.*;
Branch tree;
void setup() {
size(600, 600);
// create the root branch growing straight up
tree=new Branch(new Vec2D(width/2, height), new Vec2D(0, -1), 200, 0);
}
void draw() {
background(255);
tree.update();
tree.draw();
}
class Branch {
int depth;
Vec2D startPos;
Vec2D dir;
Vec2D currPos;
float len, maxLen;
List<Branch> children=new ArrayList<Branch>();
Branch(Vec2D pos, Vec2D dir, float maxLen, int depth) {
this.startPos=pos;
this.dir=dir;
this.depth=depth;
this.maxLen=maxLen;
}
void update() {
// grow to maxLen
len+=(maxLen-len)*0.02;
// update current end pos
currPos=startPos.add(dir.scale(len));
// check if we can branch (plus 10% chance only)
if (canBranch() && random(1)<0.1) {
// create new direction for child branch
Vec2D newDir=dir.getRotated(random(-1,1)*PI/4);
// reduce max length for this branch
float newLen=maxLen*random(0.33,0.8);
// add to list of children (increase tree depth)
children.add(new Branch(currPos.copy(), newDir, newLen, depth+1));
}
// update children
for (Branch c : children) {
c.update();
}
}
void draw() {
// recursively draw branch(es)
line(startPos.x, startPos.y, currPos.x, currPos.y);
for (Branch c : children) {
c.draw();
}
}
// define constraints for branching:
// no more than 5 levels deep
// min 66% grown to full size
// no more than 4 child branches
boolean canBranch() {
return depth<5 && len/maxLen>0.66 && children.size()<4;
}
}

http://postspectacular.com | http://toxiclibs.org

Top Reply