You may want to look at these 2 links:
http://forum.processing.org/topic/background-gray-alpha-what-does-this-even-do-5-3-2013-1
http://forum.processing.org/topic/wanna-change-direction-with-keypressed

There are some explanations on how to make the background surface transparent,
so you can stamp, and then crop images outta it, keeping their alphaness!

I don't see the problem. You can use get() on a PImage, so it doesn't need to be on the screen. Furthermore, the get() method does preserve transparancy. So the problems you describe in your post are caused by your own code (which you don't show) and not by the get() method as such. Here is an example.

Code Example 1

1. PImage spritesheet = loadImage("http://www.nordenfelt-thegame.com/blog/wp-content/uploads/2011/11/explosion_transparent.png");
2. int DIM = 5;
3. int W = spritesheet.width/DIM;
4. int H = spritesheet.height/DIM;
5.  
6. void setup() {
7.   size(300, 300);
8.   imageMode(CENTER);
9. }
10.  
11. void draw() {
12.   int f255 = frameCount%255;
13.   background(f255, 255-f255, 0);
14.   int x = frameCount%DIM*W;
15.   int y = frameCount/DIM%DIM*H;
16.   PImage sprite = spritesheet.get(x, y, W, H);
17.   image(sprite, mouseX, mouseY);
18. }

Note that using get() inside draw() isn't very efficient. It would be faster to do that ONCE in setup() and just put all the sprites in an array, which you can use in draw() instead. See the adapted code.

Code Example 2

1. PImage spritesheet = loadImage("http://www.nordenfelt-thegame.com/blog/wp-content/uploads/2011/11/explosion_transparent.png");
2. int DIM = 5;
3. PImage[] sprites = new PImage[DIM*DIM];
4.  
5. void setup() {
6.   size(300, 300);
7.   imageMode(CENTER);
8.   int W = spritesheet.width/DIM;
9.   int H = spritesheet.height/DIM;
10.   for (int i=0; i<sprites.length; i++) {
11.     int x = i%DIM*W;
12.     int y = i/DIM*H;
13.     sprites[i] = spritesheet.get(x, y, W, H);
14.   }
15. }
16.  
17. void draw() {
18.   int f255 = frameCount%255;
19.   background(f255, 255-f255, 0);
20.   image(sprites[frameCount%sprites.length], mouseX, mouseY);
21. }

Ok, first of all, sorry for not sharing the code. I was away from home and, frankly, it's as stupid as this:

    image(walk_D, 0, 0);
    g.removeCache(walk_D);
    tempI=get(i*28, 0, 24, 44);
    image (tempI, 230, 132);

inside a for, inside a function called upon the need of the animation.
Yes, the get() keeps my alpha value but, since my screen scrolls as the player walks, part of it scrolls bellow the spritesheet, even the sheet being away from the players view, so I get a perfect animation, but with pieces of the scene surrounding my player sprite. That's what I'm trying to prevent from happening.
Yes, I could translate the spritesheet along with the scene images but 1 - it would need to recalculate the coordinates for every frame and 2 - I have different scenes with different sizes, so it just doesn't seem like the best approach.
Thank you all, as always :)

Don't use get() but use spritesheet.get() to get() from the spritesheet directly as shown in the above examples.

Ok, perfect :).
Sorry for missing that detail and thank you very very much!
Marking it as solved.