Spiral generation

Programming Questions

Goza

in Programming Questions • 5 months ago

Hello all,

I trying to draw something similar a tree section:

http://commons.wikimedia.org/wiki/File:Tree_rings.jpg

To do this I drawing a spiral and using a vertical line as a brush that rotates to the spiral direction while it is being generate.

Here is my code:

float dist = 1, radius = dist/2, alpha = 0, speed = 50;
float px, py, x, y, k;
float puntoFijoY =30;
void setup() {
size(1024, 768);
background(255);
smooth();
frameRate(25);
}
void draw() {
k = speed/radius;
alpha += k;
radius += (dist+puntoFijoY)/(360/k);
x = radius*cos(radians(alpha));
y = -radius*sin(radians(alpha));
float dx = x - width/2;
float dy = x - height/2;
float radianes = atan2(dy,dx);
pushMatrix();
translate(width/2, height/2);
translate(x,y);
rotate(abs(radianes *180/PI));
stroke(153,51,50);
//rect(x,y,10,5);
line(0, 0, 0, 10);
popMatrix();
}

As you will see the line just rotates in the right direction just form a while.

Do you know how to do this.

Salutations,

Replies(5)

asimes

I like how that looks, almost calligraphic. The first thing that comes to mind is that the original image does not have spirals, it has concentric circles. I tried making a test and it is far from polished but at least it does roughly what I want. The idea is just to draw multiple concentric circles but with random wiggles to be imperfect like the tree. This code only draws one wiggly circle at the moment but it's the general idea. You could replace the point with your line:

int rad = 100, index = 0;
float theta = 0;
PVector currWiggle = new PVector();
PVector[] wiggles = new PVector[1000];
void setup() {
size(400, 400);
background(255);
// Guarentee that wiggle ends up in the same position after a rotation
for (int i = 0; i < 250; i++) wiggles[i] = new PVector(-0.25, -0.25);
for (int i = 250; i < 500; i++) wiggles[i] = new PVector(0.25, -0.25);
for (int i = 500; i < 750; i++) wiggles[i] = new PVector(-0.25, 0.25);
for (int i = 750; i < 1000; i++) wiggles[i] = new PVector(0.25, 0.25);
// Randomize
for (int i = 0; i < 1000; i++) {
int randIndex = (int)random(1000);
PVector swap = new PVector(wiggles[i].x, wiggles[i].y);
wiggles[i].x = wiggles[randIndex].x;
wiggles[i].y = wiggles[randIndex].y;
wiggles[randIndex].x = swap.x;
wiggles[randIndex].y = swap.y;
}
}
void draw() {
currWiggle.x += wiggles[index].x;
currWiggle.y += wiggles[index].y;
float x = width/2+cos(theta)*rad+currWiggle.x;
float y = height/2+sin(theta)*rad+currWiggle.y;
point(x, y);
theta += TWO_PI/1000;
index++;
if (index == 1000) noLoop();
}

Goza

Re: Spiral generation

5 months ago

Thanks for your answer Asimes.

Good idea. Any way I need to do it using a spiral.

Goza

Re: Spiral generation

5 months ago

I think the problem is with the trigonometry function:

float dx = x - width/2;
float dy = x - height/2;
float radianes = atan2(dy,dx);
--->
rotate(abs(radianes *180/PI));
stroke(153,51,50);
line(0, 0, 0, 10);

To calculate direction I'm using the center of stage...

It's right?

asimes

Re: Spiral generation

5 months ago

Oh, I had misunderstood your question earlier then, I didn't realize you wanted to fix your alignment. This should do it:

float dist = 1, radius = dist/2, alpha = 0, speed = 50;
float px, py, x, y, k;
float puntoFijoY =30;
void setup() {
size(1024, 768);
background(255);
smooth();
frameRate(25);
}
void draw() {
k = speed/radius;
alpha += k;
radius += (dist+puntoFijoY)/(360/k);
x = width/2+cos(radians(alpha))*radius;
y = height/2+sin(-radians(alpha))*radius;
float dx = x - width/2;
float dy = y - height/2;
float radianes = atan2(dy, dx);
pushMatrix();
translate(width/2, height/2);
rotate(radianes);
translate(radius, 0);
stroke(153, 51, 50);
line(-5, 0, 5, 0);
popMatrix();
}

Goza

Re: Spiral generation

5 months ago

Thanks again Asines, it works great, thats just what a meant.