Transformation matrix to map a line segment onto another

Programming Questions

bricola

Transformation matrix to map a line segment onto another

in Programming Questions • 1 year ago

Hi, I'm having transformation matrix woes. So I have 2 line segments and I'm trying construct with scale(), translate() and rotate() the matrix that maps one onto the other. I'm almost there but I'm having issues with the operator order. At the moment I have (partially pseudo):

PMatrix2d mat = new PMatrix2d();
//get the scale ratio of the line segs
float scale = line2.getLength() / line1.getLength();
//get angle between line segs
float angle = PVector.sub( line2 .p2, line2 .p1).heading2D() - PVector.sub(line1.p2, line1.p1).heading2D() + Main.PI;
mat.translate(line1.p1.x, line1 .p1.y);
mat.scale(scale);
mat.translate(- line1.p1.x, - line1.p1.y);
mat.translate(( line2.p2.x - line1.p1.x)/scale, ( line2.p2.y - line1.p1.y)/scale);
mat.rotate(angle);
return mat;

Any hinters? Attached is an almost entirely useless diagram. Cheers.

Replies(2)

toxmeister

Re: Transformation matrix to map a line segment onto another

1 year ago

I think you've got one extra translate() in there.. your order should be:

1) move L1 to world origin (i.e. subtract l1a)

2) rotate to match direction of L2

3) scale to length of L2

4) move L1 to L2a

To do this all in one matrix multiply you need to concatenate these operations in reverse order..

Untested...

PVector l1a = new PVector(10, 20);
PVector l1b = new PVector(-30, 40);
PVector l2a = new PVector(150, 160);
PVector l2b = new PVector(300, 50);
PVector dirA = PVector.sub(l1b, l1a);
PVector dirB = PVector.sub(l2b, l2a);
float delta = dirB.heading2D() - dirA.heading2D();
float scale = dirB.mag() / dirA.mag();
PMatrix2D pm=new PMatrix2D();
pm.translate(l2a.x, l2a.y); // step 4
pm.scale(scale); // step 3
pm.rotate(delta); // step 2
pm.translate(-l1a.x, -l1a.y); // step 1
l1a=pm.mult(l1a,null);
l1b=pm.mult(l1b,null);

// ...now l1 vertices should match l2

http://postspectacular.com | http://toxiclibs.org

bricola

Re: Transformation matrix to map a line segment onto another

1 year ago

Ah man, it worked a treat! Thank you so much. I was fiddling about with that for hours. If you're interested, it's for a fractalesque drawing program I'm writing where you draw shapes or import them as SVG, then attach 'sockets' to them. The sockets are given rules as to which other sockets of which shapes they can join to (it can be the same shape). The algorithm then recursively joins these shapes together at the sockets - the aligning of the sockets is the bit you helped with (the hardest bit...).

Cheers!

Rob

Top Reply