IllegalArgumentException: negative width

Programming Questions

paul_ngc

IllegalArgumentException: negative width

in Programming Questions • 3 years ago

The first error was solved. But now I've got the following error, that sometimes popups. So I guess it says that it can't display a point because it size is -3 for example. No problem if it's too small, but when I get this error it won't export the pdf.

The error:

processing.app.debug.RunnerException: IllegalArgumentException: negative width

at processing.app.Sketch.placeException(Sketch.java:1543)

at processing.app.debug.Runner.findException(Runner.java:583)

at processing.app.debug.Runner.reportException(Runner.java:558)

at processing.app.debug.Runner.exception(Runner.java:498)

at processing.app.debug.EventThread.exceptionEvent(EventThread.java:367)

at processing.app.debug.EventThread.handleEvent(EventThread.java:255)

at processing.app.debug.EventThread.run(EventThread.java:89)

Exception in thread "Animation Thread" java.lang.IllegalArgumentException: negative width

at java.awt.BasicStroke.<init>(BasicStroke.java:181)

at java.awt.BasicStroke.<init>(BasicStroke.java:254)

at processing.core.PGraphicsJava2D.strokeImpl(PGraphicsJava2D.java:1427)

at processing.core.PGraphicsJava2D.strokeWeight(PGraphicsJava2D.java:1408)

at processing.core.PGraphics3D.rawPoints(PGraphics3D.java:1072)

at processing.core.PGraphics3D.endShape(PGraphics3D.java:660)

at processing.core.PGraphics.endShape(PGraphics.java:1181)

at processing.core.PGraphics.point(PGraphics.java:1448)

at processing.core.PApplet.point(PApplet.java:7789)

at Volkswagen_Grafik_3.draw(Volkswagen_Grafik_3.java:132)

at processing.core.PApplet.handleDraw(PApplet.java:1606)

at processing.core.PApplet.run(PApplet.java:1503)

at java.lang.Thread.run(Thread.java:637)

The code

// Thanks to Generative Gestaltung for the code of the mesh drawing!

// Thanks to Amnon Owed for helping me out

import processing.opengl.*;

import processing.pdf.*;

import controlP5.*;

ControlP5 myP5;

ControlWindow myGUIWindow;

// horizontal

int uCount = 28;

float uMin = 4.13;

float uMax = 5.20;

// vertical

int vCount = 28;

float vMin = 0.40;

float vMax = -0.39;

// panning

float xwidth = 0.47;

float yheight = 0.5;

// extra

float magnification = 250;

// view rotation

int offsetX = 0, offsetY = 0, clickX = 0, clickY = 0;

float rotationX = -14.10, rotationY = -3.77, targetRotationX = 0, targetRotationY = 0, clickRotationX, clickRotationY;

boolean savePDF = false;

PImage boven;

PImage onder;

PImage links;

PImage rechts;

void setup() {

  size(600, 600, OPENGL);

  hint(ENABLE_OPENGL_4X_SMOOTH);

  boven = loadImage("boven.png");

  onder = loadImage("onder.png");

  links = loadImage("links.png");

  rechts = loadImage("rechts.png");



  // controlp5 setup

  myP5 = new ControlP5(this);

  myP5.setAutoDraw(false);

  myGUIWindow = myP5.addControlWindow("GUI_WINDOW", 600,105);

  myGUIWindow.hideCoordinates();

  // control window setup

  myGUIWindow.setTitle("Werte wählen");

  Controller mySlideruMin = myP5.addSlider("uMin",-5,5, uMin, 10, 10, 225, 10);

  mySlideruMin.setWindow(myGUIWindow);

  Controller mySlideruMax = myP5.addSlider("uMax",-5,5, uMax, 10, 25, 225, 10);

  mySlideruMax.setWindow(myGUIWindow);

  Controller mySlidervMin = myP5.addSlider("vMin",-5,5, vMin, 10, 40, 225, 10);

  mySlidervMin.setWindow(myGUIWindow);

  Controller mySlidervMax = myP5.addSlider("vMax",-5,5, vMax, 10, 55, 225, 10);

  mySlidervMax.setWindow(myGUIWindow);

  Controller mySlidervCount = myP5.addSlider("vCount",1,100, vCount, 10, 70, 225, 10);

  mySlidervCount.setWindow(myGUIWindow);

  Controller mySlideruCount = myP5.addSlider("uCount",1,100, uCount, 10, 85, 225, 10);

  mySlideruCount.setWindow(myGUIWindow);

  Controller mySliderrotationX = myP5.addSlider("rotationX",-50,50, rotationX, 305, 10, 225, 10);

  mySliderrotationX.setWindow(myGUIWindow);

  Controller mySliderrotationY = myP5.addSlider("rotationY",-50,50, rotationY, 305, 25, 225, 10);

  mySliderrotationY.setWindow(myGUIWindow);

  Controller mySliderxwidth = myP5.addSlider("xwidth",-2.5,2.5, xwidth, 305, 40, 225, 10);

  mySliderxwidth.setWindow(myGUIWindow);

  Controller mySlideryheight = myP5.addSlider("yheight",-2.5,2.5, yheight, 305, 55, 225, 10);

  mySlideryheight.setWindow(myGUIWindow);

  Controller mySlidermagnification = myP5.addSlider("magnification",1,400, magnification, 305, 70, 225, 10);

  mySlidermagnification.setWindow(myGUIWindow);

}

void draw() {

  String filename = int(uMin*10)+"_"+int(uMax*10)+"_"+int(vMin*10)+"_"+int(vMax*10)+"_";

  if (savePDF) beginRaw(PDF, filename+timestamp()+".pdf");

  background(0);

  image (boven,0,0);

  image (onder,0,547);

  image (links,0,56);

  image (rechts,548,56);

  noFill();

  stroke(255);

  setView();

  scale(magnification);

  // draw mesh

  for (float iv = vCount-1; iv >= 0; iv--) {

   beginShape();

   for (float iu = 0; iu <= uCount; iu++) {

   float u = map(iu, 0, uCount, uMin, uMax);

   float v = map(iv, 0, vCount, vMin, vMax);

   float x = 0.75*v;

   float y = sin(u)*v;

   float z = cos(u)*cos(v);

   vertex(x, y, z);

   v = map(iv+1, 0, vCount, vMin, vMax);

   x = 0.75*v;

   y = sin(u)*v;

   z = cos(u)*cos(v);

   vertex(x, y, z);

   strokeWeight(0.2 + z*0.5 + u*0.5 + v*0.5);

   point(x,y,z);

   }

   endShape();

  }



  // image output

  if(savePDF == true) {

   endRaw();

   savePDF = false;

  }

}

void keyPressed(){

  if(key=='p' || key=='P') savePDF = true;

  println("U Range: " + nf(uMin,0,1) + " - " + nf(uMax,0,1) + " | V Range: " + nf(vMin,0,1) + " - " + nf(vMax,0,1));

}

void setView() {

  translate(width*xwidth,height*yheight);

  rotateX(-rotationY);

  rotateY(rotationX);

}

String timestamp() {

  return String.format("%1$ty%1$tm%1$td_%1$tH%1$tM%1$tS", Calendar.getInstance());

}

Replies(6)

cedrickie..

Re: The fiel Component.x is not visible!

3 years ago

what do you want to do or draw with point(x,y,z) ?
its just a single point you are drawing... and the problem is, that you want to draw it at x,y,z but they are not declared so far...
you create it in the loop. but even if you put your point after the loop it wont work cause you have to make the variable global to use it outside of the loop. Anyway, not sure if it helps you cause you still only draw 1 point even if you can access these variables.

paul_ngc

Re: The fiel Component.x is not visible!

3 years ago

Hi Cedrickiefer,

Thanks for the quick reply. I want to have a '3d graph' that's not showing a grid made out of lines, but a grid made out of points.

I tried some more and now I don't get the error anymore, but now all the points have the same size. With strokeWeight I have to make some variable that if it deep in the z-axis it will become smaller.

The most recent version of the sketch is above.

blindfish

Re: The fiel Component.x is not visible!

3 years ago

You could just try replacing the points with rectangles. IIRC they will scale depending on their 3d position...

paul_ngc

Re: Re: The fiel Component.x is not visible!

3 years ago

Thanks for the answer Blindfish, but I already tried it with spheres, and the result was okay, but when you export it, you won't see difference in size.

But it was also pretty heavy for the computer. Took quiet some time to load into Illustrator.

amnon.owed

Re: IllegalArgumentException: negative width

3 years ago

All right, to follow up the email discussion...

First, there are some lines you don't need anymore when you directly use points instead of beginShape-vertex-endShape.

Second, to prevent a variable of becoming negative you can use abs().

// draw mesh
for (float iv = vCount-1; iv >= 0; iv--) {
// beginShape();
for (float iu = 0; iu <= uCount; iu++) {
float u = map(iu, 0, uCount, uMin, uMax);
float v = map(iv, 0, vCount, vMin, vMax);
float x = 0.75*v;
float y = sin(u)*v;
float z = cos(u)*cos(v);
// vertex(x, y, z);
strokeWeight(abs(0.2 + z*0.5 + u*0.5 + v*0.5));
point(x,y,z);
v = map(iv+1, 0, vCount, vMin, vMax);
x = 0.75*v;
y = sin(u)*v;
z = cos(u)*cos(v);
// vertex(x, y, z);
strokeWeight(abs(0.2 + z*0.5 + u*0.5 + v*0.5));
point(x,y,z);
}
// endShape(); }

paul_ngc

Re: Re: IllegalArgumentException: negative width

3 years ago

Thanks Amnon!

That did the trick. Now I don't get the errors anymore :)

Seems like I'm missing some important information ( like the use of abs ), because I've checked the book Getting Started with Processing, but I couldn't find anything about that in there.

Top Reply