translate and scale and then check mouseX and mouseY!? Flowchart

Programming Questions

Chrisir

translate and scale and then check mouseX and mouseY!? Flowchart

in Programming Questions • 1 year ago

Hello,

this is probably simple but I couldn't find it on the forum.

I did a flowchart and you can click the single items and drag them.

This is done in the class with checking if mouseX and mouseY are within the item
and when it is the item returns mouseOver == true and can be dragged. Works fine.
Line 406/407 are bold.

But when I scale or translate the whole graphic (right mouse button drag)
the items wander on the screen but mouseX and mouseY don't.

So the checking if mouseX and mouseY are within the item doesn't work anymore.

I tried to multiply the mouseX and mouseY with my var myScale but didn't work.

What is the formula please to check if mouseX and mouseY are within the item?

Thank you so much!

Greetings, Chrisir

// this prgram provides a flowchart / diagram
// http://en.wikipedia.org/wiki/Flowchart
ArrayList<GraphicalItem> graphicalItems;
//
final color lightGreen = color (2, 244, 2, 22);
final color lightBlue = color(2, 0, 244, 22);
// State of program
final int stateNormal = 0;
int state=stateNormal;
//
// for graphical:
final int typeOfGraphicalItemStandardWithHeader = 0;
final int typeOfGraphicalItemStandardWithoutHeader = 1;
final int typeOfGraphicalItemConditional = 2;
final int typeOfGraphicalItemStartEnd = 3;
//
// for graphical: which adaptor is used on a box?
// (clockwise) north, east, south or west.
final int adaptorNorth=0;
final int adaptorEast=1;
final int adaptorSouth=2;
final int adaptorWest=3;
//
// for scale and translating
float myScale = 1.0;
float myTranslate = 0.0; // only y-direction
// where to place next box vertically
int lineY = 40;
//
// for drag and drop:
// mouse dragged?
boolean hold=false;
GraphicalItem holdItem ; // which item is dragged
// for drag and drop: difference between the upper left corner
// x,y position and where mouse clicked in the graphical item
PVector offSet;
// ---------------------------------------------------------------
void setup() {
// size( screen.width, screen.height );
size( 800, 600 );
smooth();
noStroke();
fill(0);
offSet=new PVector();
// Create an empty ArrayList
graphicalItems = new ArrayList();
// fill the ArrayList
initGraphical() ;
} // func
//
//
void draw() {
background(255);
//
if (state==stateNormal) {
scale(myScale);
translate( 0, myTranslate ) ;
showGraphical();
}
else {
println ("Error 182" );
}
} // func
//
//
// =================================================================
// Init items
void initGraphical() {
// fills the graphicalItems in the arrayList
graphicalItems.clear();
lineY = 40;
//
graphicalItems.add ( new GraphicalItem(
typeOfGraphicalItemStandardWithHeader, 20, lineY,
"Entry 0", "This is interesting",
null,
lightGreen ));
int EntryGreen = graphicalItems.size()-1;
graphicalItems.add ( new GraphicalItem(
typeOfGraphicalItemStandardWithHeader, 320, lineY,
"Entry 1", "This is lightblue ",
new AdaptorType(EntryGreen, adaptorWest, adaptorEast),
lightBlue ));
int EntryBlue = graphicalItems.size()-1;
graphicalItems.add ( new GraphicalItem(
typeOfGraphicalItemConditional,
100, lineY+100,
"", "Conditional",
new AdaptorType(EntryGreen, adaptorNorth, adaptorSouth),
color (0) ));
int EntryConditional = graphicalItems.size()-1;
lineY+=70;
graphicalItems.add ( new GraphicalItem(
typeOfGraphicalItemStartEnd,
180, lineY+100,
"", "Test2",
new AdaptorType(EntryConditional, adaptorNorth, adaptorEast),
color (0) ));
lineY+=70;
graphicalItems.add ( new GraphicalItem(
typeOfGraphicalItemStartEnd,
40, lineY+100,
"", "Test3",
new AdaptorType(EntryConditional, adaptorNorth, adaptorWest),
color (0) ));
int EntryStartItem = graphicalItems.size()-1;
graphicalItems.add ( new GraphicalItem(
typeOfGraphicalItemStandardWithoutHeader,
240, lineY+200,
"", "Test3",
new AdaptorType(EntryBlue, adaptorNorth, adaptorSouth),
color (0) ));
//
// add further Line to last item. This line
// goes from the last item (it's west side) to item
// number EntryStartItem (south)
AddLineToElement( graphicalItems.size()-1,
EntryStartItem,
adaptorWest,
adaptorSouth );
//
} // func
//
// Inputs ****************************************************
//
void mousePressed() {
if (state==stateNormal) {
if (mouseButton==LEFT) {
for (int i = 0; i <= graphicalItems.size()-1; i++ ) {
GraphicalItem myGraphicalItem1 = graphicalItems.get(i);
if (myGraphicalItem1.isMouseOver()) {
hold = true;
holdItem = myGraphicalItem1;
offSet.x= myGraphicalItem1.Position.x-mouseX;
offSet.y= myGraphicalItem1.Position.y-mouseY;
}
} // for
} // if
} // if
} // func
//
void mouseDragged() {
if (state==stateNormal) {
if (hold) {
holdItem.Position.x = mouseX+offSet.x;
holdItem.Position.y = mouseY+offSet.y;
}
if (mousePressed && mouseButton == RIGHT) {
myScale = map(mouseX, 0, width, 0, 2);
myTranslate = map(mouseY, 0, height, -height, height);
} // if
} // if
} // func
//
void mouseReleased () {
if (state==stateNormal) {
if (mouseButton == LEFT) {
hold = false;
}
}
} // function
//
void keyPressed () {
if (state==stateNormal) {
//
if (key=='r') {
myScale = 1.0;
myTranslate = 0.0;
}
}
else {
println("Error 429: unknown state ");
}
} // keyPressed
//-----------------------------------------------------------
//
void AddLineToElement( int NumberOfStartItem, int NumberOfTargetItem,
int adaptor1, int adaptor2) {
// add a line
GraphicalItem itemStart = graphicalItems.get(NumberOfStartItem);
itemStart.addAdaptor ( new AdaptorType(NumberOfTargetItem, adaptor1, adaptor2) );
}
//
void showGraphical() {
// show the graphicalItems from the arrayList
textAlign(LEFT);
text ( "Graphical Representation"
+ " - "
+ "Move items with left Mouse button. Drag with right mouse button: scale "
+ "(x-direction) and up/down (y-direction).", 20, 14 );
if (graphicalItems.isEmpty()) {
text("Graphical Diagram is empty.", 220, 170 );
}
else
{
for (int i = 0; i <= graphicalItems.size()-1; i++ ) {
GraphicalItem myGraphicalItem1 = graphicalItems.get(i);
myGraphicalItem1.display() ;
} // for
} // if else
} // func
//
GraphicalItem getElement( String textHeaderParam, String textNormalParam ) {
// returns object or null
for (int i = 0; i <= graphicalItems.size()-1; i++ ) {
GraphicalItem myGraphicalItem1 = graphicalItems.get(i);
if (myGraphicalItem1.textHeader.equals(textHeaderParam) &&
myGraphicalItem1.textNormal.equals(textNormalParam)) {
return myGraphicalItem1;
} // if
} // for
return null;
} // func
//
int getElementNumber( String textHeaderParam, String textNormalParam ) {
// returns number of object or -1
for (int i = 0; i <= graphicalItems.size()-1; i++ ) {
GraphicalItem myGraphicalItem1 = graphicalItems.get(i);
if (myGraphicalItem1.textHeader.equals(textHeaderParam) &&
myGraphicalItem1.textNormal.equals(textNormalParam)) {
return i;
} // if
} // for
return -1;
} // func
//
// ==============================================================
class GraphicalItem {
//
PVector Position; // Pos and size of the whole box
PVector boxSize; // Size
final int headerHeight = 20; // Height of header text box
color headerColor; // color of header box
// the type of the item
int typeOfGraphicalItem;
// texts
String textHeader="";
String textNormal="";
// Positions of adaptors
PVector adaptorLeft, adaptorRight;
PVector adaptorUp, adaptorDown;
//
// where the adaptors lead to: array of
// AdaptorType (see class AdaptorType)
AdaptorType adaptorTo[] = new AdaptorType [1] ;
//
//
// constructor ----------
GraphicalItem(
int _typeOfGraphicalItem,
int _x, int _y,
String _header, String _normalText,
AdaptorType _adaptorTo,
color _tempColor) {
//
// constructor
Position = new PVector( _x, _y);
boxSize = new PVector( 100, 70 );
textHeader = _header;
textNormal = _normalText;
adaptorTo [0] = _adaptorTo;
//
typeOfGraphicalItem=_typeOfGraphicalItem;
//
if (typeOfGraphicalItem == typeOfGraphicalItemConditional) {
// Conditional item = ttiangle
// calculate the four adaptors pos
adaptorUp = new PVector( boxSize.x/2, 0 );
adaptorRight = new PVector( 2*boxSize.x/3+11, boxSize.y/2 );
// adaptorDown = new PVector( boxSize.x/2, boxSize.y );
adaptorLeft = new PVector( boxSize.x/3-7, boxSize.y/2 );
}
else {
// calculate the four adaptors pos
adaptorUp = new PVector( boxSize.x/2, 0 );
adaptorRight = new PVector( boxSize.x, boxSize.y/2 );
adaptorDown = new PVector( boxSize.x/2, boxSize.y );
adaptorLeft = new PVector( 0, boxSize.y/2 );
}
//
headerColor = _tempColor;
plausibilityCheck();
}// constructor
//
void plausibilityCheck () {
// checks whether there are not plausible parameters, e.g.
// a defined header with a typeOfGraphicalItem that has no
// header.
if (typeOfGraphicalItem == typeOfGraphicalItemConditional ||
typeOfGraphicalItem == typeOfGraphicalItemStandardWithoutHeader ||
typeOfGraphicalItem == typeOfGraphicalItemStartEnd ) {
if (!textHeader.trim().equals("")) {
println("Remark 285: StandardWithoutHeader or Conditional etc. has defined header (not shown) with header: '"
+ textHeader
+ "' and normal text: '"
+ textNormal
+ "'. "
+ "Type being: "
+ typeOfGraphicalItem
+ ". Header ignored.");
}
}
}
//
void display() {
switch (typeOfGraphicalItem) {
case typeOfGraphicalItemStandardWithHeader:
displayStandardWithHeader() ;
break;
case typeOfGraphicalItemStandardWithoutHeader:
displayStandardWithoutHeader();
break;
case typeOfGraphicalItemConditional:
displayConditional();
break;
case typeOfGraphicalItemStartEnd:
displayStartEnd();
break;
default:
println("Error occured 245");
break;
} // switch
//
} // method
//
void displayStandardWithHeader() {
fill (headerColor);
stroke(0);
// header rect
rect (Position.x, Position.y,
boxSize.x, headerHeight);
fill(244);
// rect for normal text field (lower half)
rect (Position.x, Position.y+headerHeight,
boxSize.x, boxSize.y-headerHeight);
fill (0);
text (textHeader, Position.x+4, Position.y+2, boxSize.x-5, headerHeight);
text (textNormal, Position.x+4, Position.y+headerHeight+2, boxSize.x-5, boxSize.y-headerHeight);
// adaptors --------
for (int i=0; i < adaptorTo.length; i++) {
if (adaptorTo[i] != null) {
adaptorTo[i].display ( this ) ;
} // if
} // for
} // method
//
void displayStandardWithoutHeader() {
fill(244);
// rect for text field
rect (Position.x, Position.y,
boxSize.x, boxSize.y);
fill (0);
text (textNormal, Position.x+4, Position.y+2, boxSize.x-5, boxSize.y);
// adaptors --------
for (int i=0; i < adaptorTo.length; i++) {
if (adaptorTo[i] != null) {
adaptorTo[i].display ( this ) ;
} // if
} // for
} // method
//
void displayConditional() {
// Conditional is triangle
fill(244);
triangle (Position.x, Position.y,
Position.x+boxSize.x+0, Position.y,
Position.x+boxSize.x/2+5, Position.y + boxSize.y);
fill (0);
textAlign(CENTER);
text (textNormal,
Position.x+2, Position.y+2,
boxSize.x-5, boxSize.y );
// adaptors ----------
for (int i=0; i < adaptorTo.length; i++) {
if (adaptorTo[i] != null) {
adaptorTo[i].display ( this ) ;
} // if
} // for
} // method
//
void displayStartEnd() {
fill(244);
ellipseMode(CORNER);
ellipse (Position.x, Position.y, boxSize.x, boxSize.y);
fill (0);
textAlign(CENTER);
text (textNormal,
Position.x+7, Position.y+18,
boxSize.x-5, boxSize.y );
// adaptors ------------
for (int i=0; i < adaptorTo.length; i++) {
if (adaptorTo[i] != null) {
adaptorTo[i].display ( this ) ;
} // if
} // for
} // method
//
void addAdaptor(AdaptorType _adaptorTo) {
// appends one line on a existing GraphicalItem
if (_adaptorTo.adaptorToGraphicalItem > -1) {
adaptorTo = (AdaptorType[])append( adaptorTo, _adaptorTo );
}
} // method
//
boolean isMouseOver() {
if (mouseX*1>Position.x && mouseX*1<Position.x+boxSize.x &&
mouseY*1>Position.y && mouseY*1<Position.y+boxSize.y) {
return true;
}
else
{
return false;
}
} // method
//
boolean isMouseOver_OLD() {
if (mouseX>Position.x && mouseX<Position.x+boxSize.x &&
mouseY>Position.y && mouseY<Position.y+boxSize.y) {
return true;
}
else
{
return false;
}
} // method
} // class
// ==============================================================
class AdaptorType {
// Represents one connecting line.
//
// Start point (FROM) is a point at
// the GraphicalItem (a box) this
// AdaptorType-object belongs to.
// End point (TO) is another GraphicalItem
// marked by the var adaptorToGraphicalItem
// which is an Index for the ArrayList
// graphicalItems.
// To specify the exakt point at
// the from-GraphicalItem, the var
// fromAdaptor denotes whether it's
// (clockwise) north, east, south or west.
// And: To specify the exakt point at
// the to-GraphicalItem, the var
// toAdaptor denotes whether it's
// (clockwise) north, east, south or west.
//
// Indices of another GraphicalItem
int adaptorToGraphicalItem = -1; // other graphical item
// from which Adaptor of the four
int fromAdaptor = 1; // 0 = north adaptor, 1 = east adaptor, 2 = south adaptor, 3 = west adaptor
// to which Adaptor of the four
int toAdaptor = 1; // 0 = north adaptor, 1 = east adaptor, 2 = south adaptor, 3 = west adaptor
//
AdaptorType (int tempAdaptorToGraphicalItem,
int tempFromAdaptor,
int tempToAdaptor ) {
adaptorToGraphicalItem = tempAdaptorToGraphicalItem;
fromAdaptor = tempFromAdaptor;
toAdaptor = tempToAdaptor;
} //
//
void display(GraphicalItem startGraphicalItem) {
if (adaptorToGraphicalItem > -1) {
PVector startVector = getPVector
(startGraphicalItem,
fromAdaptor);
PVector endVector = getPVector
( (GraphicalItem) graphicalItems.get( adaptorToGraphicalItem),
toAdaptor);
//
line ( startVector.x, startVector.y,
endVector.x, endVector.y );
} // if
} // method
PVector getPVector(GraphicalItem startGraphicalItem, int whichAdaptor) {
PVector buffer = new PVector ();
//
switch (whichAdaptor) {
case adaptorNorth:
buffer.x=startGraphicalItem.Position.x+startGraphicalItem.adaptorUp.x;
buffer.y=startGraphicalItem.Position.y+startGraphicalItem.adaptorUp.y;
break;
case adaptorEast:
buffer.x=startGraphicalItem.Position.x+startGraphicalItem.adaptorRight.x;
buffer.y=startGraphicalItem.Position.y+startGraphicalItem.adaptorRight.y;
break;
case adaptorSouth:
buffer.x=startGraphicalItem.Position.x+startGraphicalItem.adaptorDown.x;
buffer.y=startGraphicalItem.Position.y+startGraphicalItem.adaptorDown.y;
break;
case adaptorWest:
buffer.x=startGraphicalItem.Position.x+startGraphicalItem.adaptorLeft.x;
buffer.y=startGraphicalItem.Position.y+startGraphicalItem.adaptorLeft.y;
break;
default:
println ("Error 337");
break;
} // switch
return buffer;
} // method
} // class
// ==============================================================

Replies(7)

amnon.owed

Re: translate and scale and then check mouseX and mouseY!? Flowchart

1 year ago

You can replace your isMouseOver() function by the following:

boolean isMouseOver() {
if (mouseX/myScale > Position.x
&& mouseX/myScale < Position.x + boxSize.x
&& mouseY/myScale - myTranslate > Position.y
&& mouseY/myScale - myTranslate < Position.y + boxSize.y) {
return true;
} else {
return false;
}
}

That's the mouseOver. There are probably some other functions (like the dragging distance) that are also affected by the scale. So you could correct those for scale as well.

Something else. You are actually using an isOverRect() function as a general isMouseOver. But you have non-rect shapes as well. So another improvement would be to have isOverCircle() and isOverTriangle() functions as well. In that sense it would probably make more sense to have a general Shape object and several subclasses that extend the main Shape such as rectangle, triangle and circle. Each with their custom isMouseOver() function (same name, but different functionality).

Chrisir

Re: translate and scale and then check mouseX and mouseY!? Flowchart

1 year ago

Thank you very much!

Chrisir

Re: translate and scale and then check mouseX and mouseY!? Flowchart

1 year ago

hello,

I have another question.

I have to connect two graphical items with a line (or two lines go from one item to two others).

At the moment the line is a simple class AdaptorType depending from the class GraphicalItem.

But the target GraphicalItem where the line leads to is referred by it's index in the ArrayList (that's done in class AdaptorType, I made the lines bold, see below).

That sounds very unwise since when you remove one item, all indices after it change, right?

So it's unstable / not reliable.

What is the alternative?

Is it possible to make a pointer (direct reference?) to the object itself which would stay the same after removing another?

To do so, could the constructor return this reference?
See line 79ff. where I use the index at the moment.

Thank you!

Greetings, Chrisir

// this prgram provides a flowchart / diagram
// http://en.wikipedia.org/wiki/Flowchart
ArrayList<GraphicalItem> graphicalItems;
//
final color lightGreen = color (2, 244, 2, 22);
final color lightBlue = color(2, 0, 244, 22);
// State of program
final int stateNormal = 0;
int state=stateNormal;
//
// for graphical:
final int typeOfGraphicalItemStandardWithHeader = 0;
final int typeOfGraphicalItemStandardWithoutHeader = 1;
final int typeOfGraphicalItemConditional = 2;
final int typeOfGraphicalItemStartEnd = 3;
//
// for graphical: which adaptor is used on a box?
// (clockwise) north, east, south or west.
final int adaptorNorth=0;
final int adaptorEast=1;
final int adaptorSouth=2;
final int adaptorWest=3;
//
// for scale and translating
float myScale = 1.0;
float myTranslate = 0.0; // only y-direction
// where to place next box vertically
int lineY = 40;
//
// for drag and drop:
// mouse dragged?
boolean hold=false;
GraphicalItem holdItem ; // which item is dragged
// for drag and drop: difference between the upper left corner
// x,y position and where mouse clicked in the graphical item
PVector offSet;
// ---------------------------------------------------------------
void setup() {
// size( screen.width, screen.height );
size( 800, 600 );
smooth();
noStroke();
fill(0);
offSet=new PVector();
// Create an empty ArrayList
graphicalItems = new ArrayList();
// fill the ArrayList
initGraphical() ;
} // func
//
//
void draw() {
background(255);
//
if (state==stateNormal) {
scale(myScale);
translate( 0, myTranslate ) ;
showGraphical();
}
else {
println ("Error 182" );
}
} // func
//
//
// =================================================================
// Init items
void initGraphical() {
// fills the graphicalItems in the arrayList
graphicalItems.clear();
lineY = 40;
//
graphicalItems.add ( new GraphicalItem(
typeOfGraphicalItemStandardWithHeader, 20, lineY,
"Entry 0", "This is interesting",
null,
lightGreen ));
int EntryGreen = graphicalItems.size()-1;
graphicalItems.add ( new GraphicalItem(
typeOfGraphicalItemStandardWithHeader, 320, lineY,
"Entry 1", "This is lightblue ",
new AdaptorType(EntryGreen, adaptorWest, adaptorEast),
lightBlue ));
int EntryBlue = graphicalItems.size()-1;
graphicalItems.add ( new GraphicalItem(
typeOfGraphicalItemConditional,
100, lineY+100,
"", "Conditional",
new AdaptorType(EntryGreen, adaptorNorth, adaptorSouth),
color (0) ));
int EntryConditional = graphicalItems.size()-1;
lineY+=70;
graphicalItems.add ( new GraphicalItem(
typeOfGraphicalItemStartEnd,
180, lineY+100,
"", "Test2",
new AdaptorType(EntryConditional, adaptorNorth, adaptorEast),
color (0) ));
lineY+=70;
graphicalItems.add ( new GraphicalItem(
typeOfGraphicalItemStartEnd,
40, lineY+100,
"", "Test3",
new AdaptorType(EntryConditional, adaptorNorth, adaptorWest),
color (0) ));
int EntryStartItem = graphicalItems.size()-1;
graphicalItems.add ( new GraphicalItem(
typeOfGraphicalItemStandardWithoutHeader,
240, lineY+200,
"", "Test3",
new AdaptorType(EntryBlue, adaptorNorth, adaptorSouth),
color (0) ));
//
// add further Line to last item. This line
// goes from the last item (it's west side) to item
// number EntryStartItem (south)
AddLineToElement( graphicalItems.size()-1,
EntryStartItem,
adaptorWest,
adaptorSouth );
//
} // func
//
// Inputs ****************************************************
//
void mousePressed() {
if (state==stateNormal) {
if (mouseButton==LEFT) {
// drag one item
for (int i = 0; i <= graphicalItems.size()-1; i++ ) {
GraphicalItem myGraphicalItem1 = graphicalItems.get(i);
if (myGraphicalItem1.isMouseOver()) {
hold = true;
holdItem = myGraphicalItem1;
offSet.x = myGraphicalItem1.Position.x-mouseX;
offSet.y = myGraphicalItem1.Position.y-mouseY;
}
} // for
} // if
} // if
} // func
//
void mouseDragged() {
if (state==stateNormal) {
if (hold) {
// mouseButton is LEFT
holdItem.Position.x = mouseX+offSet.x;
holdItem.Position.y = mouseY+offSet.y;
}
else if (mousePressed && (mouseButton == RIGHT)) {
myScale = map(mouseX, 0, width, 0, 2);
myTranslate = map(mouseY, 0, height, -height, height);
} // if
} // if
} // func
//
void mouseReleased () {
if (state==stateNormal) {
if (mouseButton == LEFT) {
hold = false;
println("f");
}
}
} // function
//
void keyPressed () {
if (state==stateNormal) {
//
if (key=='r') {
// reset scale and translate
myScale = 1.0;
myTranslate = 0.0;
}
else
{
// do nothing
}
}
else {
println("Error 429: unknown state ");
}
} // keyPressed
//-----------------------------------------------------------
//
void AddLineToElement( int NumberOfStartItem, int NumberOfTargetItem,
int adaptor1, int adaptor2) {
// add a line
GraphicalItem itemStart = graphicalItems.get(NumberOfStartItem);
itemStart.addAdaptor ( new AdaptorType(NumberOfTargetItem, adaptor1, adaptor2) );
}
//
void showGraphical() {
// show the graphicalItems from the arrayList
textAlign(LEFT);
text ( "Graphical Representation"
+ " - "
+ "Move items with left Mouse button. Drag with right mouse button: scale "
+ "(x-direction) and up/down (y-direction).", 20, 14 );
if (graphicalItems.isEmpty()) {
text("Graphical Diagram is empty.", 220, 170 );
}
else
{
for (int i = 0; i <= graphicalItems.size()-1; i++ ) {
GraphicalItem myGraphicalItem1 = graphicalItems.get(i);
myGraphicalItem1.display() ;
} // for
} // if else
} // func
//
GraphicalItem getElement( String textHeaderParam, String textNormalParam ) {
// returns object or null
for (int i = 0; i <= graphicalItems.size()-1; i++ ) {
GraphicalItem myGraphicalItem1 = graphicalItems.get(i);
if (myGraphicalItem1.textHeader.equals(textHeaderParam) &&
myGraphicalItem1.textNormal.equals(textNormalParam)) {
return myGraphicalItem1;
} // if
} // for
return null;
} // func
//
int getElementNumber( String textHeaderParam, String textNormalParam ) {
// returns number of object or -1
for (int i = 0; i <= graphicalItems.size()-1; i++ ) {
GraphicalItem myGraphicalItem1 = graphicalItems.get(i);
if (myGraphicalItem1.textHeader.equals(textHeaderParam) &&
myGraphicalItem1.textNormal.equals(textNormalParam)) {
return i;
} // if
} // for
return -1;
} // func
//
// ==============================================================
class GraphicalItem {
//
PVector Position; // Pos and size of the whole box
PVector boxSize; // Size
final int headerHeight = 20; // Height of header text box
color headerColor; // color of header box
// the type of the item
int typeOfGraphicalItem;
// texts
String textHeader="";
String textNormal="";
//
// where the adaptors lead to: array of
// AdaptorType (see class AdaptorType)
AdaptorType adaptorTo[] = new AdaptorType [1];
//
// Positions of adaptors
PVector adaptorLeft, adaptorRight;
PVector adaptorUp, adaptorDown;
//
// constructor ----------
GraphicalItem(
int _typeOfGraphicalItem,
int _x, int _y,
String _header, String _normalText,
AdaptorType _adaptorTo,
color _tempColor) {
//
// constructor
Position = new PVector( _x, _y);
boxSize = new PVector( 100, 70 );
textHeader = _header;
textNormal = _normalText;
adaptorTo [0] = _adaptorTo;
//
typeOfGraphicalItem=_typeOfGraphicalItem;
//
if (typeOfGraphicalItem == typeOfGraphicalItemConditional) {
// Conditional item = ttiangle
// calculate the four adaptors pos
adaptorUp = new PVector( boxSize.x/2, 0 );
adaptorRight = new PVector( 2*boxSize.x/3+11, boxSize.y/2 );
// adaptorDown = new PVector( boxSize.x/2, boxSize.y );
adaptorLeft = new PVector( boxSize.x/3-7, boxSize.y/2 );
}
else {
// calculate the four adaptors pos
adaptorUp = new PVector( boxSize.x/2, 0 );
adaptorRight = new PVector( boxSize.x, boxSize.y/2 );
adaptorDown = new PVector( boxSize.x/2, boxSize.y );
adaptorLeft = new PVector( 0, boxSize.y/2 );
}
//
headerColor = _tempColor;
plausibilityCheck();
}// constructor
//
void plausibilityCheck () {
// checks whether there are not plausible parameters, e.g.
// a defined header with a typeOfGraphicalItem that has no
// header.
if (typeOfGraphicalItem == typeOfGraphicalItemConditional ||
typeOfGraphicalItem == typeOfGraphicalItemStandardWithoutHeader ||
typeOfGraphicalItem == typeOfGraphicalItemStartEnd ) {
if (!textHeader.trim().equals("")) {
println("Remark 285: StandardWithoutHeader or Conditional etc. has defined header (not shown) with header: '"
+ textHeader
+ "' and normal text: '"
+ textNormal
+ "'. "
+ "Type being: "
+ typeOfGraphicalItem
+ ". Header ignored.");
}
}
}
//
void display() {
switch (typeOfGraphicalItem) {
case typeOfGraphicalItemStandardWithHeader:
displayStandardWithHeader() ;
break;
case typeOfGraphicalItemStandardWithoutHeader:
displayStandardWithoutHeader();
break;
case typeOfGraphicalItemConditional:
displayConditional();
break;
case typeOfGraphicalItemStartEnd:
displayStartEnd();
break;
default:
println("Error occured 245");
break;
} // switch
//
} // method
//
void displayStandardWithHeader() {
fill (headerColor);
stroke(0);
// header rect
rect (Position.x, Position.y,
boxSize.x, headerHeight);
fill(244);
// rect for normal text field (lower half)
rect (Position.x, Position.y+headerHeight,
boxSize.x, boxSize.y-headerHeight);
fill (0);
text (textHeader, Position.x+4, Position.y+2, boxSize.x-5, headerHeight);
text (textNormal, Position.x+4, Position.y+headerHeight+2, boxSize.x-5, boxSize.y-headerHeight);
// adaptors --------
for (int i=0; i < adaptorTo.length; i++) {
if (adaptorTo[i] != null) {
adaptorTo[i].display ( this ) ;
} // if
} // for
} // method
//
void displayStandardWithoutHeader() {
fill(244);
// rect for text field
rect (Position.x, Position.y,
boxSize.x, boxSize.y);
fill (0);
text (textNormal, Position.x+4, Position.y+2, boxSize.x-5, boxSize.y);
// adaptors --------
for (int i=0; i < adaptorTo.length; i++) {
if (adaptorTo[i] != null) {
adaptorTo[i].display ( this ) ;
} // if
} // for
} // method
//
void displayConditional() {
// Conditional is triangle
fill(244);
triangle (Position.x, Position.y,
Position.x+boxSize.x+0, Position.y,
Position.x+boxSize.x/2+5, Position.y + boxSize.y);
fill (0);
textAlign(CENTER);
text (textNormal,
Position.x+2, Position.y+2,
boxSize.x-5, boxSize.y );
// adaptors ----------
for (int i=0; i < adaptorTo.length; i++) {
if (adaptorTo[i] != null) {
adaptorTo[i].display ( this ) ;
} // if
} // for
} // method
//
void displayStartEnd() {
fill(244);
ellipseMode(CORNER);
ellipse (Position.x, Position.y, boxSize.x, boxSize.y);
fill (0);
textAlign(CENTER);
text (textNormal,
Position.x+7, Position.y+18,
boxSize.x-5, boxSize.y );
// adaptors ------------
for (int i=0; i < adaptorTo.length; i++) {
if (adaptorTo[i] != null) {
adaptorTo[i].display ( this ) ;
} // if
} // for
} // method
//
void addAdaptor(AdaptorType _adaptorTo) {
// appends one line on a existing GraphicalItem
if (_adaptorTo.adaptorToGraphicalItem > -1) {
adaptorTo = (AdaptorType[])append( adaptorTo, _adaptorTo );
}
} // method
//
boolean isMouseOver() {
if (mouseX/myScale > Position.x
&& mouseX/myScale < Position.x + boxSize.x
&& mouseY/myScale - myTranslate > Position.y
&& mouseY/myScale - myTranslate < Position.y + boxSize.y) {
return true;
} // if
else {
return false;
} // if else
} // method
//
} // class
// ==============================================================
class AdaptorType {
// Represents one connecting line.
//
// Start point (FROM) is a point at
// the GraphicalItem (a box) this
// AdaptorType-object belongs to.
// End point (TO) is another GraphicalItem
// marked by the var adaptorToGraphicalItem
// which is an Index for the ArrayList
// graphicalItems.
// To specify the exakt point at
// the from-GraphicalItem, the var
// fromAdaptor denotes whether it's
// (clockwise) north, east, south or west.
// And: To specify the exakt point at
// the to-GraphicalItem, the var
// toAdaptor denotes whether it's
// (clockwise) north, east, south or west.
//
// Indices of another GraphicalItem
int adaptorToGraphicalItem = -1; // other graphical item
// from which Adaptor of the four
int fromAdaptor = 1; // 0 = north adaptor, 1 = east adaptor, 2 = south adaptor, 3 = west adaptor
// to which Adaptor of the four
int toAdaptor = 1; // 0 = north adaptor, 1 = east adaptor, 2 = south adaptor, 3 = west adaptor
//
AdaptorType (int tempAdaptorToGraphicalItem,
int tempFromAdaptor,
int tempToAdaptor ) {
adaptorToGraphicalItem = tempAdaptorToGraphicalItem;
fromAdaptor = tempFromAdaptor;
toAdaptor = tempToAdaptor;
} //
//
void display(GraphicalItem startGraphicalItem) {
if (adaptorToGraphicalItem > -1) {
PVector startVector = getPVector
(startGraphicalItem, fromAdaptor);
PVector endVector = getPVector
((GraphicalItem) graphicalItems.get(adaptorToGraphicalItem), toAdaptor);
//
line ( startVector.x, startVector.y,
endVector.x, endVector.y );
} // if
} // method
//
PVector getPVector(GraphicalItem startGraphicalItem, int whichAdaptor) {
PVector buffer = new PVector ();
//
switch (whichAdaptor) {
case adaptorNorth:
buffer.x=startGraphicalItem.Position.x+startGraphicalItem.adaptorUp.x;
buffer.y=startGraphicalItem.Position.y+startGraphicalItem.adaptorUp.y;
break;
case adaptorEast:
buffer.x=startGraphicalItem.Position.x+startGraphicalItem.adaptorRight.x;
buffer.y=startGraphicalItem.Position.y+startGraphicalItem.adaptorRight.y;
break;
case adaptorSouth:
buffer.x=startGraphicalItem.Position.x+startGraphicalItem.adaptorDown.x;
buffer.y=startGraphicalItem.Position.y+startGraphicalItem.adaptorDown.y;
break;
case adaptorWest:
buffer.x=startGraphicalItem.Position.x+startGraphicalItem.adaptorLeft.x;
buffer.y=startGraphicalItem.Position.y+startGraphicalItem.adaptorLeft.y;
break;
default:
println ("Error 337 - unknown adaptor");
break;
} // switch
return buffer;
} // method
} // class
// ==============================================================

amnon.owed

Re: translate and scale and then check mouseX and mouseY!? Flowchart

1 year ago

There are always more ways than one to do it. In all cases you will have to deal with adding/removing/displaying objects and adding/removing/displaying connections.

You could use direct references to the connected objects. But remember that as long as an object is referenced it 'stays in existence', meaning that removing the 'original object' reference from the arraylist will not remove the connection nor the object from memory.

You could give each object a uniqueID. Once each object has a reliable ID you can use it in different ways. You could store and display the connections at the object or the global level. Either way uniqueID's are useful for keeping track of connections etc.

Put something like this at the global level:

int id;
int getUniqueID() {
return id++;
}

Then put something like this in your objects.

class SomeObject {
int objectID; // holds the object's unique ID
SomeObject() {
objectID = getUniqueID();
}
getObjectID() {
return objectID;
}
}

PhiLho

Re: translate and scale and then check mouseX and mouseY!? Flowchart

1 year ago

Without analyzing deeply your code (a bit long...), I can answer 'yes' to your question: don't pass around indexes, it is indeed very brittle. Just pass the objects themselves, you will pass actually just references to these objects.
Don't do x.add(new Item()) but do Item item = new Item(); x.add(item); so you can pass the item to the next constructor.
Note 1: the cast on graphicalItems.get() isn't necessary (old habit? You omit it elsewhere).
Note 2: for (int i = 0; i <= graphicalItems.size()-1; i++) is more usually written for (int i = 0; i < graphicalItems.size(); i++). For a trained eye, the first form makes the mind to pause and think, while the second one is just glanced at once.
Note 3: When you don't need an index, the new for loop is handy:

for (int i=0; i < adaptorTo.length; i++) {
if (adaptorTo[i] != null) {
adaptorTo[i].display ( this ) ;
} // if
} // for

can be:

for (AdaptorType to : adaptorTo) {
if (to != null) {
to.display ( this ) ;
} // if
} // for

(why you don't use an array list here?)
or:

for (int i = 0; i <= graphicalItems.size()-1; i++ ) {
GraphicalItem myGraphicalItem1 = graphicalItems.get(i);
if (myGraphicalItem1.textHeader.equals(textHeaderParam) &&
myGraphicalItem1.textNormal.equals(textNormalParam)) {
return myGraphicalItem1;
} // if
} // for

can be:

for (GraphicalItem myGraphicalItem : graphicalItems) {
if (myGraphicalItem.textHeader.equals(textHeaderParam) &&
myGraphicalItem.textNormal.equals(textNormalParam)) {
return myGraphicalItem;
} // if
} // for

Minor superficial remarks...
I haven't tried yet this sketch, but from the screen shot, it looks impressive.

Chrisir

Re: translate and scale and then check mouseX and mouseY!? Flowchart

1 year ago

that's very helpful!

Thank you both!

And thanks for the word "impressive"

Chrisir

New Code - working - solved

1 year ago

Hello,

I now did what you both told me...

You can drag the items with left mouse,
scale (x and y) and translate (only y) with right mouse (r resets).
When item is selected it is marked with a * and you can remove it by delete.
n = new diagram
u = un-select

It works with an unique ID now.

Works fine.

Thanks again!

Greetings, Chrisir

// this program provides a flowchart / diagram
// http://en.wikipedia.org/wiki/Flowchart
ArrayList<GraphicalItem> graphicalItems;
//
// State of program
final int stateNormal = 0;
int state=stateNormal;
//
// for graphical:
final int typeOfGraphicalItemStandardWithHeader = 0;
final int typeOfGraphicalItemStandardWithoutHeader = 1;
final int typeOfGraphicalItemConditional = 2;
final int typeOfGraphicalItemStartEnd = 3;
// to be able to name those types we use an array
// which order of indices must be according to the consts
// above:
final String[] typeOfGraphicalItemName = {
"Box with header",
"Box without header",
"Condition",
"Start or End"
};
//
// for graphical: which adaptor is used on a box?
// (clockwise) north, east, south or west.
final int adaptorNorth=0;
final int adaptorEast=1;
final int adaptorSouth=2;
final int adaptorWest=3;
//
// colors
final color lightGreen = color (2, 244, 2, 22);
final color lightBlue = color(2, 0, 244, 22);
final color black = color (0);
//
// for scale and translating
float myScale = 1.0;
float myTranslate = 0.0; // only y-direction
//
// for drag and drop:
// mouse dragged?
boolean hold=false;
GraphicalItem holdItem ; // which item is dragged
// for drag and drop: difference between the upper left corner
// x,y position and where mouse clicked in the graphical item
PVector offSet=new PVector();
//
// for unique ID
int id=1000;
// which item is selected
int selected = -1;
//
// Main functions ****************************************************
//
void setup() {
// size( screen.width, screen.height );
size( 800, 600 );
println("start of the program");
// smooth();
noStroke();
fill(0);
// Create an empty ArrayList
graphicalItems = new ArrayList();
// fill the ArrayList
initGraphical();
println("end of setup()");
} // func
//
//
void draw() {
background(255);
// depending on program's state
if (state == stateNormal) {
scale(myScale);
translate( 0, myTranslate ) ;
showGraphical();
}
else {
println ("Error 182 - unknown state" );
}
} // func
//
// Init diagram ****************************************************
//
void initGraphical() {
// Init items:
// fill the graphicalItems in the arrayList.
//
// where to place next box vertically
int lineY = 40;
// clear list
graphicalItems.clear();
//
// item to be defined
GraphicalItem item;
//
item = new GraphicalItem(
typeOfGraphicalItemStandardWithHeader, 20, lineY,
"Entry 0", "This is interesting",
null,
lightGreen );
graphicalItems.add (item);
int EntryGreen = item.objectID;
item=new GraphicalItem(
typeOfGraphicalItemStandardWithHeader, 320, lineY,
"Entry 1", "This is lightblue ",
new AdaptorType(EntryGreen, adaptorWest, adaptorEast),
lightBlue );
graphicalItems.add ( item );
int EntryBlue = item.objectID;
item=new GraphicalItem(
typeOfGraphicalItemConditional,
100, lineY+100,
"", "Conditional",
new AdaptorType(EntryGreen, adaptorNorth, adaptorSouth),
color (0) );
graphicalItems.add (item);
int EntryConditional = item.objectID;
lineY+=70;
item=new GraphicalItem(
typeOfGraphicalItemStartEnd,
180, lineY+100,
"", "Test 2",
new AdaptorType(EntryConditional, adaptorNorth, adaptorEast),
color (0) );
graphicalItems.add (item);
lineY+=70;
item= new GraphicalItem(
typeOfGraphicalItemStartEnd,
40, lineY+100,
"", "Test3",
new AdaptorType(EntryConditional, adaptorNorth, adaptorWest),
color (0) );
graphicalItems.add (item);
int EntryStartItem = item.objectID;
item= new GraphicalItem(
typeOfGraphicalItemStandardWithoutHeader,
240, lineY+200,
"", "Test3",
new AdaptorType(EntryBlue, adaptorNorth, adaptorSouth),
color (0) );
graphicalItems.add (item);
int WithoutHeaderItem = item.objectID;
//
// add further Line to item WithoutHeaderItem. This line
// goes from the last item (it's west side) to item
// number EntryStartItem (south side)
AddLineToElement( WithoutHeaderItem,
EntryStartItem,
adaptorWest,
adaptorSouth );
//
} // func
//
// Inputs ****************************************************
//
void mousePressed() {
if (state==stateNormal) {
if (mouseButton==LEFT) {
// drag one item
for (GraphicalItem myGraphicalItem : graphicalItems) {
if (myGraphicalItem.isMouseOver()) {
selected = myGraphicalItem.getObjectID();
hold = true;
holdItem = myGraphicalItem;
offSet.x = myGraphicalItem.Position.x-mouseX;
offSet.y = myGraphicalItem.Position.y-mouseY;
} // if
} // for
} // if
} // if
} // func
//
void mouseDragged() {
if (state==stateNormal) {
if (hold) {
// mouseButton is LEFT
holdItem.Position.x = mouseX+offSet.x;
holdItem.Position.y = mouseY+offSet.y;
}
else if (mousePressed && (mouseButton == RIGHT)) {
myScale = map(mouseX, 0, width, 0, 2);
myTranslate = map(mouseY, 0, height, -height, height);
} // if
} // if
} // func
//
void mouseReleased () {
if (state==stateNormal) {
if (mouseButton == LEFT) {
hold = false;
}
}
} // function
//
void keyPressed () {
if (state==stateNormal) {
keyPressedStateNormal();
}
else {
println("Error 429: unknown state ");
}
} // keyPressed
//
void keyPressedStateNormal() {
// eval keys for state normal
if (!(key==CODED)) {
if (key=='r') {
// reset scale and translate
myScale = 1.0;
myTranslate = 0.0;
} // the r
else if (key=='n') {
// make new diagram
println ("new diagram ----");
initGraphical();
} // the n
else if (key=='u') { // un-mark
// remove marker
selected=-1;
} // the u
else if (key==DELETE) {
// delete selected item.
// if there are items:
if (!graphicalItems.isEmpty()) {
//get selected
GraphicalItem itemSelected = getElementByID(selected);
if (itemSelected!=null) {
// delete it
itemSelected.delete();
// remove marker
selected=-1;
}
else
{
println ("Delete: Found no selected item. Select with Mouse.");
}
}
} // delete
else
{
// do nothing
} // else
} // if not CODED
} // func
//
// Other, minor functions ****************************************************
//
void AddLineToElement( int NumberOfStartItem, int NumberOfTargetItem,
int adaptor1, int adaptor2) {
// add a line
GraphicalItem itemStart = getElementByID (NumberOfStartItem);
itemStart.addAdaptor ( new AdaptorType(NumberOfTargetItem, adaptor1, adaptor2) );
}
//
void showGraphical() {
// show the graphicalItems from the arrayList
textAlign(LEFT);
text ( "Graphical Representation"
+ " - "
+ "Move items with left Mouse button. Drag with right mouse button: scale "
+ "(x-direction) and up/down (y-direction).", 20, 14 );
if (graphicalItems.isEmpty()) {
text("Graphical Diagram is empty.", 220, 170 );
}
else
{
for (GraphicalItem myGraphicalItem : graphicalItems) {
myGraphicalItem.display() ;
} // for
} // if else
} // func
//
GraphicalItem getElementByID( int myIdParameter ) {
// returns object or null
for (GraphicalItem myGraphicalItem : graphicalItems) {
if (myGraphicalItem.objectID==myIdParameter) {
return myGraphicalItem;
} // if
} // for
return null;
} // func
//
GraphicalItem getElementFromTexts( String textHeaderParam, String textNormalParam ) {
// not in use
// returns object or null
for (GraphicalItem myGraphicalItem : graphicalItems) {
if (myGraphicalItem.textHeader.equals(textHeaderParam) &&
myGraphicalItem.textNormal.equals(textNormalParam)) {
return myGraphicalItem;
} // if
} // for
return null;
} // func
//
int getElementNumberFromTexts( String textHeaderParam, String textNormalParam ) {
// not in use
// returns number of object or -1
for (GraphicalItem myGraphicalItem : graphicalItems) {
if (myGraphicalItem.textHeader.equals(textHeaderParam) &&
myGraphicalItem.textNormal.equals(textNormalParam)) {
// return i;
return myGraphicalItem.getObjectID();
} // if
} // for
return -1;
} // func
//
// ==============================================================
class GraphicalItem {
//
PVector Position; // Pos and size of the whole box
PVector boxSize; // Size
final int headerHeight = 20; // Height of header text box
color headerColor; // color of header box
// the type of the item
int typeOfGraphicalItem;
// texts
String textHeader="";
String textNormal="";
//
// where the adaptors lead to: ArrayList of
// AdaptorType (see class AdaptorType)
ArrayList<AdaptorType> adaptorTo;
//
// Positions of items own adaptors as x,y
PVector adaptorNorth;
PVector adaptorEast;
PVector adaptorSouth;
PVector adaptorWest;
//
// holds the object's unique ID
int objectID;
//
// constructor ----------
GraphicalItem(
int _typeOfGraphicalItem,
int _x, int _y,
String _header, String _normalText,
AdaptorType _adaptorTo,
color _tempColor) {
//
Position = new PVector( _x, _y);
boxSize = new PVector( 100, 70 );
textHeader = _header;
textNormal = _normalText;
adaptorTo = new ArrayList();
if (_adaptorTo!=null) {
adaptorTo.add (new AdaptorType(
_adaptorTo.adaptorToGraphicalItem,
_adaptorTo.fromAdaptor,
_adaptorTo.toAdaptor));
//adaptorTo [0] = _adaptorTo;
}
//
// type
typeOfGraphicalItem=_typeOfGraphicalItem;
//
if (typeOfGraphicalItem == typeOfGraphicalItemConditional) {
// Conditional item = triangle
// calculate the four adaptors pos
adaptorNorth = new PVector( boxSize.x/2, 0 );
adaptorEast = new PVector( 2*boxSize.x/3+11, boxSize.y/2 );
adaptorWest = new PVector( boxSize.x/3-7, boxSize.y/2 );
// rarely used with Conditional:
adaptorSouth = new PVector( boxSize.x/2 + 4, boxSize.y );
}
else {
// item = all except Conditional / triangle
// calculate the four adaptors pos
adaptorNorth = new PVector( boxSize.x/2, 0 );
adaptorEast = new PVector( boxSize.x, boxSize.y/2 );
adaptorSouth = new PVector( boxSize.x/2, boxSize.y );
adaptorWest = new PVector( 0, boxSize.y/2 );
}
//
headerColor = _tempColor;
objectID = getUniqueID();
//
plausibilityCheck();
}// constructor
//
private void plausibilityCheck () {
// checks whether there are not plausible parameters, e.g.
// a defined header with a typeOfGraphicalItem that has no
// header (header text ignored).
// Same for color with colorless types.
//
// check header text
if (typeOfGraphicalItem == typeOfGraphicalItemConditional ||
typeOfGraphicalItem == typeOfGraphicalItemStandardWithoutHeader ||
typeOfGraphicalItem == typeOfGraphicalItemStartEnd ) {
if (!textHeader.trim().equals("")) {
println("Remark 285: StandardWithoutHeader or Conditional etc. "
+ "has defined header (not shown) with header: '"
+ textHeader
+ "' and normal text: '"
+ textNormal
+ "'. "
+ "Type being: "
+ typeOfGraphicalItemName[typeOfGraphicalItem]
+ ". Header ignored.");
}
} // if
// check color
if (typeOfGraphicalItem != typeOfGraphicalItemStandardWithHeader &&
headerColor != black) {
println("Remark 325: color is set for header "
+ "(headerColor <> 0). Header being: '"
+ textHeader
+ "' and normal text: '"
+ textNormal
+ "'. "
+ "Type being: "
+ typeOfGraphicalItemName[typeOfGraphicalItem]
+ ". Color ignored.");
} // if
} // func
//
void display() {
// display a star in the text when selected
if (selected == objectID) {
if (textNormal.charAt(textNormal.length()-1) != '*') {
textNormal+="*";
}
}
else {
if (textNormal.charAt(textNormal.length()-1) == '*') {
// un-select
textNormal=textNormal.substring(0, textNormal.length()-1);
}
}
// display it
switch (typeOfGraphicalItem) {
case typeOfGraphicalItemStandardWithHeader:
displayStandardWithHeader() ;
break;
case typeOfGraphicalItemStandardWithoutHeader:
displayStandardWithoutHeader();
break;
case typeOfGraphicalItemConditional:
displayConditional();
break;
case typeOfGraphicalItemStartEnd:
displayStartEnd();
break;
default:
println("Error occured 245 - unknown typeOfGraphicalItem");
break;
} // switch
//
} // method
//
private void displayStandardWithHeader() {
fill (headerColor);
stroke(0);
// header rect
rect (Position.x, Position.y,
boxSize.x, headerHeight);
fill(244);
// rect for normal text field (lower half)
rect (Position.x, Position.y+headerHeight,
boxSize.x, boxSize.y-headerHeight);
fill (0);
text (textHeader, Position.x+4, Position.y+2, boxSize.x-5, headerHeight);
text (textNormal, Position.x+4, Position.y+headerHeight+2, boxSize.x-5, boxSize.y-headerHeight);
// adaptors --------
showAdaptors(adaptorTo);
} // method
//
private void displayStandardWithoutHeader() {
fill(244);
// rect for text field
rect (Position.x, Position.y,
boxSize.x, boxSize.y);
fill (0);
text (textNormal,
Position.x+4, Position.y+2,
boxSize.x-5, boxSize.y);
// adaptors --------
showAdaptors(adaptorTo) ;
} // method
//
private void displayConditional() {
// Conditional is triangle
fill(244);
triangle (Position.x, Position.y,
Position.x+boxSize.x+0, Position.y,
Position.x+boxSize.x/2+5, Position.y + boxSize.y);
fill (0);
textAlign(CENTER);
text (textNormal,
Position.x+2, Position.y+2,
boxSize.x-5, boxSize.y );
// adaptors ----------
showAdaptors(adaptorTo) ;
} // method
//
private void displayStartEnd() {
fill(244);
ellipseMode(CORNER);
ellipse (Position.x, Position.y, boxSize.x, boxSize.y);
fill (0);
textAlign(CENTER);
text (textNormal,
Position.x+7, Position.y+18,
boxSize.x-5, boxSize.y );
// adaptors ------------
showAdaptors(adaptorTo) ;
} // method
//
private void showAdaptors(ArrayList<AdaptorType> adaptorTo) {
// adaptors --------
for (AdaptorType adaptorThis : adaptorTo) {
if (adaptorThis != null) {
adaptorThis.display ( this ) ;
} // if
} // for
} // method
//
void addAdaptor(AdaptorType _adaptorTo) {
// appends one line on a existing GraphicalItem
if (_adaptorTo.adaptorToGraphicalItem > -1) {
adaptorTo.add (_adaptorTo);
} // if
} // method
//
boolean isMouseOver() {
if (mouseX/myScale > Position.x
&& mouseX/myScale < Position.x + boxSize.x
&& mouseY/myScale - myTranslate > Position.y
&& mouseY/myScale - myTranslate < Position.y + boxSize.y) {
return true;
} // if
else {
return false;
} // if else
} // method
//
int getObjectID() {
return objectID;
} // method
//
void delete() {
// delete one item in 3 steps:
// 1. delete outgoing Adaptors
adaptorTo.clear();
// 2. delete incoming Adaptors
deleteAllIncomingAdaptors(this);
// 3. delete graphicalItem itself
graphicalItems.remove(this);
} // method
//
private void deleteAllIncomingAdaptors( GraphicalItem myGraphicalItemParameter ) {
// delete
// go through all graphicalItems
for (GraphicalItem myGraphicalItem : graphicalItems) {
// when it's different from the one being tested:
if (myGraphicalItemParameter.objectID != myGraphicalItem.objectID) {
// check its adaptors --------
for (AdaptorType adaptorThis : adaptorTo) {
// When it's leading to the item being deleted
if (adaptorThis.adaptorToGraphicalItem==myGraphicalItemParameter.objectID) {
myGraphicalItem.adaptorTo.remove(adaptorThis);
// adaptorThis.remove();
} // if
} // for
} // for
} // if
} // method
//
private int getUniqueID() {
return id++;
}
//
} // class
// ==============================================================
class AdaptorType {
// Represents one connecting line.
//
// Start point (FROM) is a point at
// the GraphicalItem (a box) this
// AdaptorType-object belongs to.
// End point (TO) is another GraphicalItem
// marked by the var adaptorToGraphicalItem
// which is an Index for the ArrayList
// graphicalItems.
// To specify the exakt point at
// the from-GraphicalItem, the var
// fromAdaptor denotes whether it's
// (clockwise) north, east, south or west.
// And: To specify the exakt point at
// the to-GraphicalItem, the var
// toAdaptor denotes whether it's
// (clockwise) north, east, south or west.
//
// Indices of another GraphicalItem
int adaptorToGraphicalItem = -1; // other graphical item
// from which Adaptor of the four
int fromAdaptor = adaptorEast;
// to which Adaptor of the four
int toAdaptor = adaptorEast;
//
// constructor
AdaptorType ( int tempAdaptorToGraphicalItem,
int tempFromAdaptor,
int tempToAdaptor ) {
adaptorToGraphicalItem = tempAdaptorToGraphicalItem;
fromAdaptor = tempFromAdaptor;
toAdaptor = tempToAdaptor;
} // constructor
//
void display(GraphicalItem startGraphicalItem) {
// show the line
if (startGraphicalItem!=null) {
if (adaptorToGraphicalItem > -1) {
PVector startVector = getPVector
(startGraphicalItem, fromAdaptor);
GraphicalItem toItem = getElementByID(adaptorToGraphicalItem);
if (toItem!=null) {
PVector endVector = getPVector
(toItem, toAdaptor);
line ( startVector.x, startVector.y,
endVector.x, endVector.y );
} // if
} // if
} // if
} // method
//
private PVector getPVector(GraphicalItem graphicalItem, int whichAdaptor) {
// returns x,y for one adaptor "whichAdaptor" on the
// GraphicalItem named "startGraphicalItem".
// Can therefore be used for the start point and the end point of
// a line.
PVector buffer = new PVector ();
//
switch (whichAdaptor) {
case adaptorNorth:
buffer.x=graphicalItem.Position.x+graphicalItem.adaptorNorth.x;
buffer.y=graphicalItem.Position.y+graphicalItem.adaptorNorth.y;
break;
case adaptorEast:
buffer.x=graphicalItem.Position.x+graphicalItem.adaptorEast.x;
buffer.y=graphicalItem.Position.y+graphicalItem.adaptorEast.y;
break;
case adaptorSouth:
buffer.x=graphicalItem.Position.x+graphicalItem.adaptorSouth.x;
buffer.y=graphicalItem.Position.y+graphicalItem.adaptorSouth.y;
break;
case adaptorWest:
buffer.x=graphicalItem.Position.x+graphicalItem.adaptorWest.x;
buffer.y=graphicalItem.Position.y+graphicalItem.adaptorWest.y;
break;
default:
println ("Error 337 - unknown adaptor");
break;
} // switch
return buffer;
} // method
//
} // class
// ==============================================================

Top Reply