subtract image colors - Processing Forum

Loading...

Processing Forum

Programming Questions

4ndrea

subtract image colors

in Programming Questions • 8 months ago

Hi,

I have a question about pixels color. I'm writing a code for subtract all colors of an image except red, but i have some problems. The result isn't what I expected. Subtracting G and B values, R comes off equally. An other problem is how subtract black pixels?! I put here my code:

PImage img;
PImage imgOut;
void setup () {
size(1200, 800);
img = loadImage("sea.jpg");
imgOut = createImage(img.width, img.height, ARGB);
}
void draw() {
background(100,100,100);
copyPixels(img, imgOut, 20, 255, 20, 255);
image(imgOut, 0, 0);
}
void copyPixels(PImage img, PImage imgOut, float gMin, float gMax, float bMin, float bMax) {
img.loadPixels();
imgOut.loadPixels();
for (int i=0; i<img.pixels.length; i++) {
color c = img.pixels[i];
float r = red(c); // Get the red value
float g = green(c);
float b = blue(c);
if (g >= gMin && g <= gMax || b >= bMin && b <= bMax) {
imgOut.pixels[i] = color(0, 0);
}
else {
imgOut.pixels[i] = c;
}
}
imgOut.updatePixels();
}

1

Replies(17)

4ndrea

Re: subtract image colors

8 months ago

anyone?!

GoToLoop

GoToLoop

Re: subtract image colors

8 months ago

I dunno much, but I've found a way to have some red.
At least, it's a start!

# 28 -> imgOut. pixels[i] = c & r<<020;

Problem it seems that color combinations are not absolute.
Many shades of red can have many parts of both green & blue!

PhiLho

PhiLho

Re: subtract image colors

8 months ago

Perhaps reset the green and blue channels (set them to zero) and leave the red channel unchanged.

GoToLoop

GoToLoop

Re: subtract image colors

8 months ago

I guess I've got a lil' hang on how to do it.
At least, it's pretty reddish ta moi!

/**
 * Reddishfy (v2.1)
 * by 4ndrea (2013/Feb)
 * mod GoToLoop
 * http://forum.processing.org/topic/subtract-image-colors
 */

PImage img, imgRed;

void setup () {
  size(1200, 800);
  background(0200);
  imageMode(CENTER);
  noLoop();

  img = loadImage("sea.jpg");
  imgRed = createImage(img.width, img.height, ARGB);


  reddishfy(img, imgRed, 040, 0400, 040, 0400);
  image(imgRed, width>>1, height>>1);
}

void reddishfy(PImage imgIn, PImage imgOut, 
float gMin, float gMax, float bMin, float bMax) {

  imgIn.loadPixels();
  imgOut.loadPixels();

  for (int c, g, b, i=imgIn.pixels.length; 
  i!=0; imgOut.pixels[i] = c) {

    c = imgIn.pixels[--i];

    g = c >> 010 & 0xFF;
    b = c & 0xFF;

    if (g >= gMin & g <= gMax)     c &= #FF00FF;
    if (b >= bMin & b <= bMax)     c &= #FFFF00;
  }

  imgOut.updatePixels();
}

GoToLoop

GoToLoop

Re: subtract image colors

8 months ago

Alternative version! Click or hit any key to switch original/modded:

/**
 * Reddishfy (v3.21)
 * by 4ndrea (2013/Feb)
 * mod GoToLoop
 * http://forum.processing.org/topic/subtract-image-colors
 */

PImage img, imgRed;
boolean toDisplayOriginal;

void setup () {
  size(1200, 800);
  background(0200);
  imageMode(CENTER);
  noLoop();

  img = loadImage("sea.jpg");
  imgRed = reddishfy(img, 040, 0400, 040, 0400);
}

void draw() {
  image(toDisplayOriginal? img : imgRed, width>>1, height>>1);
}

void mousePressed() {
  toDisplayOriginal = !toDisplayOriginal;
  redraw();
}

void keyPressed() {
  mousePressed();
}

PImage reddishfy(PImage imgIn, int gMin, int gMax, int bMin, int bMax) {
  PImage imgOut = createImage(imgIn.width, imgIn.height, ARGB);
  imgOut.pixels = imgIn.pixels.clone();

  for (int c, g, b, i=imgOut.pixels.length; i!=0; imgOut.pixels[i] = c) {
    c = imgOut.pixels[--i];

    g = c >> 010 & 0xFF;
    b = c & 0xFF;

    if (g >= gMin & g <= gMax)     c &= #FF00FF;
    if (b >= bMin & b <= bMax)     c &= #FFFF00;
  }

  return imgOut;
}

4ndrea

Re: subtract image colors

8 months ago

Wow, wonderful!!

but is not really what I want to do...Let me try to explain better: if I have an image, with a yellow house and red roof, I'd like to remove all colors except red...so, the result is the red roof alone...the others image colors trasparent (alpha)...do you understand me now?!

Thank you so much for your time!!

GoToLoop

GoToLoop

Re: subtract image colors

8 months ago

Lemme think. You want any pixel not red enough to be 100% transparent, right?
Well, check this one out:
P.S.: Now capable of doing both types of transformation. Switch redOrInv true/ false!

/**
 * Reddishfy (v5.2)
 * by 4ndrea (2013/Feb)
 * mod GoToLoop
 * http://forum.processing.org/topic/subtract-image-colors
 */

PImage img, imgRed;
boolean isOriginalNow;

final static boolean redOrInv = false;
final static color invMask = 0x00FFFFFF;
final static color greenMask = #FF00FF, blueMask = #FFFF00;

void setup () {
  size(1200, 750);
  noLoop();

  ( img = loadImage("sea.jpg") ).resize(width, height);
  imgRed = morphRed(img, 040, 0400, 040, 0400);
}

void draw() {
  background( random(0400) );
  image(isOriginalNow? img : imgRed, 0, 0);
}

void mousePressed() {
  isOriginalNow = !isOriginalNow;
  redraw();
}

void keyPressed() {
  mousePressed();
}

PImage morphRed(PImage imgIn, int gMin, int gMax, int bMin, int bMax) {

  PImage imgOut = createImage(imgIn.width, imgIn.height, ARGB);
  imgOut.pixels = imgIn.pixels.clone();

  for (int c, g, b, i=imgOut.pixels.length; i!=0; imgOut.pixels[i] = c) {

    c = imgOut.pixels[--i];
    g = c >> 010 & 0xFF;
    b = c & 0xFF;

    if (redOrInv) {
      if (g >= gMin & g <= gMax)     c &= greenMask;
      if (b >= bMin & b <= bMax)     c &= blueMask;
    }

    else if (g >= gMin & g <= gMax | b >= bMin & b <= bMax)  c &= invMask;
  }

  return imgOut;
}

4ndrea

Re: subtract image colors

8 months ago

Thanks a lot!

I modified something and I found a way for remove dark tones...what do you think about it?!Some red tones are deleted the same...

PImage img, imgRed;
boolean isOriginalNow;
final static color invMask = 0x00FFFFFF;
final static color greenMask = #FF00FF, blueMask = #FFFF00;
void setup () {
size(1200, 750);
noLoop();
img = loadImage("mar.jpg") ;
imgRed = morphRed(img, 80, 255, 80, 255, 100);
}
void draw() {
background(255);
image(isOriginalNow? img : imgRed, 0, 0);
}
void mousePressed() {
isOriginalNow = !isOriginalNow;
redraw();
}
void keyPressed() {
mousePressed();
}
PImage morphRed(PImage imgIn, int gMin, int gMax, int bMin, int bMax, int darkLimit) {
PImage imgOut = createImage(imgIn.width, imgIn.height, ARGB);
imgOut.pixels = imgIn.pixels.clone();
for (int c, r, g, b, i=imgOut.pixels.length; i!=0; imgOut.pixels[i] = c) {
c = imgOut.pixels[--i];
r = c >> 16 & 0xFF;
g = c >> 010 & 0xFF;
b = c & 0xFF;
if ((r<=darkLimit) && (g<=darkLimit) && (b<=darkLimit)) c &= color(0, 0); //darkTones
else if (g >= gMin & g <= gMax | b >= bMin & b <= bMax) c &= invMask;
}
return imgOut;
}

GoToLoop

GoToLoop

Re: subtract image colors

8 months ago

From what I can understand, any pixel w/ all of its color channel intensity level
less than 100 is eliminated, even red ones (code # 42)!
For example -> color(99, 0 , 0) is sifted all the same, even though it's purely red!

Now, color(30, 101, 0) stays and is able to escape #42 condition,
even though it's very yellow-greenish!
At least, @ # 43, its g part is extirpated and only a faint r stays!

But letting the faint r get away is a lil' contradictory to condition @ #42!

Perhaps you should change else if to just if @ #43.
Or even swap lines #42 & #43.
So both conditions apply always!

Since we don't have your original image, we can't aim at what you're trying to reach!

4ndrea

Re: subtract image colors

8 months ago

my goal is to remain only evident red pixels...no dark red...only evident red...but I don't know in visual perception when the red is evident...so, I rely to my eye...it's so diffult!

do you understand me?

Massimo

Massimo

Re: Re: subtract image colors

8 months ago

I think that for " evident" you might mean " saturated": I think you should switch to HSB color space using colorMode() cause it's much easier to manage similarity among colors with Hue/Saturation/Brightness parameters...

I hope this help.

ciao,

Massimo

4ndrea

Re: subtract image colors

8 months ago

for example, with this img, it seems to work:

http://patatatravel.files.wordpress.com/2008/05/mar_rosso.jpg

4ndrea

Re: subtract image colors

8 months ago

but it is not very precise...

4ndrea

Re: subtract image colors

8 months ago

you're so right...I try!

sono italiano anche io...ciao!

GoToLoop

GoToLoop

Re: subtract image colors

8 months ago

Massimo is right! In RGB, red color shades can have much of both green & blue.
So it's very difficult to say whether an RGB color code is "red" just by looking at it.

You have to use HSB approach, although it's a little exotic!

Here's my latest "RGB" of your algorithm:

/**
 * Reddishfy (v6.0)
 * by 4ndrea (2013/Feb)
 * mod GoToLoop
 * http://forum.processing.org/topic/subtract-image-colors
 */

PImage img, imgRed;
boolean isOriginalNow;

final static String fileName = "http://patatatravel.files.wordpress.com/2008/05/mar_rosso.jpg";
//final static String fileName = "mar_rosso.jpg";

final static boolean filterOrSift = false;
final static color invMask = 0x00FFFFFF, redMask = #00FFFF;
final static color greenMask = #FF00FF, blueMask = #FFFF00;

void setup () {
  size(1200, 750);
  noLoop();

  ( img = loadImage(fileName) ).resize(width, height);

  imgRed = morphRed(img, 
  0400, // keep red channel
  040, // eliminates if green >= 32
  040, // eliminates if blue  >= 32
  040); // filters out pixels w/ intensitity <= 32
}

void draw() {
  background( random(0400) );
  image(isOriginalNow? img : imgRed, 0, 0);
}

void mousePressed() {
  isOriginalNow = !isOriginalNow;
  redraw();
}

void keyPressed() {
  mousePressed();
}

PImage morphRed(PImage imgIn, int rMax, int gMax, int bMax, int toneMin) {

  PImage imgOut = createImage(imgIn.width, imgIn.height, ARGB);
  imgOut.pixels = imgIn.pixels.clone();

  for (int c, r, g, b, i=imgOut.pixels.length; i!=0; imgOut.pixels[i] = c) {

    c = imgOut.pixels[--i];
    r = c >> 020 & 0xFF;
    g = c >> 010 & 0xFF;
    b = c & 0xFF;

    // filter out each color channel which exceeded its limit:
    if (filterOrSift) {
      if (g >= gMax)      c &= redMask;
      if (g >= gMax)      c &= greenMask;
      if (b >= bMax)      c &= blueMask;
    }
    // remove any pixel in which any of the channels exceeded its limit:
    else if (r >= rMax | g >= gMax | b >= bMax)        c &= invMask;

    // remove overall weak pixel color:
    if (r <= toneMin & g <= toneMin & b <= toneMin)    c &= invMask;
  }

  return imgOut;
}

4ndrea

Re: subtract image colors

8 months ago

it works:

//blue
PImage img;
PImage imgOut;
void setup () {
size(1200,900);
img = loadImage("mar.jpg");
colorMode(HSB, 360, 100, 100);
imgOut = createImage(img.width, img.height, ARGB);
}
void draw() {
background(255);
copyPixels(img, imgOut, 190, 245, 30, 30);
image(imgOut,0,0);
}
void copyPixels(PImage img,PImage imgOut, float hMin, float hMax, float sMin, float bMin){
img.loadPixels();
imgOut.loadPixels();
for (int i=0; i<img.pixels.length; i++){
color c = img.pixels[i];
if(hue(c) >= hMin && hue(c) <= hMax && saturation(c)>=sMin && brightness(c)>=bMin) {
imgOut.pixels[i] = c;
} else {
imgOut.pixels[i] = color(0,0);
}
}
imgOut.updatePixels();
}

4ndrea

Re: subtract image colors

8 months ago

for the red, it's between 350°-360° and 0°-10°(Hue values), so I have to create four different kind variables, like h1Min, h1Max, h2Min, h2Max...or is there an other method?

Top Reply