Transforming pdf to image

pedroglp

in Contributed Library Questions • 1 month ago

Well, I'm trying to use pdfbox to create a image trough a pdf file.
There only a few codes of this on the web and almost all of then have some problems, so I can't have a good reference.
Here's is my code:

//lots of import

void setup() {
size(200, 200);
}

void draw()
{
PDDocument pdf = null;
pdf = PDDocument.load(new File("C:\\Users\\Pedrog\\Documents\\Processing\\pdfConvert\\testing.pdf"));
PDFImageWriter imageWriter = new PDFImageWriter();
imageWriter.writeImage(pdf, "png", "", 1, 10, "imagemPdf");
}

But I keep reciving IOException on load function, I checked the library reference and they say that happens when: "If there is an error reading from the stream.". ( http://pdfbox.apache.org/apidocs/org/apache/pdfbox/pdmodel/PDDocument.html#load%28java.io.File%29)
I've already checked the path, the file name and executed processing as admin but nothing helped me.
Can someone give me any ideas?

Thank you.

Replies(4)

dimkir

Re: Transforming pdf to image

1 month ago

The error you're getting is:

When you're saying

But I keep reciving IOException on load function

you use terminology not correctly. And in this way you confuse first of all yourself, and from this confusion you misread the documents.

As the documentation says,

Exception is thrown " If there is an error reading from the stream.".

But in your case, it's NOT that exception is thrown, but it's just java (at compile time) just warns you that you haven't put the code to handle the exception. So if you see error Unhandled exception, it means that your code didn't even compile yet. So this error doesn't apply to the run-time (when usually IOException may happen).

All you have to do in your case is just wrap your code in try{} catch{} block.

like shown below (I also moved the code to setup from the draw() otherwise it would be converting pdf every frame):

//lots of import
void setup() {
size(400, 800);
PDDocument pdf = null;
try{
pdf = PDDocument.load(new File(dataPath("test.pdf")));
PDFImageWriter imageWriter = new PDFImageWriter();
imageWriter.writeImage(pdf, "png", "", 1,1, dataPath("test-") );
}
catch(IOException ioex){
ioex.printStackTrace();
exit(); // this is to stop execution of sketch
return;
}
noLoop();
String imgFilename = "test-1.png";
img = loadImage(imgFilename);
if ( img == null ){
println("Error, cannot load image file [" + imgFilename + "]");
exit();
return;
}
}
PImage img;
void draw()
{
image(img, 0, 0);
}

Also if you create code folder inside of your sketch folder, then you won't need to insert imports for pdfbox. Everything what's inside of code subfolder of your sketch gets automatically imported.

Here's the contents of the code subfolder. (probably just 1 jar file is enough, i guess -app- one is redundant. But i just copied them there anyways.. just to be sure :)

As the result

I managed to convert PDF to image and display it in a sketch:

And that's the originating PDF:

You may still get exceptions thrown in case you make make mistake when stating amount of pages you want to convert to image (ie. in my test.pdf, i have only 2 pages, so when I specify page range 1-11 the exception will be thrown.

Here's screenshot of the exception and some commentary which may help you reading exception errors and to trace that error to your code

hope this helps

pedroglp

Re: Transforming pdf to image

1 month ago

You really helped me a lot! I'm on my phone now and I've just read the answer. But I will try as soon as I arrive home. Thank you so much for the class haha :). Btw why does this function only work inside "try" method?

GoToLoop

Re: Transforming pdf to image

1 month ago

BtW, why does this function only work inside "try" method?

That is called try/ catch block.
When we call a method which has throws declared in it, and also refers to a checked exception,
we oughta put that encased in such block.

This code won't compile:

void setup() {
  test(5);
  exit();
}

void test(int a) throws ClassNotFoundException {
  println(a);
}

Since test() is declared it can throw a ClassNotFoundException, and it's also of a checked type;
we have to put that call inside a try block for it to compile:

void setup() {
  try {
    test(5);
  }

  catch(Throwable t) {
  }

  exit();
}

void test(int a) throws ClassNotFoundException {
  println(a);
}

Even though test() just lied about it. It doesn't throw anything at all!

And before I forget, this link got a list of common Java exceptions:
http://www.roseindia.net/java/java-exception/listofjavaexception.shtml

pedroglp

Re: Transforming pdf to image

1 month ago

@GoToLoop
Thank you for the explanation GoToLoop. It was very helpfull, I think I'll have to deal with alot of other functions with throw. (and this site you sent me is really good!)

@Topic
I finally converted the pdf to image :) but I had to add two missing jars:
- commons-logging.1.1.3
- http://mvnrepository.com/artifact/org.apache.pdfbox/fontbox/1.8.2
(IF YOU ARE READING THIS ON FUTURE: SEARCH THE NEWEST FONTBOX!!! IT WILL CORRECT ALOT OF BUGS)

I don't know if these jars depends of the PDF(so probably I'll have to test other kinds of pdf) or the pdfbox library assumide that I must had those jars.

I think won't have anymore problem, I just had to check a way to keep searching pdfs on the folder and converting then when found a new one. But I think it will be no hard job.

Thanks for you two :)

Top Reply