Texture mapping on polygons?

Programming Questions

goldenmas..

in Programming Questions • 3 years ago

Hi everyone, this is my first post here.

I've been working on a project where I have a bunch of geometric objects in 3d space that are made up of groups of polygons kind of mashed together. I got everything working fine, and wanted to take the next step and start playing with texture maps, but I was unable to get the texture mapping to work. The color of the object would change but the texture would just not show up.

any ideas?

Here's the code, thanks!

PImage tmap;

void setup() {

size(640, 360, P3D);

tmap = loadImage("texture1.jpg");

noStroke();

}

void draw() {

background(0);

translate(width / 2, height / 2);

rotateY(map(mouseX, 0, width, -PI, PI));

rotateZ(PI/6);

drawPoly(5,200);

}

void drawPoly(int numSides, float radius){

float angle = 2*PI/numSides;

float[][] pointArray = new float[numSides][2];

for(int i=0; i<numSides; i++){

pointArray[i][0] = radius * sin(angle*i);

}

for(int i=0; i<numSides; i++){

pointArray[i][1] = radius * cos(angle*i);

}

beginShape();

for(int i=0; i<numSides; i++){

texture(tmap);

vertex(pointArray[i][0], pointArray[i][1]);

}

endShape();

}

Replies(1)

goldenmas..

Re: Texture mapping on polygons?

3 years ago

well, in the interest of anyone else who is trying to figure out this question in the future, I figured it out:

I wasn't using the UV coordinates to map the texture to my polygon. I also needed to use the same basic trig stuff to plot out where the UV coords should be. There wasn't any examples explaining this, but it wasn't too hard to figure out with some trial and error:

import processing.opengl.*;

PImage img;

void setup() {

size(640, 360, OPENGL);

img = loadImage("texture2.jpg");

noStroke();

}

void draw() {

background(255);

translate(width / 2, height / 2);

rotateY(map(mouseX, 0, width, -PI, PI));

texture(img);

drawPoly(15,150);

}

void drawPoly(int numSides, float radius) {

float angle = 2*PI/numSides;

float[][] pointArray = new float[numSides][2];

float[][] imgArray = new float[numSides][2];

for(int i=0; i<numSides; i++) {

pointArray[i][0] = radius * sin(angle*i);

imgArray[i][0] = img.width/2 + (img.width/2) * sin(angle*i);

}

for(int i=0; i<numSides; i++) {

pointArray[i][1] = radius * cos(angle*i);

imgArray[i][1] = img.height/2 + (img.height/2) * cos(angle*i);

}

beginShape();

texture(img);

for(int i=0; i<numSides; i++) {

vertex(pointArray[i][0], pointArray[i][1], 0, imgArray[i][0], imgArray[i][1]);

}

endShape();

}

Top Reply