Trying to create a gravity system but keep getting NullPointerException and can't find the error...

Programming Questions

Pedro Alm..

Trying to create a gravity system but keep getting NullPointerException and can't find the error...

in Programming Questions • 3 months ago

Hey,

Can anyone help me understand why I'm getting a NullPointerException?

I'm new to this and from what I understand it means I didn't initialize something.. I just can't seem to find what..

I'm trying to learn create a gravitational system, here is my code:

float G_CONSTANT = 6.674;

Planet moon,earth;

void setup(){

size(500,500);

moon = new Planet(100,100,10);

earth = new Planet(300,300,30);

}

void draw(){

moon.display();

moon.gravitationPull(earth);

earth.display();

earth.gravitationPull(moon);

}

class Planet {

int x,y;

float radius = 0;

float mass;

PVector location, velocity, acceleration,gravitation;

Planet(int x_, int y_, float radius_){

x = x_;

y = y_;

location = new PVector(x,y);

velocity = new PVector(0,0);

acceleration = new PVector(0,0);

mass = PI * sq(radius);

}

void display() {

noStroke();

fill(0);

ellipse(x,y,radius*2,radius*2);

}

void gravitationPull(Planet planet_) {

PVector dist = PVector.sub(planet_.location,this.location);

float GmDividedbyMag= ((-G_CONSTANT*planet_.mass)/dist.mag());

PVector gravitation = PVector.mult(dist,GmDividedbyMag);

acceleration = planet_.gravitation;

acceleration.div(planet_.mass);

velocity.add(acceleration);

location.add(velocity);

}

Replies(7)

kooogy

Re: Trying to create a gravity system but keep getting NullPointerException and can't find the error...

3 months ago

where are you getting a null pointer? the error normally tells you which line it occurred in...

benj.n.su..

Re: Trying to create a gravity system but keep getting NullPointerException and can't find the error...

3 months ago

i believe your problem is that in your gravitationPull(Planet planet_) method.

in the line:

acceleration = planet_.gravitation;

you cannot make a new PVector simply by setting it equal to another one such as you would x = y. you have to use the PVectors get() function like so:

acceleration = planet_.acceleration.get();

That gets rid of the null pointer for me, but the code doesn't work. I have to go so I'm sorry I can't debug it in it's entirety.

for help though, check out http://thenartureofcode.com there's a whole chapter on forces.

[EDIT: changed link from org to com]

datguy

Re: Trying to create a gravity system but keep getting NullPointerException and can't find the error...

3 months ago

When you run it, it will highlight the line that's getting a NullPointerException. In this case, it's this line:

    acceleration.div(planet_.mass);

To find the problem, throw in println statements to see what your variables hold.  In this case, there are two variables that could possibly be null (acceleration and planet_).  Adding println statements reveals that acceleration is null.  With this knowledge, you can trace back through your code to find out why.

datguy

Re: Trying to create a gravity system but keep getting NullPointerException and can't find the error...

3 months ago

The problem is that you declared a gravitation variable, but you never set it. This line is suspect:

PVector gravitation = PVector.mult(dist, GmDividedbyMag);

You're declaring a local variable; did you mean to use the instance variable from planet_ or from this?

benj.n.su..

Re: Trying to create a gravity system but keep getting NullPointerException and can't find the error...

3 months ago

the issue i brought up with using the get() method when trying to copy a PVector is for real. you can't set a PVector to another PVector by making them equal to each other. you have to get a copy using get() or it will be null.

datguy is spot on with regard to println-ing everything you can think of. if you do, you'll find that in your gravitationPull() method, nearly all of your variables are coming up as NaN (not a number). i think the reason for this is because the radius isn't properly set in your class. your setup should do this:

class Planet {
int x,y;
float radius; //JUST DECLARE, DO NOT SET YET
float mass;
PVector location, velocity, acceleration,gravitation;
Planet(int x_, int y_, float radius_){
x = x_;
y = y_;
radius = radius_; //MISSING SETTING
location = new PVector(x,y);
velocity = new PVector(0,0);
acceleration = new PVector(0,0);
mass = PI * sq(radius);
}

if you do those two things (get() and set radius), your code will run, although probably not as expected.

I'm in total agreement with datguy that you need to tighten up your local/instance variables. however, with regard to the PVector gravitation, it might actually be the case that pedro almeida is using a local variable. Since the gravitational force will depend on the mass of the two bodies, it has to be generated on the fly. one pattern to do this (which i learned from daniel shiffman's nature of code http://natureofcode.com) is to calc the force of gravity in that manner.

also as datguy pointed out, what's confusing the issue is that you have both the local PVector gravitation, and an instance PVector gravitation which is never set. in your Planet class, you might want to use a scalar instance variable G to represent the strength of gravity as opposed to a PVector gravitation for the force of gravity. i'm not sure i'm going to articulate this right but here goes: a planet does not in and of itself have a force of gravity. gravity is exerted upon the planet the strength of which depends on the mass of the planet and the planets distance to other massive bodies nearby.

check out example 2.6 here: http://natureofcode.com/book/chapter-2-forces/

GoToLoop

Re: Trying to create a gravity system but keep getting NullPointerException and can't find the error...

3 months ago

As said above, it was enough to instantiate all PVectors. Also, used method set() to initialize acceleration.

Planet moon, earth;

void setup() {
  size(500, 500);
  noStroke();
  fill(0);

  moon = new Planet(100, 100, 10);
  earth = new Planet(300, 300, 30);
}

void draw() {
  moon.display();
  moon.gravitationPull(earth);

  earth.display();
  earth.gravitationPull(moon);
}

class Planet {
  int x, y;
  float diam, mass;
  PVector location, velocity, acceleration, gravitation, dist;
  
  final static float G_CONSTANT = 6.674;

  Planet(int xx, int yy, float rad) {
    x = xx;
    y = yy;
    
    diam = 2*rad;
    mass = TWO_PI*rad;

    location = new PVector(x, y);
    velocity = new PVector();
    acceleration = new PVector();
    gravitation = new PVector();
    dist = new PVector();
  }

  void display() {
    ellipse(x, y, diam, diam);
  }

  void gravitationPull(Planet planet) {
    dist = PVector.sub(planet.location, location);
    float GmDividedbyMag= -G_CONSTANT*planet.mass / dist.mag();
    gravitation = PVector.mult(dist, GmDividedbyMag);
    acceleration.set(planet.gravitation);
    acceleration.div(planet.mass);
    velocity.add(acceleration);
    location.add(velocity);
  }
}

Pedro Alm..

Re: Trying to create a gravity system but keep getting NullPointerException and can't find the error...

3 months ago

Thanks a lot guys! I checked out the website The Nature of Code and Its great to learn this stuff!