Move a character to radians

General Discussion Other

kivifreak

in General Discussion • Other • 1 year ago

Hey guys,

my standard of physics isnt thagt high yet (yes still school),

but im working since a long time on a project Cyclops and basically my problem is i cant find out,

how to get the x and y coordinate toward the direction (angle).

So lets say it goes diagonally it would be x+=0.5 and y+=0.5 so x+y=1

I guess i need to do this stuff with sin and cos, but heres my problem.

I only had sin & cos for light-angle calculation, not for this case...

Thanks for your help & support

greetings kivifrea

Replies(4)

Chrisir

Re: Move a character to radians

1 year ago

physics allows us to treat x and y separately.

you paint a ball at x,y

when you want to move it to the right,
go x = x + 1;
when you want to move it to the bottom,
go y = y + 1;

Now you combine the two and it goes diagonal.

Now you can stay with x = x + 1;
but set
y = y + 3;
Thus it will move faster down the right - but the velocity in the x-direction stays the same.

see

http://www.processing.org/learning/topics/linear.html

http://www.processing.org/learning/topics/bounce.html

For angle-stuff

float x = cos(radians(angle)) * radius;
float y = sin(radians(angle)) * radius;


see 
http://www.processing.org/learning/trig/

Greetings, Chrisir

Chrisir

Re: Move a character to radians

1 year ago

I made a small example for sin and cos

int angle=0;
int radius = 100;
void setup() {
size (770, 770);
}
void draw() {
background (0);
// get x and y
float x = cos(radians(angle)) * radius;
float y = sin(radians(angle)) * radius;
// headline
fill(234, 2, 2);
stroke(234, 2, 2);
text("Demonstration of sin and cos",
width/2 - textWidth("Demonstration of sin and cos")/2,
height / 2 -radius - 30);
strokeWeight(1);
line (width/2 - textWidth("Demonstration of sin and cos")/2,
height / 2 -radius - 27,
width/2 + textWidth("Demonstration of sin and cos")/2-8,
height / 2 -radius - 27);
// line from center to current angle
strokeWeight(1);
line (width/2, height / 2,
width/2 + x, height/2 + y);
// show middle point / center
stroke(255, 2, 2);
strokeWeight(5);
point (width/2, height / 2);
// show current angle by adding x and y to center
stroke(2, 244, 222);
point (width/2 + x, height/2 + y);
// show x part
stroke(2, 244, 2);
fill(2, 244, 2);
line (
width/2, height / 2+ radius + 10,
width/2 + x, height / 2 + radius + 10);
text("x = "+x, width/2, height / 2 + radius + 30);
// show y part
stroke(30, 120, 222);
fill(30, 120, 222);
line (
width/2 + radius + 10, height / 2,
width/2 + radius + 10, height / 2 + y );
text("y = "+y, width/2 + radius + 30, height / 2 + 0);
// show angle part
fill(234);
println(angle);
text ("angle = "+ angle, width/2-27, height / 2 - 10 );
// show formula
fill(234);
text( "float x = cos(radians(angle)) * radius;", width/2-227, height - 140 );
text( "float y = sin(radians(angle)) * radius;", width/2-227, height - 120 );
// ----------------
// manage the angle
angle ++;
if (angle>360)
{
angle=0;
}
}

kivifreak

Re: Move a character to radians

1 year ago

Thx soo much :)

Chrisir

Re: Move a character to radians

1 year ago

you're welcome!

Top Reply