String from array to float

Programming Questions

vextex

in Programming Questions • 10 months ago

Even after searching and reading through the forums, I can't get my head around how to make this work. Here's some of my code.

String[] pulses = { "sin(t)", "cos(t)" };
void setup() {
size(500, 500);
}
void draw() {
float t = millis() * 0.15;
float sizeChange = …
ellipse(0, 0, sizeChange, sizeChange)
}

Now, the problem is that nothing seems to work on line 9. What I want is to be able to take some index from the array “pulses” and use it to be the “sizeChange”, but stuff like

float sizeChange = float(pulses[1]);

and other variants like the more complex (in writing) “Float.parseFloat()”, don't seem to work. The best I can get (when printing) is NaN. However, if I use “int()”, I always get 0, which of course will not work, since all the values will be between -1 an 1 anyway, I need the float.

It seems like it should be simple, but I'm not getting it to work.

Thank you in advance

Replies(15)

v.k.

Re: String from array to float

10 months ago

this? I didn't get... Why the String?

void setup() {
size(500, 500);
}
void draw() {
float t = millis() * 0.15;
float sizeChange = sin(radians(t))*100;
ellipse(width/2, height/2, sizeChange, sizeChange);
}

vextex

Re: String from array to float

10 months ago

That works, but it's not why I need. The idea is that I could just have an array with a lot of different options (not just two, that was to simplify the question), and change it “on the fly” by just switching the index of it that it accessess. That way I could have an array with 20 options, and by changing just one number, completely alter sizeChange.

That is not my final code, it's just an oversimplified version of the section I'm having trouble with, so it's a smaller use case.

v.k.

Re: String from array to float

10 months ago

I have seen code generating code, but i don't know how to do it, this sketch for instance is doing this, but just to be copied, I don't know if you can use on the fly...

Maybe a switch would do it?

something like

switch (equation)

{

case 0:

sizeChange = sin(t);

break;

case 1:

sizeChange = cos(t);

break

etc...

}

or maybe...

a class that takes a string in a method, inside the class you make a switch or a lot of ifs. Than you can store those strings in an array and use it to pass to that method:

String[] pulses = { "sin(t)", "cos(t)" };

Selector s =new Selector();

s.draw(pulses[1]);

and in the class

void draw(String equation)

{

if( sin(t))

do stuff...

if(cos(t))

other stuff

}

[edit]: Actually i thing you can only switch in ints...

yep see from reference:

" Only primitive datatypes which can convert to an integer (byte, char, and int)"

you could still make an Enum

vextex

Re: String from array to float

10 months ago

That's not ideal at all, it's a lot of code and redundancy, that also depends on me updating the different functions every time I make a change, programming should make our lives easier, not harder.

If I can do

float sizeChange = int(pulses[1]);

(and get 0.0), then why can't I do

float sizeChange = float(pulses[1]);

and get the result I need? (and instead get NaN). It really shouldn't be much harder than that. The string converts to integer (and it does convert, because I can do math operations with it), so why does it not convert to float? That's what got me stumped. I see where the problem is, I see what the solution should be, but the implementation does not work.

PhiLho

Re: String from array to float

10 months ago

If you need to compute a formula given in a string, you need a specialized library, or you can just use the JavaScript library shipped with Java.

vextex

Re: String from array to float

10 months ago

Could you please elaborate more? I get that I need to

import netscape.javascript.*;

But after that, I'm at a loss as to how I should proceed.

Alternatively, I can get it to work by moving the array inside “draw”, and making it use floats

void setup() {
size(500, 500);
}
void draw() {
float t = millis() * 0.15;
float[] pulses = { sin(t), cos(t) };
float sizeChange = pulses[1];
ellipse(0, 0, sizeChange, sizeChange);
}

But this seems really wasteful, it's effectively computing everything in the array over and over again, wasting resources. Ultimately, I'd expect to be able to do something like this (but with only one circle at a time.

So using a bit of javascript to convert to the float would be fine, could you elaborate a bit on the code?

Thank you.

v.k.

Re: String from array to float

10 months ago

Cool site! Again I would go like this, I don't see code redundancy :

press a key to change mode.

int mode = 0;
void setup() {
size(500, 500);
smooth();
frameRate(300);
}
void draw() {
background(0);
float t = millis() * 0.15;
float sizeChange = getEq(mode, t);
ellipse(width/2, height/2, sizeChange, sizeChange);
}
void keyReleased()
{
mode = (mode+1)%4;
println(mode);
}
float getEq(int mode, float value)
{
float result = -1;
float factor = 100;
switch (mode)
{
case 0:
result = sin(radians(value))*factor;
break;
case 1:
result = sin(tan(radians(value))*pow(sin(radians(value)),10))*factor;
break;
case 2:
result = pow(sin(radians(value*PI)),12)*factor;
break;
case 3:
result = cos(sin(radians(value*3))+radians(value*3))*factor;
break;
}
return result;
}

PhiLho

Re: String from array to float

10 months ago

No, not this JavaScript library, the new one:

import javax.script.ScriptEngine;
import javax.script.ScriptEngineManager;
import javax.script.ScriptException;
import javax.script.Invocable;
ScriptEngine jsEngine;
final String FUNC = "Math.sin(x) + Math.cos(x)";
void setup()
{
size(500, 500);
background(255);
strokeWeight(3);
ScriptEngineManager mgr = new ScriptEngineManager();
jsEngine = mgr.getEngineByName("JavaScript");
stroke(#FF0000);
for (int x = 0; x < width; x++)
{
double y = getYEval(x / TWO_PI);
point((float) x, (float) (1 * height / 2 + y * height / 16));
}
}
double getYEval(double x)
{
try
{
String expr = "var x = " + x + "; " + FUNC;
return ((Double) jsEngine.eval(expr)).doubleValue();
}
catch (ScriptException ex)
{
ex.printStackTrace();
}
return 0;
}

There are other invocation strategies, more or less efficient, you can have a glimpse at:
http://bazaar.launchpad.net/~philho/+junk/Processing/view/head:/_QuickExperiments/_Java/JavaScriptUsage/JavaScriptUsage.pde
(I extracted the above code from there)

vextex

Re: String from array to float

10 months ago

Thank you both for the help. I'll see what I can come up with with your implementations.

v.k.

Re: String from array to float

10 months ago

My pleasure, I really liked this ;) as you can see below

And now i got why you want to do it the way you want. If you get this working with js, I would like to see.

//* based on a question by vextex at forum.processing.org
int eqIndex = 0;
String[] equations = {"sin(t)",
"cos(t)",
"cos(t)*sin(t)",
"sin(t)*sin(t*1.5)",
"sin(tan(cos(t)*1.2))",
"sin(tan(t)*0.05)",
"cos(sin(t*3))*sin(t*0.2)",
"sin(pow(8,sin(t)))",
"sin(exp(cos(t*0.8))*2)",
"sin(t-PI*tan(t)*0.01)",
"pow(sin(t*PI),12)",
"cos(sin(t)*tan(t*PI)*PI/8)",
"sin(tan(t)*pow(sin(t),10))",
"cos(sin(t*3)+t*3)",
"pow(abs(sin(t*2))*0.6,sin(t*2))*0.6"};
PFont f;
void setup() {
size(500, 500, P2D);
smooth();
f = createFont("arial",20);
textAlign(LEFT);
frameRate(300);
background(0);
}
void draw() {
noStroke();
fill(0,10);
rect(0, 0, width, height -50);
fill(0);
rect(0, height - 50, width, height);
float t = millis() * 0.15;
textFont(f, 15);
fill(200);
float sizeChange = getEq(eqIndex, t, 150);
fill(220);
ellipse(34.5, height - 37, 20, 20);
fill(0);
text(nf((eqIndex + 1),2), 26,height -31);
fill(200);
textSize(20);
text(equations[eqIndex], 54,height -31);
fill(255);
ellipse(width/2, height/2, sizeChange, sizeChange);
}
void keyReleased()
{
eqIndex = (eqIndex+1)%15;
println(eqIndex);
}
float getEq(int eqIndex, float value, float factor)
{
float result = -1;
//float factor = 100;
float t = radians(value);
switch (eqIndex)
{
case 0:
result = sin(t)*factor;
break;
case 1:
result = cos(t)*factor;
break;
case 2:
result = cos(t)*sin(t)*factor;
break;
case 3:
result = sin(t)*sin(t*1.5)*factor;//
break;
case 4:
result = sin(tan(cos(t)*1.2))*factor;
break;
case 5:
result = sin(tan(t)*0.05)*factor;
break;
case 6:
result = cos(sin(t*3))*sin(t*0.2)*factor;
break;
case 7:
result = sin(pow(8,sin(t)))*factor;
break;
case 8:
result = sin(exp(cos(t*0.8))*2)*factor;
break;
case 9:
result = sin(t-PI*tan(t)*0.01)*factor;
break;
case 10:
result = pow(sin(t*PI),12)*factor;
break;
case 11:
result = cos(sin(t)*tan(t*PI)*PI/8)*factor;
break;
case 12:
result = sin(t-PI*tan(t)*0.01)*factor;
break;
case 13:
result = cos(sin(t*3)+t*3)*factor;
break;
case 14:
result = pow(abs(sin(t*2))*0.6,sin(t*2))*0.6*factor;
break;
}
return result;
}

vextex

Re: Re: String from array to float

10 months ago

I didn't have much chance to look at the code, yet, but on a first look, you should probably change lines 44 to 47 to something more like

void keyReleased() {
if(eqIndex < 14) {
eqIndex++;
}
else {
eqIndex = 0;
}
}

This way it won't throw an error when reaching the end, and the incrementing is simpler (no need to do “ eqIndex = (eqIndex+1); ”)

v.k.

Re: String from array to float

10 months ago

??? I'm getting no error with that code... It works, give it a try :)

[EDIT], ops, i messed when pasting (my local copy wsa fine), in the line 53 was missing "%15", probably accidentally deleted together with a debug line after pasting in forum. Corrected now (in bold)! I can try it. Thanks for pointing.

vextex

Re: Re: String from array to float

10 months ago

I did try it, I get an “ArrayIndexOutOfBoundsException: 15” error, after I get to the last one.

v.k.

Re: String from array to float

10 months ago

With this edited code? Repasted? Well here it runs fine. The modulo operator should avoid that error. Anyway, you've seen enough :)

I found that really cool. Thanks for the inspiration. If you ever get the javaScript running, and wants to share it, i'd like to see.

vextex

Re: String from array to float

10 months ago

Yes, I tried it again before posting that answer, and it still gave me the error (using the latest beta), but I agree, it was good enough for me to understand.

The limitation bothers me a bit, though, I'd expect processing to be able to do it on its own, without having to resort to javascript (specially since it seems to work converting to an integer, but not to a float).

Since my needs are still a bit vague on the issue (I'm still experimenting with the result), I'll probably resort to having the array as floats inside draw(), it may not be very memory efficient, but will do for now. Using javascript inside processing is complicated (read, beyond my current understanding, since I'm still a bit fresh to processing, and programming in general, trying to teach myself), so I'll probably have to learn a bit more and come back to this particular issue later on.