Using frameCount and modulus to make an animation seem slower

Programming Questions

Andrew

Using frameCount and modulus to make an animation seem slower

in Programming Questions • 3 months ago

I'm trying to write this so that every 5 frames, an ellipse is drawn, and on the other frames, a rectangle is drawn (to make the ellipse fade out slowly). Help? This returns the error "unexpected token: frameCount"

void setup (){
size (1280,720);
ellipseMode (CENTER);
rectMode(CENTER);
frameRate (30);
background (0);
strokeWeight (5);
}
color[] colorList = {color(255,78,80), color(252,145,58), color(249,212,35), color(237,229,116), color(225,245,196),}; //Creates a list of colors. Add more in a comma-separated list...
void draw () {
int w = width;
int h = height;
float d = random(150, 300);
float x = random(0, width);
float y = random(0, height);
color randomColor = colorList[ (int) random(colorList.length) ];
for (frameCount > 0) {
if (frameCount % 5 = 0 ) {
fill(random(77+-25), random(209+-25), random(230+-25), 100);
stroke(0,0,0,10);
ellipse (x, y, d, d);
} else {
noStroke ();
fill(0,10);
rect(w/2,h/2,w,h);
}
//saveFrame("frame##.png"); // saves frame to sketch folder when mouse pressed
}

Replies(3)

Chrisir

Re: Using frameCount and modulus to make an animation seem slower

3 months ago

Hello,

you had one missing } at the end and one , too much in colorList (at the very end).

Also since frameCount is an built-in var, no need to change it in a for-loop (or it's not allowed maybe).
Instead of using a for-loop just use the built-in loop functionality of draw() itself.

In line 21 testing of equality is done with == (and not with = a single sign).

Looks very cool btw!

Greetings, Chrisir

//
void setup () {
size (1280, 720);
ellipseMode (CENTER);
rectMode(CENTER);
// frameRate (30);
background (0);
strokeWeight (5);
}
color[] colorList = {
color(255, 78, 80), color(252, 145, 58), color(249, 212, 35), color(237, 229, 116), color(225, 245, 196)
}; //Creates a list of colors. Add more in a comma-separated list...
void draw () {
int w = width;
int h = height;
float d = random(150, 300);
float x = random(0, width);
float y = random(0, height);
color randomColor = colorList[ (int) random(colorList.length) ];
// for (frameCount2 > 0) {
if (frameCount % 5 == 0 ) {
fill(random(77+-25), random(209+-25), random(230+-25), 100);
stroke(0, 0, 0, 10);
ellipse (x, y, d, d);
}
else {
noStroke ();
fill(0, 10);
rect(w/2, h/2, w, h);
}
//saveFrame("frame##.png"); // saves frame to sketch folder when mouse pressed
// }
} // draw
//

amnon.owed

Re: Using frameCount and modulus to make an animation seem slower

3 months ago

Some suggestions:

Use autoformat (press CTRL+T) to make your code much more readable.
But don't use autoformat on your current code, because it will crash it (seriously).
Don't know what you mean by for(frameCount>0) but it doesn't make sense.
To make the frameCount + modulu work you have to use == (equals) instead of = (assign).
Those random +- probably don't do what you intend. Check the reference and adapt your code if needed.
Place the ellipse calculations into the same if as the ellipse.
Actually use the color from your list.

Adapted Code

color[] colorList = {
color(255, 78, 80),
color(252, 145, 58),
color(249, 212, 35),
color(237, 229, 116),
color(225, 245, 196),
};
void setup () {
size (1280, 720);
background(0);
strokeWeight(5);
}
void draw () {
if (frameCount % 5 == 0 ) {
float d = random(150, 300);
float x = random(width);
float y = random(height);
color randomColor = colorList[ (int) random(colorList.length) ];
fill(randomColor);
stroke(0, 10);
ellipse(x, y, d, d);
} else {
noStroke();
fill(0, 10);
rect(0, 0, width, height);
}
}

GoToLoop

Re: Using frameCount and modulus to make an animation seem slower

3 months ago

Wow! Peeps here are fast.
There were some serious bugs. But I've ended up w/ this solution:

final color[] colorList = {
  color(255, 78, 80), color(252, 145, 58), 
  color(249, 212, 35), color(237, 229, 116), color(225, 245, 196)
};

int w, h, ww, hh;
boolean toggle;

void setup() {
  size(1280, 720);
  frameRate(30);

  smooth();
  strokeWeight(5);

  ellipseMode(CENTER);
  rectMode(CENTER);

  background(0);

  w = width;
  h = height;

  ww = w >> 1;
  hh = h >> 1;
}

void draw() {
  final int x = (int) random(w);
  final int y = (int) random(h);
  final int d = (int) random(150, 300);

  final color randomColor = colorList[ (int) random(colorList.length) ];

  if (frameCount % 5 == 0) {
    fill(randomColor);
    stroke(0, 10);

    if (toggle = !toggle)    ellipse(x, y, d, d);
    else                     rect(x, y, d, d);
  }

  else {
    noStroke();
    fill(0, 10);
    rect(ww, hh, w, h);
  }
}

P.S.: On 2nd thought, I guess you didn't mean to toggle circles/squares drawing!

Just remove toggle parts. HEHEHE!

Top Reply