Note: don't forget to change the topic type to discussion, since you don't ask a question. I changed it for you (routine...).

At a glance, I see a simple possible optimization:
        if ( dist (wx, wy, vpoints[n].x, vpoints[n].y) <= tempDist) {
          tempDist= dist (wx, wy, vpoints[n].x, vpoints[n].y);
dist() is a costly computation, you do this one twice, just do something like:
        float dst = dist (wx, wy, vpoints[n].x, vpoints[n].y) ;
        if ( dst <= tempDist) {
          tempDist = dst ;
I also wonder why you declare 11 points but use only 10...

Nice effect, anyway.

Thank you PhiLho

I noticed the thread question icon (although I thought I'd chosen discussion or whatever the alternative was!)  but couldn't see a way to edit it afterwards.

I originally came up with the the organic Voronoi idea a long time ago - I think it was one of the first things I 'ported' to processing. I've removed one of those dist() calls and tidied up the 'for' loops/declaration and include the code here for anyone who wants it. I suspect that map() call could be removed with a little thought too :D

For anyone who needs and explanation, it's a simple Voronoi diagram where the reference points are bounced around (like balls in a breakout game). Pixels are then coloured according to how close they are to a reference point.

Five minutes after I'd posted on OpenProcessing I spotted a program (Tiny Cells I think it's called) that seems to do almost exactly the same thing in fewer lines of code and much quicker!

1. 
   
   //GLOBALS
   int numPoints=10;
   vpoint[] vpoints=new vpoint[numPoints];
   void setup() {
   
     size(320, 240);
   
     //create initial points
     for (int f=0;f<numPoints;f++)
       vpoints[f]=new vpoint(10+int(random(width-20)), 10+int(random(height-20)), int(random(-10,10)), int(random(-20,20)));
   }
   
   
   void draw() {
   
     float tempDist, tempDist2;
     color tempPink;
   
     background(0);
    
     //for all window points get nearest dist and colour
     for (int wx=0; wx<width; wx++)
       for (int wy=0; wy<height; wy++) {
         //set impossible value
         tempDist=width;
         for (int n=0; n<numPoints; n++)
         {
           tempDist2 = dist(wx, wy, vpoints[n].x, vpoints[n].y);
           if (tempDist2 <= tempDist) {
             tempDist=tempDist2;
             //set color according to distance
             tempPink=int(map(tempDist, 0, 255, 140, 0));
             set(wx, wy, color(tempPink, tempPink>>1, tempPink>>1));
           }
         }
       }
   
     //move points
     for (int n=0; n<numPoints; n++)
       vpoints[n].update();
   }
   
   
   
   class vpoint {
     int x, y;       //position
     int dx, dy;     //movement deltas
     vpoint(int xx, int yy, int ddx, int ddy) {
       x=xx;
       y=yy;
       dx=ddx;
       dy=ddy;
     }
     void update(){
   
       x+=dx;
       y+=dy;
       if ((x<10) || (x>width-10)) dx=-dx;
       if ((y<10) || (y>height-10)) dy=-dy;
     }
   }
   
   

Another potential gain of speed: instead of using set(), do loadPixels() before the loop, use the pixels[] array to set the color, and don't forget the updatePixels() after the loop.
Actually, you no longer need tempDist (or the other...).
And while the map isn't costly, I am not sure it does what you want to do: I doubt the tempDist actually ranges from 0 to 255, it can go much higher (in theory, up to the diagonal of the sketch).