Textfields and printing PDFS

General Discussion Other

richielau

in General Discussion • Other • 9 months ago

I've tried two UI library imports

import java.awt.*;

import controlP5.*;

neither seem to work well with being able to print PDFs using "import processing.pdf.*;"

I just need to be able to use text fields, and print pdfs... anyone else having these issues, or know a good solution? I'm surprised that such a basic interface is so difficult to implement with processing.

Replies(4)

PhiLho

Re: Textfields and printing PDFS

9 months ago

By "print PDF", do you mean "send to the (physical) printer"?
What is your difficulty, exactly?

richielau

Re: Textfields and printing PDFS

9 months ago

I'm trying to save a PDF of my screen. However, if I try and use a textfield, while it appears on screen, it renders a bad zero file sized PDF.

What I need to accomplish is have a text field that i can type into, and see it's typed results on screen , and on a PDF output.

andreas.s..

Re: Textfields and printing PDFS

9 months ago

Hi, a similar question poped up earlier, so here some modified code from my reply here. hth

import controlP5.*;
import processing.pdf.*;
// using controlP5 version 2.0.4 with processing 2.0b7
ControlP5 cp5;
boolean record;
PFont font;
void setup() {
size(800,600);
cp5 = new ControlP5( this );
cp5.addBang( "save" )
.setPosition( 20 , 20 )
.setSize( 100 , 100 )
;
cp5.addTextfield( "input" )
.setPosition( 20 , 150 )
.setSize( 100 , 20 )
;
font = createFont("Helvetica",80);
}
void draw() {
pushMatrix();
if( record ) {
beginRecord( PDF , "txt-" + frameCount + ".pdf" );
}
textFont(font);
textLeading(70);
background(0);
noStroke();
translate( 200 , 100 );
fill( 255 );
text( cp5.get( Textfield.class, "input").getText(), 0 , 0 , 600 , 400 );
if( record ) {
record = false;
endRecord();
}
popMatrix();
}
void save() {
record = true;
}

richielau

Re: Textfields and printing PDFS

9 months ago

@ andreas.s - Thanks, your example worked. i'm not sure why yet, but I do not get the following message with your example:

"use createFont() instead of loadFont() when drawing text using the PDF library."

Top Reply