Toxi.physics Circular/ParticleConstraint

fridddd

Toxi.physics Circular/ParticleConstraint

in Contributed Library Questions • 2 years ago

Hi,

I'm trying to get a better understanding of the toxilibs and physics in particular but it's not really working out. Taking small steps so i started with 2d first. After modifying the attract2d-example i'm trying to add a barrier when they fall down so i need to implement a (circular) particleconstraint on the particles and this is where things go wrong. I've tried (the commented lines) but i'ts saying it cannot find the class? So my guess is i'm totally wrong here and before i lose all hope i turn to you...

And some small things-

This "for"-structure, is this processing-native or only available in toxi? I assume it says increase verletparticle p untill it is equal to physics.particles?

for (VerletParticle2D p : physics.particles) {
ellipse(p.x, p.y, 5, 5);
point(p.x,p.y);

And from the boxfluiddemo: What is AABB?

physics.setWorldBounds(new AABB(new Vec3D(),new Vec3D(DIM,DIM,DIM)));

Anyway sorry for the long post but i'd like to understand this (amazing) library so i really appreciate all the help and i hope i've been clear enough in explaining the issues. Thanks

FRid

And on a sidenote: are there any good tutorials regarding the toxilibs (physics in particular)? The javadocs are not really working for me, i see all the very nice features available but i have no knowledge of how to implement them.

import toxi.geom.*;
import toxi.physics2d.*;
import toxi.physics2d.behaviors.*;

int NUM_PARTICLES = 100;

VerletPhysics2D physics;

//CirculrConstraint myConstraint; // This gives me "cannot find class or type named "CircularConstraint""
//ParticleConstraint2d myConstraint; // This gives me "cannot find class or type named "ParticleConstraint2d""

void setup() {
size(400,400,P2D);

physics = new VerletPhysics2D();
physics.setDrag(0.05f);
physics.setWorldBounds(new Rect(0, 0, width, 300));
physics.addBehavior(new GravityBehavior(new Vec2D(0, 0.15f)));

//myConstraint = new CircularConstraint(200,200,300);
//Physics.addConstraintToAll(myConstraint,p);

}

void addParticle() {
VerletParticle2D p = new VerletParticle2D(Vec2D.randomVector().scale(5).addSelf(width / 2, 0));
physics.addParticle(p);
physics.addBehavior(new AttractionBehavior(p, 5, -1.2f, 0.01f)); //(Vec2,radius,strength,jitter)
}

void draw() {
background(255,0,0);

if (physics.particles.size() < NUM_PARTICLES) {
    addParticle();
}
physics.update();
for (VerletParticle2D p : physics.particles) {
    ellipse(p.x, p.y, 5, 5);
    point(p.x,p.y);
}
}

Replies(5)

amnon.owed

Re: Toxi.physics Circular/ParticleConstraint

2 years ago

Let me try to answer some of those things (even though I have still much to learn about the libs myself).

With regard to your specific code example. There are a few things that I changed to make it work.

Add the import statement for 2D constraints: import toxi.physics2d.constraints.*;
Fixed typo for CircularConstraint
I used a circle so I can display it and use it as a constraint. You can set it directly in the constraint, however to set the location as you tried, you will need to use a Vec2D like this: Vec2D(200,200)
You can addContraintToAll in principle, however in this case there will be no particles in there yet. So it's kind of pointless. For this example it's better to add the constraint to the individual particle as you create each one with the the addParticle function.

Code Example

import toxi.geom.*;
import toxi.physics2d.*;
import toxi.physics2d.behaviors.*;
import toxi.physics2d.constraints.*;
int NUM_PARTICLES = 100;
VerletPhysics2D physics;
CircularConstraint myConstraint;
Circle c;
void setup() {
size(400,400,P2D);
physics = new VerletPhysics2D();
physics.setDrag(0.05f);
physics.setWorldBounds(new Rect(0, 0, width, 300));
physics.addBehavior(new GravityBehavior(new Vec2D(0, 0.15f)));
c = new Circle(new Vec2D(200,200),75);
myConstraint = new CircularConstraint(c);
noStroke();
smooth();
}
void addParticle() {
VerletParticle2D p = new VerletParticle2D(Vec2D.randomVector().scale(5).addSelf(width / 2, 0));
p.addConstraint(myConstraint);
physics.addParticle(p);
physics.addBehavior(new AttractionBehavior(p, 5, -1.2f, 0.01f));
}
void draw() {
background(255,0,0);
if (physics.particles.size() < NUM_PARTICLES) {
addParticle();
}
physics.update();
float r = c.getRadius() * 2;
fill(255,125);
ellipse(c.x, c.y, r, r);
fill(255);
for (VerletParticle2D p : physics.particles) {
ellipse(p.x, p.y, 5, 5);
point(p.x,p.y);
}
}

To answer some of your other questions.

The for loop is a JAVA thing. There are a couple of ways you can run through a for loop. The classic way, with an iterator and with the enhanced for loop, which is what this one is called. It's also called a for-each loop cause that's how you can see it. For each VerletParticle2D p in the list of physics.particles do this and that. It's the cleanest and shortest way to write, so I personally prefer the enhanced for loop. If you need the index i specifically, you can revert back to the other for loop methods.

The AABB in the boxfluiddemo is a 3D box. See here. With the code you gave it's created at position (0,0,0) with dimensions (dim, dim, dim). In turn the box is used as worldbounds for the physics systems. It's pretty much the same as in 2D except you have a box instead of a rectangle to constrain things.

There are a lot of online Toxiclibs tutorials gathered here. Check 'em out.

fridddd

Re: Toxi.physics Circular/ParticleConstraint

2 years ago

Much clearer, thanks!

"Add the import statement for 2D constraints: import toxi.physics2d.constraints.*;"

Damn, i'm almost ashamed it was a missing library (and a typo). And thanks for the tutorials, didn't find those before.

FRid

fiveagon

Re: Toxi.physics Circular/ParticleConstraint

2 years ago

I've been looking at toxi.physics2d stuff, including just Vec2D. I was inspired to take Amnon's example and make it use Geomerative. It turned into some sort of fluid thing. In draw(), uncomment line 47 to make the fluidShape less "sticky".

import geomerative.*;
import toxi.geom.*;
import toxi.physics2d.*;
import toxi.physics2d.behaviors.*;
import toxi.physics2d.constraints.*;
int NUM_PARTICLES = 50;
VerletPhysics2D physics = new VerletPhysics2D();
Vec2D particleOrigin;
Circle c;
CircularConstraint myConstraint;
List<RShape> shapeList = new ArrayList<RShape>(NUM_PARTICLES);
RShape fluidShape;
void setup() {
size(640, 360);
smooth();
RG.init(this);
physics.setDrag(0.05f);
physics.setWorldBounds(new Rect(0, 0, width, 300));
physics.addBehavior(new GravityBehavior(new Vec2D(0, 0.15f)));
c = new Circle(new Vec2D(width/2, height/2), 75);
myConstraint = new CircularConstraint(c);
particleOrigin = new Vec2D(width/2, 0);
addParticle();
fluidShape = shapeList.get(0);
}
void addParticle() {
RShape s = RG.getEllipse(0, 0, height);
s.scale(0.05);
s.translate(particleOrigin.x, particleOrigin.y);
shapeList.add(s);
VerletParticle2D p = new VerletParticle2D(Vec2D.randomVector().scale(5).addSelf(particleOrigin));
p.addConstraint(myConstraint);
physics.addParticle(p);
physics.addBehavior(new AttractionBehavior(p, 5, -1.2f, 0.01f));
}
void draw() {
background(255, 0, 0);
if (physics.particles.size() < NUM_PARTICLES) {
addParticle();
}
physics.update();
float r = c.getRadius() * 2;
fill(255, 125);
ellipse(c.x, c.y, r, r);
fill(255);
// Uncomment this to get a different effect!
// fluidShape = shapeList.get(0);
int i = 0;
for (VerletParticle2D p : physics.particles) {
Vec2D v = p.getVelocity();
RShape s = shapeList.get(i++);
s.translate(v.x, v.y);
fluidShape = RG.union(fluidShape, s);
}
fluidShape.draw();
}

fridddd

Re: Toxi.physics Circular/ParticleConstraint

2 years ago

Nice one! Somewhat reminds me of melting marshmellows.