The usual NullPointerException, this time with mouseClicked()

Programming Questions

noise

The usual NullPointerException, this time with mouseClicked()

in Programming Questions • 3 years ago

I am getting a NullPointerException when I use a mouseClicked() to add a new object to an array. I think it's a scope problem or perhaps the mouseClicked() event is happening in the middle of something causing confusion. My sketch models some charged particles moving around in 2 dimensions. When you click, it is supposed to add a new particle of random charge polarity where you click. I can't really see what the problem is specifically, though. Perhaps it's obvious to someone around here.

Thanks

// Global Declarations.
int backgroundColor = 200;
int noOfParticles = 0;
// Temporary value to hold the field strength.
float tempFieldStrength;
Particle[] particles;
// PVector holding a temporary field.
PVector tempFieldVector;
// Setup Function.
void setup() {
size(640, 480);
particles = new Particle[16];
particles[0] = new Particle(10, -10, 300, 200);
noOfParticles++;
particles[1] = new Particle(10, -10, 400, 400);
noOfParticles++;
particles[2] = new Particle(10, 10, 500, 300);
noOfParticles++;
particles[3] = new Particle(10, 10, 100, 100);
noOfParticles++;
}
// Main Program Loop.
void draw() {
background(backgroundColor);
// Locate particles.
for (int i = 0; i < noOfParticles; i++) {
particles[i].updateLocation(); // Here's where Processing highlights the crash...
}
// Draw particles.
for (int i = 0; i < noOfParticles; i++) {
particles[i].drawParticle();
}
// Update particle velocity.
for (int i = 0; i < noOfParticles; i++) {
particles[i].updateVelocity(i);
}
}
void mouseClicked() {
// Random charge
float polarity = random(-1, 1);
if (polarity > 0) polarity = 10;
if (polarity < 0) polarity = -10;
noOfParticles++;
particles[noOfParticles+1] = new Particle(10, int(polarity), mouseX, mouseY);
}
class Particle {
// Fields
// The particle's mass.
float mass;
// The particle's charge.
float charge;
// The particle's physical size.
int dia;
// PVector representing particle location.
PVector loc;
// PVector representing particle velocity.
PVector v;
// Constructor
Particle(float m, int c, int x, int y) {
// How the constructor is called will determine the particle mass and charge.
mass = m;
charge = c;
// The location of each new particle is chosen by the main program.
loc = new PVector(x, y);
// The velocity of all particles starts out at 0.
v = new PVector(0, 0);
tempFieldVector = new PVector(0, 0);
}
// Methods
void drawParticle() {
noStroke();
// Particle fill color will be based on the charge.
if (charge > 0) fill(255);
if (charge < 0) fill(0);
// Draw the particle at it's location vector.
ellipse(loc.x, loc.y, int(mass), int(mass));
}
void updateVelocity(int whichOne) {
// Velocity changes based on the pull of all the other particles.
for (int i = 0; i < noOfParticles; i++) {
if (whichOne != i) {
// Add to the velocity vector the force due to each particle.
tempFieldVector.x = loc.x - particles[i].loc.x;
tempFieldVector.y = loc.y - particles[i].loc.y;
tempFieldStrength = charge * particles[i].charge / sq(tempFieldVector.mag());
tempFieldVector.normalize();
tempFieldVector.mult(tempFieldStrength / mass);
v.add(tempFieldVector);
}
}
}
void updateLocation() {
// The location vector is based on the old location plus the velocity.
loc.add(v);
}
}

Replies(7)

cedrickie..

Re: The usual NullPointerException, this time with mouseClicked()

3 years ago

try working with an array list.
This should solve your problems and makes more sense in your case.
http://processing.org/reference/ArrayList.html
http://processing.org/learning/topics/arraylistclass.html

PhiLho

Re: The usual NullPointerException, this time with mouseClicked()

3 years ago

Indeed, the NPEs are quite common, but fortunately they are usually easy to fix... Except here the exception happens (probably, I haven't run your code) actually outside of mouseClicked(). When reporting such error, you should provide the error message Processing gives.

Cedric is right about ArrayList, but if you plan not to use more than a fixed number of particles, check you don't exceed the bounds of the array, you will avoid another very common error: ArrayIndexOutOfBoundsException.
In your case, the error comes from the fact you increment noOfParticles then use noOfParticles+1, thus skipping an entry in your array. Note that you can use:
particles[++noOfParticles] = new Particle(10, int(polarity), mouseX, mouseY);

noise

Re: The usual NullPointerException, this time with mouseClicked()

3 years ago

I may or may not have implemented your solution properly, but I still get the NPE. I think I will just use the ArrayList anyway and keep track of its size with the built-in size() method rather than relying on my skills as a programmer. I originally used the Array because I know those better and figured I wouldn't need more than X many particles anyway.

And next time I will copy the error information to the thread.

Thanks everyone and we'll see how the ArrayList works out.

quarks

Re: The usual NullPointerException, this time with mouseClicked()

3 years ago

In this program noOfParticles does two things
1) Keeps track of the actual number of particles created but also
2) The location in the array where the next particle should be stored.

For instance if noOfParticles = 5 then array positions 0-4 have been taken so change the mouseClicked methods to

void mouseClicked() {
// Random charge
float polarity = random(-1, 1);
if (polarity > 0) polarity = 10;
if (polarity < 0) polarity = -10;
particles[noOfParticles] = new Particle(10, int(polarity), mouseX, mouseY);
noOfParticles++;
}

or be clever and replace lines 6 & 7 with a single line

particles[noOfParticles++] = new Particle(10, int(polarity), mouseX, mouseY);

noise

Re: The usual NullPointerException, this time with mouseClicked()

3 years ago

It works just fine with the ArrayList. But I saved the array version as a separate file and it works if I post-increment noOfParticles as I use it as my array index. At first when it didn't work I was pre-incrementing.

By the way, I can look this up for myself but if anyone is really bored and wants to respond, can you remove a member of an ArrayList from the middle and have the list still make sense? Basically, I'm thinking ahead to what happens when my particles drift away off screen and I don't need them anymore.

But thanks again for the responses.

blindfish

Re: The usual NullPointerException, this time with mouseClicked()

3 years ago

can you remove a member of an ArrayList from the middle and have the list still make sense?

Depends what you mean by "still make sense". If you mean can you remove an item from an ArrayList and have your code continue to work then the answer is yes (assuming you're using the ArrayList's size as the limit when iterating over it). In fact there's a remove method that does just that. One note of caution though: you should probably avoid removing an element when you are iterating over the ArrayList. If you do you might run into all kinds of interesting errors. Instead you may have to 'mark' the element to be deleted (e.g. by setting an appropriate property) and then check the value of this property and act accordingly at the end of each cycle.

noise

Re: Re: The usual NullPointerException, this time with mouseClicked()

3 years ago

Nice. OK. So just wait to remove an element until after I'm done using the ArrayList for the time being.

Top Reply