Using controlP5, peasycam, and a PGraphics buffer; any thoughts on how to do so?

addisandr..

Using controlP5, peasycam, and a PGraphics buffer; any thoughts on how to do so?

in Contributed Library Questions • 2 years ago

So what I am trying to do is draw into a P3D buffer off screen while the applet is set for P2D. I am able to use this set up to get the text to work right on the labels in controlP5 and then write the buffer to the graphics context to get the 3d drawings I am doing. The issue comes when I want to also rotate the 3d graphics using peasycam. Anyone have any thoughts or has maybe done it before?

here is an example program, it displays how controlP5 can be used with 3D but the camera will not work.

import controlP5.*;
import peasy.*;
// global vars.
ControlP5 controlP5;
PeasyCam cam;
PGraphics3D g3;
PMatrix3D currCamMatrix;
PGraphics buffer;
float rot;
void setup()
{
size(400, 400, P2D);
cam = new PeasyCam(this, 400);
buffer = createGraphics(width, height, P3D);
rot = 0.0;
controlP5 = new ControlP5(this);
controlP5.setAutoDraw(false);
ListBox l = controlP5.addListBox("GUI", 5, 30, 100, height-20);
l.setLabel("Test controlP5");
// g3 = (PGraphics3D)cam.g;
}
void draw()
{
background(0);
// draw the cube.
drawCube();
// refresh the screen with what is
// in the buffer.
refresh();
// draw the "GUI"
drawGUI();
}
void drawCube()
{
buffer.beginDraw();
buffer.pushMatrix();
buffer.background(150);
buffer.colorMode(HSB);
buffer.fill(#66FFFF);
buffer.stroke(#FF3070);
buffer.translate(200, 200);
buffer.rotateY(rot+=.005);
buffer.box(100);
buffer.popMatrix();
buffer.endDraw();
}
void refresh()
{
image(buffer, 0, 0);
}
void drawGUI()
{
// currCamMatrix = new PMatrix3D(cam.g.camera);
// camera();
controlP5.draw();
// buffer.setMatrix();
}

Replies(4)

thomas.di..

Re: Using controlP5, peasycam, and a PGraphics buffer; any thoughts on how to do so?

2 years ago

i too would be interested in how to use peasycam within PGraphics buffer.

but you can do this with the "proscene" library: http://code.google.com/p/proscene/downloads/list
it comes with a lot of very nice examples, and one of these example is exactly what you need (BasicUseOffscreen.pde)

thomas

addisandr..

Re: Using controlP5, peasycam, and a PGraphics buffer; any thoughts on how to do so?

2 years ago

I'll look into that Thomas. I am not opposed to using other libraries to getting the job done that I need but it just seams that ControlP5 and PeasyCam are very commonly used libraries, and using a PGraphics buffer is sometimes a must for your project to work.

addisandr..

Re: Using controlP5, peasycam, and a PGraphics buffer; any thoughts on how to do so?

2 years ago

It seems Proscene might be the best solution. I have read through a bunch of examples and a little documentation, and its seems to cover everything that I was running into issues with. I was actually starting to think about writing a library to combine all the features but it seems I would have written something close and probably not as good as proscene so this was a good find. Thanks again Thomas!

addisandr..

Re: Using controlP5, peasycam, and a PGraphics buffer; any thoughts on how to do so?

2 years ago

I was able to use Proscene libraries to do what I wanted. Here is a sample sketch for anyone else who later runs into the same issue I had.

import remixlab.proscene.*;
import controlP5.*;
// global vars.
Scene scene, GUIscene;
float rot;
ControlP5 controlP5;
PGraphics buffer;
void setup()
{
size(600, 600, JAVA2D);
// initialize the scene.
buffer = createGraphics(600, 600, P3D);
scene = new Scene(this, (PGraphics3D)buffer);
// scene.setGridIsDrawn(false);
// scene.setRadius(200);
rot = 0.0;
controlP5 = new ControlP5(this);
controlP5.setAutoDraw(false);
ListBox l = controlP5.addListBox("GUI", 5, 30, 100, height-20);
l.setLabel("Test controlP5");
}
void draw()
{
background(0);
// 3D drawing.
drawCube();
refresh();
// 2D drawing.
drawGUI();
}
void drawCube()
{
buffer.beginDraw();
scene.beginDraw();
buffer.background(0);
buffer.pushMatrix();
buffer.pushStyle();
buffer.colorMode(HSB);
buffer.fill(#66FFFF);
buffer.stroke(#FF3070);
buffer.rotateY(rot+=.005);
buffer.box(50);
buffer.popStyle();
buffer.popMatrix();
scene.endDraw();
buffer.endDraw();
}
void drawGUI()
{
scene.beginScreenDrawing();
controlP5.draw();
scene.endScreenDrawing();
}
void refresh()
{
image(buffer, 0, 0);
}

Top Reply