Trouble with basic 2d collision detection

Programming Questions

michaelhw..

Trouble with basic 2d collision detection

in Programming Questions • 1 year ago

SOLVED - See my last reply for details on how i got the below problem to work.

So i would like the non player circles to change colour whenever they overlap, but i fear i haven't implemented the collide() function properly in the CompBall class.

This is what happens below:

-when circles 0 & 1 overlap, they both do not change colour ( fail)

-when circles 0 & 2 overlap, only circle 0 changes colour ( fail)

-when circles 1 & 2 overlap, they both change colour ( pass)

could any one give me a hand?

thanks :)

Main Class:

CompBall[] cBalls;
PlayerBall player;
//---------------------------------------------------------------------------
void setup() {
size(800, 800);
cBalls = new CompBall[3];
for (int i = 0; i < cBalls.length; i++) {
cBalls[i] = new CompBall(random(500), random(500), 100, 100, i, cBalls);
}
player = new PlayerBall(random(500), random(500), 100, 100);
smooth();
}
//---------------------------------------------------------------------------
void draw() {
stroke(0);
println(frameRate);
background(0);
for (int i = 0; i < cBalls.length; i++) {
cBalls[i].collide();
cBalls[i].move(player.x, player.y, player.repel);
cBalls[i].display();
}
player.move(mouseX, mouseY);
for (int i = 0; i < cBalls.length; i++) {
if (dist(cBalls[i].x, cBalls[i].y, mouseX, mouseY) < 4) {
player.shrink();
}
}
player.display();
if (player.w < 20) {
noLoop();
}
}

CompBall Class:

class CompBall {
float x, y, w, h, speed, gravity;
color c;
int id;
CompBall[] cba;
//---------------------------------------------------------------------------
CompBall(float tx, float ty, float tw, float th, int tempID, CompBall[] tempCBA) {
x = tx;
y = ty;
w = tw;
h = th;
c = color(0, 200, 0);
speed = 2;
id = tempID;
cba = tempCBA;
}
//---------------------------------------------------------------------------
void move(float mx, float my, boolean repel) {
// Distance between X & Y co-ordinates
float diffX = mx - x;
float diffY = my - y;
// Length between the 2 points (pythag)
float len = sqrt((diffX * diffX) + (diffY * diffY));
// Catch any divide by zero situations
if (len != 0)
{
// Work out 1 unit of travel for X & Y
diffX /= len;
diffY /= len;
}
// Move the 1 unit of length by speed
diffX *= speed;
diffY *= speed;
if (!repel) {
// Change the X & Y of the object
x += diffX;
y += diffY;
}
else {
// Change the X & Y of the object
x -= diffX;
y -= diffY;
}
// Ensure the balls don't disappear off the edge
x = constrain(x, w/2, width-w/2);
y = constrain(y, w/2, height-w/2);
}
//---------------------------------------------------------------------------
void collide() {
for (int i = id + 1; i < cba.length; i++) {
float dx = cba[i].x - x;
float dy = cba[i].y - y;
float distance = sqrt(dx*dx + dy*dy);
if ( distance < cba[i].w ) {
c = color(0, 0, 200);
cba[i].c = color(0, 0, 200);
}
else {
c = color(0, 200, 0);
cba[i].c = color(0, 200, 0);
}
}
}
//---------------------------------------------------------------------------
void display() {
ellipseMode(CENTER);
textMode(CENTER);
noStroke();
for (float i = w; i > 0; i-=4) {
fill(c, i);
ellipse(x, y, i, i);
fill(0);
text(id, x, y);
}
}
}

PlayerBall Class:

class PlayerBall {
float x, y, w, h, speed;
color c;
boolean repel;
//---------------------------------------------------------------------------
PlayerBall(float tx, float ty, float tw, float th) {
x = tx;
y = ty;
w = tw;
h = th;
c = color(100, 0, 0);
speed = 1;
}
//---------------------------------------------------------------------------
void move(float mx, float my) {
x = mx;
y = my;
x = constrain(x,w/2,width-w/2);
y = constrain(y,w/2,height-w/2);
}
//---------------------------------------------------------------------------
void shrink() {
w -= 0.5;
h -= 0.5;
}
//---------------------------------------------------------------------------
void display() {
ellipseMode(CENTER);
noStroke();
if (mousePressed) {
for (float i = w; i > 0; i-=4) {
fill(255-i, i);
ellipse(x, y, i, i);
}
repel = !repel;
}
else {
for (float i = w; i > 0; i-=4) {
fill(255-i, 0, 0, i);
ellipse(x, y, i, i);
}
}
}
}

Replies(9)

Ale_

Re: Trouble with basic 2d collision detection

1 year ago

Hi!
You might create a Boolean inside CompBall class, that boolean will store the state of the current ball. If it's overlapped it will be true (i.e). Then, inside the display method you set the color according to that boolean.

class CompBall {

float x, y, w, h, speed, gravity;
boolean overlapped=false;
color c;
int id;
CompBall[] cba;

//---------------------------------------------------------------------------

CompBall(float tx, float ty, float tw, float th, int tempID, CompBall[] tempCBA) {
    x = tx;
    y = ty;
    w = tw;
    h = th;
    c = color(0, 200, 0);
    speed = 2;
    id = tempID;
    cba = tempCBA;
}

[etc.]

void collide( CompBall[] cba) { //you should pass the array to the method
    for (int i = 0; i < cba.length; i++) {
      float dx = cba[i].x - x;
      float dy = cba[i].y - y;
      float distance = sqrt(dx*dx + dy*dy);
      overlapped=false;
      if ( distance < (w/2+cba[i].w/2) && distance>0) {
        overlapped=true;
      }
    }
}

//---------------------------------------------------------------------------

void display() {
    ellipseMode(CENTER);    //maybe you could put this stuff in setup()?
    textMode(CENTER);
    noStroke();
    if (overlapped) {
      c= color(0,0,200);
}else{
c=color(0,200,0);
    }
    for (float i = w; i > 0; i-=4) {
      fill(c, i);
      ellipse(x, y, i, i);
      fill(0);
      text(id, x, y);
    }
}
}

Ale · http://60rpm.tv/i

michaelhw..

Re: Re: Trouble with basic 2d collision detection

1 year ago

Thanks for a solution, but unfortunately what happens now is:

-circle 2 never changes

-when circles 0 & 1 overlap only circle 1 changes

-when circles 1 & 2 overlap, only circle 1 changes

-any changed circles do not revert back to green

Ale_

Re: Trouble with basic 2d collision detection

1 year ago

Sorry, issues of fast responsing... ;-)

void collide(CompBall[] cba) { //you should pass the array to the method
    overlapped=false;
    for (int i = 0; i < cba.length; i++) {
      float dx = cba[i].x - x;
      float dy = cba[i].y - y;
      float distance = sqrt(dx*dx + dy*dy);
      if ( distance <(w/2+cba[i].w/2) && distance>0) {
        overlapped=true;}
    }
}

Ale · http://60rpm.tv/i

michaelhw..

Re: Trouble with basic 2d collision detection

1 year ago

The same problems still remain, the reverting back to green is working again.

i essentially back where i started when i posted the question.

I am thinking, it could be something with the for loop, i'm just not sure what, maybe it's missing out 1 circle on each iteration... hmm...

thank you though!

PhiLho

Re: Trouble with basic 2d collision detection

1 year ago

Wrong approach: each ball is responsible of changing the state of the others balls. This usually leads to redundant work and antagonist states (one changing a ball, another changing it back).
You need to have a supervisor, a separate class or the main code, to iterate on the balls and change them when needed.
The balls must not be aware of the others balls (ie. shouldn't have a reference to them as a field).

Ale_

Re: Trouble with basic 2d collision detection

1 year ago

Hi Michael, I've tried out minutes ago the quick fix I proposed and everything went ok, so I don't understand what's going on in your case.
Albeit, I agree esentially with Phi.lho, despite the fact you can fix it, it's an unefficient approach... maybe you can check efficient collision detection algorithms, as hash maps or quad trees...
- Quarks have a really great sketch on quadtrees and collision detection:
http://www.openprocessing.org/visuals/?visualID=24160
- And I did this humble one on hash-maps and collision detection:
http://www.openprocessing.org/visuals/?visualID=34290

Ale · http://60rpm.tv/i

allonestr..

Re: Trouble with basic 2d collision detection

1 year ago

Without getting stuck into your code, what I think is happening is this:

• you test ball0 against ball1 - say they overlap so you change their colours - now ball0 and ball1 are the new colour, and ball2 is the old colour

• you test ball0 against ball2 - say they don't overlap, now ball1 is the new colour, and ball0 and ball2 are the old colour

• you test ball1 against ball2 - say they don't overlap, now all three balls are the old colour

all this happens in one frame. The results are shown at the end of the frame, so you've missed seeing that ball0 and ball1 did change colour, and all three balls are shown in the old colour.

michaelhw..

Re: Trouble with basic 2d collision detection

1 year ago

OK so i changed a few things, and it works now, i've highlighted the collision parts in red.

-i no longer pass an array to each ball object

-each ball instance has a intersect function to check whether that instance is intersecting with 1 other instance

-from the main draw block i run 2 for loops checking each ball to see if they intersect another

-if true, set a bool in both instances to true, which means they are intersecting

-i took out an else block setting bools to false (not intersecting) as that was the problem allonestring was referring to

-the display() function in each ball instance looks at the bool and chooses what colour to draw with

-the display() function also sets the bool to false <-- this was important and eluded me for a very long time!

and so finally, plenty of things learned along the way, and things now work!

Thanks for all the help people!

Main:

CompBall[] cBalls;
PlayerBall player;
//---------------------------------------------------------------------------
void setup() {
size(800, 800);
// Create computer balls and put them in computer ball array.
// CompBall(x loc, y loc, width, height, speed)
cBalls = new CompBall[3];
for (int i = 0; i < cBalls.length; i++) {
cBalls[i] = new CompBall(random(width), random(height), 100, 100, 2);
}
// Create player ball.
// PlayerBall(x loc, y loc, width, height)
player = new PlayerBall(random(width), random(height), 100, 100);
smooth();
}
//---------------------------------------------------------------------------
void draw() {
//println(frameRate);
background(0);
// Move & display each computer ball in the computer balls array.
for (int i = 0; i < cBalls.length; i++) {
// When calling the move function, pass the players x, y and
// repel value.
cBalls[i].move(player.x, player.y, player.repel);
collision();
cBalls[i].display();
}
// Move the player ball according to where the mouse X & Y are.
// Also check if the player is within 24 pixels of the center
// a computer ball, if so, shrink the player ball. If within
// range of 3 computer balls the shrink is x3 fold and so on.
// Then display the player ball.
player.move(mouseX, mouseY);
for (int i = 0; i < cBalls.length; i++) {
if (dist(player.x, player.y, cBalls[i].x, cBalls[i].y) < 24) {
player.shrink();
}
}
player.display();
// If the player has shrunk to below 30 pixels in diameter (15
// radius) then end the game, player has lost.
if (player.w < 30) {
noLoop();
}
}
//---------------------------------------------------------------------------
// Iterate through each computer circle in the array and compare it with a
// circle from another internal array, passing the j instance through to
// an i instance's intersect function, which checks whether they intersect
// IF true then toggle the intersect flag to true.
// NOTE: in the display() function of each computer ball, the intersecting
// bool is set to false on every frame draw.
void collision() {
for (int i = 0; i < cBalls.length; i++) {
for (int j = i + 1; j < cBalls.length; j++) {
if ( cBalls[i].intersect( cBalls[j] ) ) {
cBalls[i].intersecting = true;
cBalls[j].intersecting = true;
}
}
}
}
//---------------------------------------------------------------------------
// If the player presses any mouse button, toggle the repel function.
void mousePressed() {
player.repel = !player.repel;
}

CompBall:

class CompBall {
float x, y, w, h, speed, oSpeed;
float gravity = 0.01;
boolean intersecting = false;
//---------------------------------------------------------------------------
CompBall(float tx, float ty, float tw, float th, float tspeed) {
x = tx;
y = ty;
w = tw;
h = th;
speed = tspeed;
oSpeed = tspeed;
}
//---------------------------------------------------------------------------
void move(float mx, float my, boolean repel) {
// Distance between X & Y co-ordinates
float diffX = mx - x;
float diffY = my - y;
// Length between the 2 points (pythag)
float len = sqrt((diffX * diffX) + (diffY * diffY));
// Catch any divide by zero situations
if (len != 0)
{
// Work out 1 unit of travel for X & Y
diffX /= len;
diffY /= len;
}
// Add gravity to ball when not repelling makes it harder the longer you take
if (!repel) {
speed += gravity;
speed = constrain(speed, 1, 10);
}
// If repel mode is activated return the speed to it's intiated value
else {
speed = oSpeed;
}
// Move the 1 unit of length by speed
diffX *= speed;
diffY *= speed;
if (!repel) {
// Change the X & Y of the object
x += diffX;
y += diffY;
}
else {
// Change the X & Y of the object
x -= diffX;
y -= diffY;
}
// Ensure the balls don't disappear off the edge
x = constrain(x, w/2, width-w/2);
y = constrain(y, w/2, height-w/2);
}
//---------------------------------------------------------------------------
// Check this circle instance with the passed through instance
// to see whether they are intersecting or not.
// NOTE: in display() function, insterseting is always reset to
// false.
boolean intersect(CompBall cb) {
float distance = dist(x, y, cb.x, cb.y);
if ( distance < (w/2) + (cb.w/2) ) {
return true;
}
else {
return false;
}
}
//---------------------------------------------------------------------------
void display() {
ellipseMode(CENTER);
noStroke();
// Use for loop with ellipses and decrease the colour by i
// to produce a gradient effect for each computer ball.
for (float i = w; i > 0; i-=4) {
if (intersecting) {
fill(0, 0, 255-i, i);
}
else {
fill(0, 255-i, 0, i);
}
ellipse(x, y, i, i);
}
// THIS WAS THE MOST IMPORTANT THING FOR COLLISION NEVER FORGET THIS PART WTF!
// Always assume circle is not intersecting.
intersecting = false;
}
}

PhiLho

Re: Trouble with basic 2d collision detection

1 year ago

" plenty of things learned along the way, and things now work!"
That's why in general I give general indications instead of real code (beside the fact that I have limited time!), as most users here enjoy dabbling with code and want to learn. One can learn from reading code, but learning is more complete when one made errors and solved them by themselves (with a little help from their friends, of course).

Top Reply