'text' problems with strings

Programming Questions

simonx

in Programming Questions • 3 years ago

hey! i quite new to processing, so please excuse my non existing knowledge :)

i would like to build a random character animation, which generates a random number of lines and a random number of letters per line. but i don't want them to show up all at once, after 'void draw' has finished, but just one at a time. so one character after another should show up until the "drawing" is over. but my code just shows one character at the beginning, then, after the 'delay' all the other characters...

i know, it sounds confusing... but can you help me?

this is my code: -----

import guru.ttslib.*;

TTS tts; // call text to speech class

PFont f;

String letters = "A B C D E F G H I J K L M N O P Q R S T U V W X Y Z Ä Ü Ö 1 2 3 4 5 6 7 8 9 0 + - / * ! ? =";

String[] words = split(letters, ' ');

void setup() {

size(1000, 500);

// background(255);

f = loadFont("andale.vlw");

}

void draw() {

background(255);

fill(0);

textFont(f, 20);

//tts = new TTS(); //call speak object

int counter3 =(int) random (1,4); // call basic var

int ycoor = 50; // y axis für die FOR schleife

for (int textLine=0; textLine<counter3; textLine++) { //

int counter1 =(int) random (1,4);

int xcoor = 30;

for (int letter=0; letter<counter1; letter++) {

int counter2 =(int) random (1,4);

tts = new TTS(); //call speak object

tts.speak(words[counter2]); // speak letters -> this is fuctioning, but the text isn't

text(words[counter2], xcoor , ycoor ); // this is just working at the end, but not "one after another", which is strange..

xcoor += 30; // letter spacing

delay(500); // Stops the program for 250 milliseconds

}

ycoor += 40; // line break

}

noLoop();

}

Replies(5)

cedrickie..

Re: 'text' problems with strings

3 years ago

if you want something to be animated, you have to make use of draw. so it wont work if you use noLoop.
Also using delay, isnt a good idea.
What you can do is to build up the string, with every frame, not using a for loop.
then just stop it on keypress (or whatever you want) to stop adding new letters and speak the word.

something like this :

String letters = "A B C D E F G H I J K L M N O P Q R S T U V W X Y Z Ä Ü Ö 1 2 3 4 5 6 7 8 9 0 + - / * ! ? =";
String[] words = split(letters, ' ');
String s = "";
int speed = 10;
void setup() {
   size(1000, 500);

   }

void draw() {
   background(255);
   fill(0);

   if(frameCount%speed == 0)
   s = s+words[int(random(words.length))];
   text(s,10,height/2,width-20,400);
   }

simonx

Re: 'text' problems with strings

3 years ago

thanks for the answer, but i don't think it can help me..

the "animation" should loop a whole day for an exhibition about words.

so there must not be something like a trigger event..

i just wanted to show a random number of lines with a random number of letters, all spoken and shown one after another.

so for example:

R A B C H U G

H Z Y B V J L P U Y Q

Z V F G H O P

and so on.

maybe its possible to show one letter every second, until the loop has reached its randomly chosen number of characters.

what i don't understand is:

why does the speaking work, and the text not??

for (int letter=0; letter<counter1; letter++) {

int counter2 =(int) random (1,4);

tts = new TTS(); //call speak object

tts.speak(words[counter2]); // speak letters -> this is fuctioning, but the text isn't

text(words[counter2], xcoor , ycoor ); // this is just working at the end, but not "one after another", which is strange..

xcoor += 30; // letter spacing

}

hmm.. i can't figure this out..

PhiLho

Re: 'text' problems with strings

3 years ago

As Cedric said, delay() is tricky to use and actually its uses are very rare... You can draw whatever you want in draw(), it will be shown on screen only at the end of draw(), and the noLoop() will prevent further events. That's a very common error in Processing...
The code Cedric shows is close of what to do.
The idea is to use draw() as the engine looping to animate on screen: it is used in place of your for loop.
It is a bit trickier in your case, because of the nested loops, but it should be manageable.

PhiLho

Re: 'text' problems with strings

3 years ago

OK, it might not be what you wanted to do, but it conforms, I think, to your description.
It is a good illustration of what I tell people when I advise to use a state machine. This one is quite simple...

int TIMER = 500; // ms
PFont f;
String letters = "A B C D E F G H I J K L M N O P Q R S T U V W X Y Z Ä Ü Ö 1 2 3 4 5 6 7 8 9 0 + - / * ! ? =";
String[] words = split(letters, ' ');
int letterCount;
int wordCount;
int textLine;
int letter;
int xcoor;
int ycoor = 50;
final int NEXTSCREEN = 0;
final int NEXTWORD = 1;
final int NEXTLETTER = 2;
int state = NEXTSCREEN;
long lastTime;
void setup() {
size(1000, 500);
f = createFont("Andale Mono", 20);
textFont(f, 20);
lastTime = millis();
fill(0);
}
void draw() {
if (millis() - lastTime < TIMER) return; // Don't do anything before the delay
lastTime = millis();
if (state == NEXTSCREEN) {
background(255);
wordCount = (int) random(1, 10); // call basic var
textLine = 0;
ycoor = 40;
state = NEXTWORD;
// println("word " + wordCount);
}
if (state == NEXTWORD) {
xcoor = 30;
letterCount = (int) random(1, 7);
letter = 0;
state = NEXTLETTER;
// println("letter " + letterCount);
}
int letterChooser = (int) random(1, words.length);
text(words[letterChooser], xcoor, ycoor);
// print(words[letterChooser]);
if (state == NEXTLETTER) {
xcoor += 30; // letter spacing
letter++;
if (letter == letterCount) {
letter = 0;
state = NEXTWORD;
// println("");
// println("word");
}
}
if (state == NEXTWORD) {
ycoor += 40; // line break
textLine++;
if (textLine == wordCount) {
state = NEXTSCREEN;
// println("sceen");
}
}
}

simonx

Re: 'text' problems with strings

3 years ago

you are a hero. thx so much!!! :)

Top Reply