You already load the lines. You need to parse the data (aka process them from text lines into something usable) by splitting the lines into relevant parts using split() or splitTokens(). You can then convert strings to floats using float(). So there are only a few basic operations and you can find more information in the examples and the reference:

• Topics > File IO > LoadFile1
• Topics > File IO > LoadFile2

• http://processing.org/reference/split_.html
• http://processing.org/reference/splitTokens_.html
• http://processing.org/reference/float.html

We can't give you more specific advices, b/c we dunno what's inside "data.txt"!
Those 2 numbers are in the beginning. Or what separates the 1st float from the 2nd, etc...

my data.txt has the following lines

You should read up on arrays. There is a section in Learning, and an article: From several variables to arrays

Hello again, !

Since now I know how your numbers are organized inside that file,
I was able to read and assign them at proper order!

Although you say they're of fractional type ( float ), I can only see integer ones ( int ).
But float is almost always a safe bet anyways!

final static byte numVars = 4;
final static float[] vars = new float[numVars];

final static byte  marginX = 25, marginY = 50;
final static color bg = #C04000;

void setup() {
  size(600, 400);
  frameRate(1);

  stroke(-1);

  String[] data = loadStrings("data.txt");
  for ( int i=0; i!=numVars; vars[i] = float(data[i++]) );
}

void draw() {

  float e, f, g, h, i, j;

  e = vars[0] + vars[1];
  f = vars[0]/e * (width-marginY);
  g = vars[1]/e * (width-marginY);

  h = vars[2] + vars[3];
  i = vars[2]/h * (height-marginY);
  j = vars[3]/h * (height-marginY);

  background(bg);

  fill(150);
  rect(marginX, marginX, f, height-marginY);

  fill(200);
  rect(f+marginX, marginX, g, i);

  fill(-1);
  rect(f+marginX, i+marginX, g, j);
}

Thanks for all the answers everyone! This last batch of code seems to work like I wanted to!

But I was wondering, if the file changes while the program is running will it change according to the new numbers? From what I am seeing it doesn't work. Could I change passive to dynamic or something like that?

You need to reload file to refresh array vars[] contents!
What about putting the reload code in a separate function, like below:

void reloadData() {
  String[] data = loadStrings("data.txt");
  for ( int i=0; i!=numVars; vars[i] = float(data[i++]) );
}

Also, you'll have to decide when to do that though.
You can do it when the user clicks some kinda refresh button or
you can establish a frequency for that to happen automatically.
Or even both! 

Since you have frameRate(1), which is 1 drawing / second;
the line code below within draw() would reload your file once each 30 seconds:

if (frameCount % 30 == 0)    reloadData();

Good luck! 

Thanks for your reply!

I finnally got it working. I copyed a bit of your code and did this:

Traditionally, variables i & j are used as loop iterators.
They're in the same vein as x, y, & z are used for coordinates and unknown numbers.

And you've violated this unspoken "rule"! 
You're using both i & j for something else!  ^_^

I've advised you to make a separate function to read the file into vars[].
In that case, the var i would have its own scope and would not conflict w/ the i within draw()!

It's a good programming rule to put generic code block procedures into their own functions/methods.
This way, they can be called from various places and make code tidy!

Also, even w/ frameRate(1), the file is being read once per second.
That's why I've advised for you to check variable frameCount to skip some frames before loading again.

Here's your code again, w/ some tweaks more.
And also, I've made a saveData() function. Although it's not being used yet!

/**
 * LoadSaveStrings (v3.0)
 * by Nick.Prof (2013/Feb)
 *
 * http://forum.processing.org/topic/
 * using-strings-from-text-file-as-input-for-float-variable
 */

final static byte numVars = 4;
final static float[] vars = new float[numVars];

final static byte  marginX = 25, marginY = 50;
final static color bg = #C04000;

final static String fileName = "data/data.txt";

void setup() {
  size(600, 400);
  frameRate(1);

  stroke(-1);

  reloadData();
}

void draw() {

  if (frameCount % 30 == 0)    reloadData();

  float a, b, c, d, e, f;

  a = vars[0] + vars[1];
  b = vars[0]/a * (width-marginY);
  c = vars[1]/a * (width-marginY);

  d = vars[2] + vars[3];
  e = vars[2]/d * (height-marginY);
  f = vars[3]/d * (height-marginY);

  background(bg);

  fill(150);
  rect(marginX, marginX, b, height-marginY);

  fill(200);
  rect(b + marginX, marginX, c, e);

  fill(-1);
  rect(b + marginX, e + marginX, c, f);
}

void reloadData() {
  String[] data = loadStrings(fileName);
  for ( int i=0; i!=numVars; vars[i] = float(data[i++]) );
}

void saveData() {
  saveStrings( fileName, str(vars) );
}

Thx for the replay but I think I didnt make myself clear xD.

" how to grab data from html"
There are several ways... from wrong to good!

A wrong way is to use, for example, regular expressions to extract the information from the tag soup.
It is a common way, wrong because it is prone to fail on arbitrary HTML code (which have quite complex rules).
It is OK as ad hoc solution, specific to a given page, where you know the structure and style (kind of quotes, etc.).
Of course, getting data from HTML is prone to errors anyway, as the webmaster of the site can decide to change markup, position, etc.

A much better way is to use a library able to parse any kind of HTML, even a badly formatted one. JSoup is a well known and good one. IIRC, some examples has been posted on Processing.org (use the search, Luke!).

Example with Jsoup:

1. import org.jsoup.Jsoup;
2. 
   
3. void setup()
4. {
5.   Document doc = null;
6.   try
7.   {
8.     doc = Jsoup.connect("http://processing.org/download/").get();
9.   }
10.   catch (IOException e)
11.   {
12.     println(e);
13.   }
14.   Element version = doc.select("h3.download-ver > strong").first();
15.   println("=> " + version.text());
16.   println("Done");
17.   exit();
18. }

I've been trying to work out Jsoup, it seems that it might be what I am looking for.

But I dont know how the tags work. Well I can understand it in th example you gave me but with more complex tags I dont know where to begin.

I've been trying to get the AEX numbers in a text file and so far I have found this site witch might be usable.
http://www.beursplaza.com/NLbeurs_koersenaex.asp

Wow, that's old style HTML! Curiously mixing the old, obsolete font tag and the more up-to-date span tag with a style attribute.
To understand how to do this, you need to know how HTML works. If that's the case, that's not to hard. Otherwise, I suggest to read up a bit on the topic, that's fun and useful!
The code:

1. import org.jsoup.Jsoup;
2. import org.jsoup.nodes.*;
3. import org.jsoup.select.*;
4. 
   
5. void setup()
6. {
7.   Document doc = null;
8.   try
9.   {
10.     doc = Jsoup.connect("http://www.beursplaza.com/NLbeurs_koersenaex.asp").get();
11.   }
12.   catch (IOException e)
13.   {
14.     println(e);
15.   }
16.   Elements values = doc.select("#table2 td");
17. //  println(values);
18.   for (Element value : values)
19.   {
20.     println("=> " + value.text());
21.   }
22.   println("Done");
23.   exit();
24. }

Exploring the HTML code, I found out a table with an id, a generally good starting point.
I select all the td tags inside this table.
Then I iterate on them, extracting only the textual part, which is probably the data you want.