trouble sending values from array to a class

joshmyc

trouble sending values from array to a class

in Contributed Library Questions • 1 years ago

Hi,

can anyone point me in right direction; I want individual balls to move with the slider positioned below it (presently they all move together). I can do this when not using classes and arrays , but am stuck on how you pass the slider value into the the balls xposition...

import controlP5.*;
ControlP5 controlP5;
Mixball[] mixball = new Mixball[5];
Slider[] mySlider = new Slider[5];
int sliderValue = 200;
void setup() {
controlP5 = new ControlP5(this);
size(900,400);
smooth();
for (int m=0 ; m<mixball.length; m ++){
mixball[m] = new Mixball(m*160, m , 10,10);
}
for (int i=0 ; i<mySlider.length; i ++){
mySlider[i] = controlP5.addSlider("sliderValue",0,200,0,i* 160+20,298,25,100);
}
}
void draw() {
background(0);
fill(255,0,0);
for (int m =0; m<mixball.length; m ++){
mixball[m].display();
mixball[m].move();
}
}
class Mixball{
int xpos;
int ypos;
int width;
int height;
Mixball(int _xpos, int _ypos, int _width, int _height){
xpos= _xpos;
ypos = _ypos;
width = _width;
height = _height;
}
void display(){
ellipse (xpos+20,ypos, width, height);
fill (255,0,0);
}
void move(){
ypos = height*24-sliderValue;
}
}

Replies(13)

v.k.

Re: trouble sending values from array to a class

1 years ago

Nov 7, 2011 12:47:48 PM controlP5.ControlP5 checkName

WARNING: Controller with name "sliderValue" already exists. overwriting reference of existing controller.

Nov 7, 2011 12:47:48 PM controlP5.ControlP5 checkName

WARNING: Controller with name "sliderValue" already exists. overwriting reference of existing controller.

Nov 7, 2011 12:47:48 PM controlP5.ControlP5 checkName

WARNING: Controller with name "sliderValue" already exists. overwriting reference of existing controller.

Nov 7, 2011 12:47:48 PM controlP5.ControlP5 checkName

WARNING: Controller with name "sliderValue" already exists. overwriting reference of existing controller.

That' s the message in console when i run your sketch. All sliders have the same name, it can't be...

maybe u can do

for (int i=0 ; i<mySlider.length; i ++){

mySlider[i] = controlP5.addSlider("sliderValue"+ i,0,200,0,i* 160+20,298,25,100);

}

Wich will clear the error, now u need to tell move() witch value to use...

joshmyc

Re: trouble sending values from array to a class

1 years ago

hey v.k.,

thanks for that. You end your reply with;

"... now u need to tell move() witch value to use.."

this is what is causing confusion for me.. what format would this take to pass slider value into moves arguments?

joshmyc

Re: trouble sending values from array to a class

1 years ago

hi processing forum,

have been struggling with this further.. still not working. Please could someone help clarify this for me... how can i send the individual slider values to the mixball.move(). I would be really grateful for some help here.....

v.k.

Re: trouble sending values from array to a class

1 years ago

joshmyc, I'm new to controlP5, but take a look at the example: "controlP5basic". It explains that a controlP5 item will trig a function with the same name. I still not sure about the "public void controlEvent(ControlEvent theEvent)" but i got things working without it. (some one can explain this?) .

I edited your code in a way things are working, but not sure if is THE way to go... but it's a start.

good luck. (the println() functions are for illustration and should be eliminated later)

import controlP5.*;
ControlP5 controlP5;
Mixball[] mixball = new Mixball[5];
Slider[] mySlider = new Slider[5];
int sliderValue = 200;
int[] slider = new int[5];
void setup() {
controlP5 = new ControlP5(this);
size(900,400);
smooth();
for (int m=0 ; m<mixball.length; m ++){
mixball[m] = new Mixball(m*160, m , 10,10);
}
for (int i=0 ; i<mySlider.length; i ++){
mySlider[i] = controlP5.addSlider("sliderValue"+i,0,200,0,i* 160+20,298,25,100);
}
}
void draw() {
background(0);
fill(255,0,0);
for (int m =0; m<mixball.length; m ++){
mixball[m].display();
mixball[m].move(slider[m]);
}
}
void sliderValue0(int theValue)
{
slider[0]=theValue;
println("I'm slider0 value ="+slider[0]);
}
void sliderValue1(int theValue)
{
slider[1]=theValue;
println("I'm slider1 value ="+slider[1]);
}
void sliderValue2(int theValue)
{
slider[2]=theValue;
println("I'm slider2 value ="+slider[2]);
}
void sliderValue3(int theValue)
{
slider[3]=theValue;
println("I'm slider3 value ="+slider[3]);
}
void sliderValue4(int theValue)
{
slider[4]=theValue;
println("I'm slider4 value ="+slider[4]);
}
/////
class Mixball{
int xpos;
int ypos;
int width;
int height;
Mixball(int _xpos, int _ypos, int _width, int _height){
xpos= _xpos;
ypos = _ypos;
width = _width;
height = _height;
}
void display(){
ellipse (xpos+20,ypos, width, height);
fill (255,0,0);
}
void move(int value){
ypos = height*24-value;
}
}

joshmyc

Re: trouble sending values from array to a class

1 years ago

cool, thanks v.k.!

i reckon i might initiate the slide values as a for or while loop, to minimise the amount of code- i guess this will have to be be done in setup?

andreas.s..

Re: trouble sending values from array to a class

1 years ago

@v.k controlEvent is the default method for controlp5 to look for in your sketch to send events triggered by a controller to. making use of method controlEvent() inside your sketch is optional.

for joshmyc's case there are different options to handle and forward controller events to individual objects.

1) access the value of a controller by making a request to controlP5 using the name of a controller as reference:

import controlP5.*;
ControlP5 controlP5;
Mixball[] mixball = new Mixball[5];
Slider[] mySlider = new Slider[5];
int sliderValue = 200;
void setup() {
controlP5 = new ControlP5(this);
size(900,400);
smooth();
for (int m=0 ; m<mixball.length; m ++){
mixball[m] = new Mixball(m*160, m , 10,10);
mySlider[m] = controlP5.addSlider("sliderValue"+m,0,200,0,m* 160+20,298,25,100);
}
}
void draw() {
background(0);
fill(255,0,0);
for (int m =0; m<mixball.length; m ++){
mixball[m].display();
// request a value by controller name
// issue to be aware of here: if the controller is not available, a
// nullpointerexception will be thrown.
int n = int(controlP5.controller("sliderValue"+m).value());
mixball[m].move(n);
}
}
/////
class Mixball{
int xpos;
int ypos;
int width;
int height;
Mixball(int _xpos, int _ypos, int _width, int _height){
xpos= _xpos;
ypos = _ypos;
width = _width;
height = _height;
}
void display(){
ellipse (xpos+20,ypos, width, height);
fill (255,0,0);
}
void move(int value){
ypos = height*24-value;
}
}

2) reference by id, use controlEvent() to evaluate an event triggered by a controller

import controlP5.*;
ControlP5 controlP5;
Mixball[] mixball = new Mixball[5];
void setup() {
controlP5 = new ControlP5(this);
size(900, 400);
smooth();
for (int m=0 ; m<mixball.length; m ++) {
mixball[m] = new Mixball(m*160, m, 10, 10);
// add a new slider and set it's id
controlP5.addSlider("sliderValue"+m, 0, 200, 0, m* 160+20, 298, 25, 100).setId(m);
}
}
void draw() {
background(0);
fill(255, 0, 0);
for (int m =0; m<mixball.length; m ++) {
mixball[m].display();
}
}
public void controlEvent(ControlEvent theEvent) {
// check if the event's name (which corresponds to the controller name)
// is correct and starts with the right prefix
if (theEvent.name().startsWith("sliderValue")) {
int id = theEvent.id();
// check if the id is within the anticipated range
if (id>=0 && id<mixball.length) {
mixball[id].move(int(theEvent.value()));
}
}
}
class Mixball {
int xpos;
int ypos;
int width;
int height;
Mixball(int _xpos, int _ypos, int _width, int _height) {
xpos= _xpos;
ypos = _ypos;
width = _width;
height = _height;
move(0);
}
void display() {
ellipse (xpos+20, ypos, width, height);
fill (255, 0, 0);
}
void move(int value) {
ypos = height*24-value;
}
}

v.k.

Re: trouble sending values from array to a class

1 years ago

andreas thanks I really was confused about. Seems to me that the controlEvent way is more clear. How does this interfere with built in mousePressed() function? Another thing if i hide() a controller does it still reading inputs? Is there an activate() or something like? Also i read some where that u are going to release a new version soon.Is that so?

joshmyc, u see i told you... I did not really know...

v.k.

Re: trouble sending values from array to a class

1 years ago

If i do:

// request a value by controller name
// issue to be aware of here: if the controller is not available, a
// nullpointerexception will be thrown.
if(controlP5.controller("sliderValue"+m.getValue()) != null){
int n = int(controlP5.controller("sliderValue"+m).getValue());
} else{
int n = defaultValue;
}
mixball[m].move(n);

Will i be protected from nullpointer exception?

andreas.s..

Re: trouble sending values from array to a class

1 years ago

try:

int n = defaultValue;
// make sure the controller request does not return null
if(controlP5.controller("sliderValue"+m) != null) {
n = int(controlP5.controller("sliderValue"+m).getValue());
}
mixball[m].move(n);

I have been working on updates for a while now but havnt reached the final go yet. Also note that version 0.5.4 does not work with processing 2.0 (which is currently in alpha). In case you are using a 2.0a version, use a 0.6.x controlP5 version until i finally get the next featured release out.

you can follow the development here http://code.google.com/p/controlp5

the latest test version is filed here http://code.google.com/p/controlp5/downloads/list (using a 0.6.x version number)

v.k.

Re: trouble sending values from array to a class

1 years ago

Thanx, I will...

joshmyc

Re: trouble sending values from array to a class

1 years ago

hi andreas,

trying the code you posted above; in example 1 i get the error;

the function getValue() does not exist...

andreas.s..

Re: trouble sending values from array to a class

1 years ago

ah, i was using post 0.5.4 syntax. getValue() should be value() here. I made changes to my previous post.

joshmyc

Re: trouble sending values from array to a class

1 years ago

o.k.so now i have added a knob to the sketch to move the xpos of the ellipses.. i am confused as to how i give the knob a value to pass to move..

i have included my attempt.. could someone point out where i've slipped up?

import controlP5.*;
ControlP5 controlP5;
Mixball[] mixball = new Mixball[5];
//Slider[] mySlider = new Slider[5];
//int sliderValue = 200;
//int knobValue = 200;
//Knob[] myKnob= new Knob[5];
void setup() {
controlP5 = new ControlP5(this);
size(900, 400);
smooth();
for (int m=0 ; m<mixball.length; m ++) {
mixball[m] = new Mixball(m*160, m, 10, 10);
controlP5.addSlider("sliderValue"+m, 0, 200, 0, m* 160+20, 298, 25, 100).setId(m);
controlP5.addKnob("dialValue"+m, 0, 200, m* 160+20, 238, 25).setId(m);
}
}
void draw() {
background(0);
fill(255, 0, 0);
for (int m =0; m<mixball.length; m ++) {
mixball[m].display();
}
}
public void controlEvent(ControlEvent theEvent) {
// check if the event's name (which corresponds to the controller name)
// is correct and starts with the right prefix
if (theEvent.isController()) {
if (theEvent.controller().name().startsWith("sliderValue"))
{
int id = theEvent.id();
// check if the id is within the anticipated range
if (id>=0 && id<mixball.length)
{
mixball[id].move(int(theEvent.value()));
}
}
if (theEvent.controller().name().startsWith("knobValue"))
{
int id = theEvent.id();
// check if the id is within the anticipated range
if (id>=0 && id<mixball.length)
{
mixball[id].move(int(theEvent.value()));
}
}
}
}
/////
class Mixball {
int xpos;
int ypos;
int width;
int height;
Mixball(int _xpos, int _ypos, int _width, int _height) {
xpos= _xpos;
ypos = _ypos;
width = _width;
height = _height;
}
void display() {
ellipse (xpos+20, ypos, width, height);
fill (255, 0, 0);
}
void move(int value) {
ypos = height*24-value;
//xpos= width-value;
}
}

Top Reply