Hi,

u use the 'unit' variable as radius for your polygons.
if you want a fixed edge-length, then u can calculate the suitable radius.

this should work:

1.     float radius = (unit* polys.get(i).verts)/(2*PI);
      
       beginShape();
       for (int j = 0; j < polys.get(i).verts; j++) {
         vertex(polys.get(i).x+cos(polys.get(i).rot+TWO_PI/polys.get(i).verts*j)*radius,
         polys.get(i).y+sin(polys.get(i).rot+TWO_PI/polys.get(i).verts*j)*radius);
       }
       endShape(CLOSE);
   

Well, it does expand for polygons with more vertices but the edges are not 50 units. I added a rect() that is 50x50 to test it next to the first polygon:

you are right, somehow i thought the outline of a polygon could be the same as a circle-outline.
maybe i should think twice before i write something when i'm tired...

try:

1. float radius = (unit/2) / sin( PI / polys.get(i).verts);

Awesome, that's perfect. How did you figure that out / could you explain why it works please?

Little optimization:

1.         Polygon poly =  polys.get(i);
2.         float radius = (unit/2) / sin(PI / poly.verts);
3.       
4.         beginShape();
5.         for (int j = 0; j < poly.verts; j++) {
6.           vertex(poly.x + cos(poly.rot + TWO_PI/poly.verts * j) * radius,
7.               poly.y + sin(poly.rot + TWO_PI/poly.verts * j) * radius);
8.         }
9.         endShape(CLOSE);

The .get(i) operation has a little cost...

Hey Asimes, yes sure, i can try to explain.

Every regular n-sided polygon can be divided into n equal triangles, which can be divded into two smaller right triangles.
i found this picture illustrating it:



So we have a right triangle where we know the Side ('unit=50') and the angle between hypothenuse and adjacent (2 *PI / n). We are searching for the radius, the formula for that would then be:
Radius  = ( Side / 2 ) / sin( π / n )

If it's not clear just google for 'Trigonometry' or ' Circumcircle of a Polygon'

Benjamin

Iron13, I made sense of your explanation, the diagram helped a lot, thank you.

asimes, since you are now using classes, you might as well take it one step further and really place the relevant code inside the class.

Adapted Code

1. float unit = 50;
2. int selected, ID;
3.  
4. ArrayList <Polygon> polys = new ArrayList <Polygon> ();
5.  
6. void setup() {
7.   size(800, 400);
8.   smooth();
9.   polys.add(new Polygon(-HALF_PI, width/5, height/2, 3));
10.   polys.add(new Polygon(-HALF_PI, width/2, height/2, 4));
11.   polys.add(new Polygon(-HALF_PI, width-width/5, height/2, 5));
12. }
13.  
14. void draw() {
15.   background(255);
16.   for (Polygon p : polys) {
17.     p.display();
18.   }
19. }
20.  
21. class Polygon {
22.   float rot, x, y;
23.   int verts;
24.   int id;
25.  
26.   Polygon(float inRo, float inX, float inY, int inVe) {
27.     rot = inRo;
28.     x = inX;
29.     y = inY;
30.     verts = inVe;
31.     id = ID++;
32.   }
33.  
34.   void display() {
35.     if (selected == id) { fill(255, 0, 0); } else { fill(255); }
36.     float radius = (unit/2)/sin(PI/verts);
37.     float pv = TWO_PI/verts;
38.     pushMatrix();
39.     translate(x, y);
40.     rotate(rot);
41.     beginShape();
42.     for (int j=0; j<verts; j++) {
43.       vertex(cos(pv*j)*radius, sin(pv*j)*radius);
44.     }
45.     endShape(CLOSE);
46.     popMatrix();
47.   }
48. }
49.  
50. void keyPressed() {
51.   if (keyCode == LEFT && selected > 0) selected--;
52.   if (keyCode == RIGHT && selected < polys.size()-1) selected++;
53.   if (keyCode == UP) polys.get(selected).verts++;
54.   if (keyCode == DOWN && polys.get(selected).verts > 3) polys.get(selected).verts--;
55. }

Calsign, I know that it was to improve speed but I don't know what kind of data it is. When I try to println it it gives me something that looks like gibberish: NGons$Polygon@108f8e0

" if Polygon is a class then what kind of data is Polygon poly =  polys.get(i)? Is it still considered to be a class?"
If I want to be a bit pedantic (or precise), poly has a type, which is a class named Polygon. The data pointed by (referenced by) poly is an instance of that class, an object. This instance is still also pointed by the polys array list...
And as kooogy said, if every object has a default toString() method, as you saw, it isn't very explicit. You can make your own custom toString(), building a string from the fields of the class you judge important to show and returning it. This toString() implementation will be automatically called by println().