Storing shapes in an array

Programming Questions

robinson92

in Programming Questions • 2 years ago

I woud like to store a shape I have drawn in a class into an array, so later when it comes to drawing them (having them fill the screen) I don't have to go out and keep declaring a "bah1... 2... 3... 4... ect = new blah" but I'm not sure how to go about storing the 'shape' in an array. I think I might just be having a mental block atm, but here is my class:

class dangerBlock
{
float reda = 0;
float redb = 0;
float redValue;
float greenValue;

dangerBlock()
{
    for (int i = 0; i < block.length; i++)
    {
      block[i] = drawBlock;
    }
}
void colourChange()
{
    float r = random(.009, .1);
    reda = reda + r;
    redb = cos (reda);
    redValue = redb;
    greenValue = redb;
    redValue = map (redValue, -1, 1, 0, 255);
    greenValue = map (greenValue, 1, -1, 0, 255);
}

void drawBlock()
{
    colourChange();
    rectMode (RADIUS);
    fill(redValue, greenValue, 0);
    rect(0, 0, 25, 25);
}
}

as I have said, the idea is to now store it so later I can just use a for loop and translate it to cover the screen, cheers.

Replies(1)

allonestr..

Re: Storing shapes in an array

2 years ago

Rather than altering your code, here's a quick class and how to store and display an array of them.

string

Copy code

shapeClass[] shapeArray;
int numShapes = 5;

void setup()
{
size(200, 200);
background(255);
smooth();
noStroke();
colorMode(RGB);
frameRate(1);

shapeArray = new shapeClass[numShapes];
for(int s = 0; s < numShapes; s++)
{
    shapeArray[s] = new shapeClass(color(30, 60, 90), random(20, 40), random(2, 50));
}
}

void draw()
{
fill(255, 128);
noStroke();
rect(0, 0, width, height);

for(int s = 0; s < numShapes; s++)
{
    pushMatrix();
    translate(random(20, 150), random(20, 150));
    shapeArray[s].display();
    popMatrix();
}
}

Copy code

class shapeClass
{
color colour;
float shapeWidth;
float shapeHeight;

shapeClass(color colour, float shapeWidth, float shapeHeight)
{
    this.colour = colour;
    this.shapeWidth = shapeWidth;
    this.shapeHeight = shapeHeight;
}

void display()
{
    smooth();
    fill(colour);
    stroke(127);
    ellipseMode(CORNER);
    ellipse(0, 0, shapeWidth, shapeHeight);
}
}

Top Reply