Timer In Processing

Programming Questions

acallen180

in Programming Questions • 1 years ago

Hello, can you help me create a code for processing in which the time increases.

I would like to create the timer in which the format is 0:00:00. I would like to control the color of the numbers.

The first 0 is the hours, the second & third 0 is the minutes and the fourth and the fifth 0 is the seconds.

For example 2:35:16 corresponds to 2 hours, 35 minutes, 16 seconds.

Thank you for your help.

Replies(17)

jbum

Re: Timer In Processing

1 years ago

Happy to help you learn now to do this, but I don't want to present it on a plate, since this sounds like homework.

The millis() function gives you time in milliseconds. Divide it my 1000 to get seconds.

Divide seconds by 60 to get minutes.

Divide minutes by 60 to get hours.

How about you write some code and we'll help if you get stuck? Read the section of the processing reference on typography to learn how to display numbers.

acallen180

Re: Timer In Processing

1 years ago

No, this does not sound like homework. I know how to display numbers. I want to know how to utilize: int s= second();, int m = minute(); & int h = hour(); .

It would be great to see a template of how a timer works for processing to view the hours, minutes and seconds. In the form, 0:00:00.

Something along the lines of the following:

PFont myfont = createFont("Verdana", 12);

void setup(){

size (250,100);

background(100,100,100);

}

void draw() {

background(100,100,100);

int s = second();

int m = minute();

int h = hour();

text(h+":"+m+":"+s, 15, 50);

}

But, I would like the timer to be set at 0:00:00.

acallen180

Re: Timer In Processing

1 years ago

Or the following:

PFont words = createFont("Vernada", 12);

int s = second();

void setup() {

size(500, 350);

frameRate(30);

}

void draw() {

background(#FFFFFF);

time();

}

void time() {

fill(#000000);

textAlign(CENTER);

textFont(words, 50);

text(second(), 350, 175);

text(":", 300, 175);

text(minute(), 250, 175);

text(":", 200, 175);

text(hour(), 150, 175);

}

jbum

You can't use second(), minute() etc. because they are based on the current time. You can use millis() to construct a clock though. Here's a sample StopWatch class, that does it. I based it on the Java code found here:

http://www.goldb.org/stopwatchjava.html

// This class based on code found here: http://www.goldb.org/stopwatchjava.html
class StopWatchTimer {
int startTime = 0, stopTime = 0;
boolean running = false;
void start() {
startTime = millis();
running = true;
}
void stop() {
stopTime = millis();
running = false;
}
int getElapsedTime() {
int elapsed;
if (running) {
elapsed = (millis() - startTime);
}
else {
elapsed = (stopTime - startTime);
}
return elapsed;
}
int second() {
return (getElapsedTime() / 1000) % 60;
}
int minute() {
return (getElapsedTime() / (1000*60)) % 60;
}
int hour() {
return (getElapsedTime() / (1000*60*60)) % 24;
}
}

To use it,

StopWatchTimer sw = new StopWatchTimer();

To start it:

sw.start();

To poll the seconds:

sw.seconds(); // instead of just seconds();

acallen180

Re: Timer In Processing

1 years ago

I understand now that I should use the millis() to construct a clock. But I don't understand the code. The timer is not visible, the text is not visible, nothing is really visible besides the canvas in Processing. I also don't know where to place the last part where you specified, "To use it, To start it & to poll the seconds".

PhiLho

Re: Timer In Processing

1 years ago

I think you can put the first two items in setup(), and in your code, replace second() with sw.second() (no plural), and so on.

acallen180

Re: Timer In Processing

1 years ago

There's an unexpected token: sw. When I replace second() with sw.second().

void setup(){

size(400, 400);

StopWatchTimer sw = new StopWatchTimer();

}

class StopWatchTimer {

int startTime = 0, stopTime = 0;

boolean running = false;

void start() {

startTime = millis();

running = true;

}

void stop() {

stopTime = millis();

running = false;

}

int getElapsedTime() {

int elapsed;

if (running) {

elapsed = (millis() - startTime);

}

else {

elapsed = (stopTime - startTime);

}

return elapsed;

}

int sw.second(){

return (getElapsedTime() / 1000) % 60;

}

int minute() {

return (getElapsedTime() / (1000*60)) % 60;

}

int hour() {

return (getElapsedTime() / (1000*60*60)) % 24;

}

jbum

Re: Timer In Processing

1 years ago

StopWatchTimer sw;

Should be declared outside setup as a global variable, so that it can still be used elsewhere.

In setup, remove the word StopWatchTimer in front of

sw = new StopWatchTimer();

So it uses the global one, instead of making a new local one. In java and processing, variables declared inside a function are local to that function (the have local scope). Variables declared outside any functions can be seen used anywhere, and have global scope.

acallen180

Re: Timer In Processing

1 years ago

Won't function once again....

//global variables

StopWatchTimer sw;

void setup(){

size(400, 400);

sw = new StopWatchTimer();

}

class StopWatchTimer {

int startTime = 0, stopTime = 0;

boolean running = false;

void start() {

startTime = millis();

running = true;

}

void stop() {

stopTime = millis();

running = false;

}

int getElapsedTime() {

int elapsed;

if (running) {

elapsed = (millis() - startTime);

}

else {

elapsed = (stopTime - startTime);

}

return elapsed;

}

int second(){

return (getElapsedTime() / 1000) % 60;

}

int minute() {

return (getElapsedTime() / (1000*60)) % 60;

}

int hour() {

return (getElapsedTime() / (1000*60*60)) % 24;

}

PhiLho

Re: Timer In Processing

1 years ago

You are supposed to use your time() function, adapted as described.

acallen180

Re: Timer In Processing

1 years ago

I am clueless.

Chrisir

Re: Timer In Processing

1 years ago

Hi,

as it was written before, you have to use minutes() etc.

Use the class / object, not only declare it.

OK, this is totally wrong, because I forgot to put sw. in - better version see below.
This one only gives you the real time.

// =================================================================
//global variables / objects
StopWatchTimer sw;
// =================================================================
// Main functions
void setup() {
size(400, 400);
sw = new StopWatchTimer();
sw.start();
}
void draw () {
time();
}
// =================================================================
// Other functions
void time() {
background(#FFFFFF);
fill(#000000);
textAlign(CENTER);
// textFont(words, 50);
text(second(), 350, 175);
text(":", 300, 175);
text(minute(), 250, 175);
text(":", 200, 175);
text(hour(), 150, 175);
}
// =================================================
// classes
class StopWatchTimer {
int startTime = 0, stopTime = 0;
boolean running = false;
void start() {
startTime = millis();
running = true;
}
void stop() {
stopTime = millis();
running = false;
}
int getElapsedTime() {
int elapsed;
if (running) {
elapsed = (millis() - startTime);
}
else {
elapsed = (stopTime - startTime);
}
return elapsed;
}
int second() {
return (getElapsedTime() / 1000) % 60;
}
int minute() {
return (getElapsedTime() / (1000*60)) % 60;
}
int hour() {
return (getElapsedTime() / (1000*60*60)) % 24;
}
}
// ====================================================

Greetings, Chrisir

acallen180

Re: Timer In Processing

1 years ago

Thank you Chrisir!

The time corresponds to the current time, which is great!

But, is there any way to have the time set at 0:00:00. Hours: Minutes: Seconds?

Chrisir

Re: Timer In Processing

1 years ago

Sure

// =================================================================
//global variables / objects
StopWatchTimer sw;
// =================================================================
// Main functions
void setup() {
size(400, 400);
println (millis());
sw = new StopWatchTimer();
sw.start();
}
void draw () {
time();
}
// =================================================================
// Other functions
void time() {
background(#FFFFFF);
fill(#000000);
textAlign(CENTER);
// textFont(words, 50);
//
// text(second()+ , 350, 175);
//
// text(":", 300, 175);
//
// text(minute(), 250, 175);
//
// text(":", 200, 175);
// text(hour(), 150, 175);
text(nf(sw.hour(), 2)+":"+nf(sw.minute(), 2)+":"+nf(sw.second(), 2), 150, 175);
}
// =================================================
// classes
class StopWatchTimer {
int startTime = 0, stopTime = 0;
boolean running = false;
void start() {
startTime = millis();
running = true;
}
void stop() {
stopTime = millis();
running = false;
}
int getElapsedTime() {
int elapsed;
if (running) {
elapsed = (millis() - startTime);
}
else {
elapsed = (stopTime - startTime);
}
return elapsed;
}
int second() {
return (getElapsedTime() / 1000) % 60;
}
int minute() {
return (getElapsedTime() / (1000*60)) % 60;
}
int hour() {
return (getElapsedTime() / (1000*60*60)) % 24;
}
}
// ====================================================

Greetings, Chrisir

acallen180

Re: Timer In Processing

1 years ago

Thank you Chrisir!!

Chrisir

Re: Timer In Processing

1 years ago

well, thanks to the other guys, jbum and phi.lho, I really only put the pieces together... and that also wrong...

tech37

Re: Timer In Processing

1 years ago

This tread was interesting. A stop watch is missing a function to stop/start the time, so I made a few modification in the code so you can stop the watch and re-start the watch using the mouse button. And I add a 100's seconds counting.

Here the modification:

text(nf(sw.hour(), 2)+":"+nf(sw.minute(), 2)+":"+nf(sw.second(), 2), 150, 175);

change to:

text(nf(sw.hour(), 2)+":"+nf(sw.minute(), 2)+":"+nf(sw.second(), 2)+":"+nf(sw.hundrensec(), 2), 150, 175);

add a mouse function :

void mousePressed()
{
if (mouseButton==LEFT)
{
sw.stop();
}
else if (mouseButton==RIGHT)
{
sw.start();
}
}
// And add in the class before int second() this :
int hundrensec()
{
return (getElapsedTime() / 10) % 100;
}

Top Reply